let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (#Z 2)) - (((id Z) (#) (f1 + (#Z 2))) ^) & Z c= dom (((id Z) ^) (#) arctan) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous holds
integral (f,A) = ((- (((id Z) ^) (#) arctan)) . (upper_bound A)) - ((- (((id Z) ^) (#) arctan)) . (lower_bound A))
let f, f1 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (#Z 2)) - (((id Z) (#) (f1 + (#Z 2))) ^) & Z c= dom (((id Z) ^) (#) arctan) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous holds
integral (f,A) = ((- (((id Z) ^) (#) arctan)) . (upper_bound A)) - ((- (((id Z) ^) (#) arctan)) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (#Z 2)) - (((id Z) (#) (f1 + (#Z 2))) ^) & Z c= dom (((id Z) ^) (#) arctan) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous implies integral (f,A) = ((- (((id Z) ^) (#) arctan)) . (upper_bound A)) - ((- (((id Z) ^) (#) arctan)) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (#Z 2)) - (((id Z) (#) (f1 + (#Z 2))) ^) & Z c= dom (((id Z) ^) (#) arctan) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((- (((id Z) ^) (#) arctan)) . (upper_bound A)) - ((- (((id Z) ^) (#) arctan)) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: - (((id Z) ^) (#) arctan) is_differentiable_on Z by A1, Th54;
A4: Z = (dom (arctan / (#Z 2))) /\ (dom (((id Z) (#) (f1 + (#Z 2))) ^)) by A1, VALUED_1:12;
then A5: Z c= dom (arctan / (#Z 2)) by XBOOLE_1:18;
A6: Z c= dom (((id Z) (#) (f1 + (#Z 2))) ^) by A4, XBOOLE_1:18;
dom (((id Z) (#) (f1 + (#Z 2))) ^) c= dom ((id Z) (#) (f1 + (#Z 2))) by RFUNCT_1:1;
then Z c= dom ((id Z) (#) (f1 + (#Z 2))) by A6;
then Z c= (dom (id Z)) /\ (dom (f1 + (#Z 2))) by VALUED_1:def 4;
then A7: Z c= dom (f1 + (#Z 2)) by XBOOLE_1:18;
A8: for x being Real st x in Z holds
f . x = ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x ^2))))

proof

let x be Real; :: thesis: ( x in Z implies f . x = ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x ^2)))) )
assume A9: x in Z ; :: thesis: f . x = ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x ^2))))
then A10: x in dom (((id Z) (#) (f1 + (#Z 2))) ^) by A6;
((arctan / (#Z 2)) - (((id Z) (#) (f1 + (#Z 2))) ^)) . x = ((arctan / (#Z 2)) . x) - ((((id Z) (#) (f1 + (#Z 2))) ^) . x) by A1, A9, VALUED_1:13
.= ((arctan / (#Z 2)) . x) - (1 / (((id Z) (#) (f1 + (#Z 2))) . x)) by A10, RFUNCT_1:def 2
.= ((arctan / (#Z 2)) . x) - (1 / (((id Z) . x) * ((f1 + (#Z 2)) . x))) by VALUED_1:5
.= ((arctan / (#Z 2)) . x) - (1 / (((id Z) . x) * ((f1 . x) + ((#Z 2) . x)))) by A7, A9, VALUED_1:def 1
.= ((arctan / (#Z 2)) . x) - (1 / (x * ((f1 . x) + ((#Z 2) . x)))) by A9, FUNCT_1:18
.= ((arctan / (#Z 2)) . x) - (1 / (x * (1 + ((#Z 2) . x)))) by A1, A9
.= ((arctan . x) / ((#Z 2) . x)) - (1 / (x * (1 + ((#Z 2) . x)))) by A9, A5, RFUNCT_1:def 1
.= ((arctan . x) / (x #Z 2)) - (1 / (x * (1 + ((#Z 2) . x)))) by TAYLOR_1:def 1
.= ((arctan . x) / (x #Z 2)) - (1 / (x * (1 + (x #Z 2)))) by TAYLOR_1:def 1
.= ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x #Z 2)))) by FDIFF_7:1
.= ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x ^2)))) by FDIFF_7:1 ;
hence f . x = ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x ^2)))) by A1; :: thesis: verum

end;

A11: for x being Element of REAL st x in dom ((- (((id Z) ^) (#) arctan)) `| Z) holds
((- (((id Z) ^) (#) arctan)) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((- (((id Z) ^) (#) arctan)) `| Z) implies ((- (((id Z) ^) (#) arctan)) `| Z) . x = f . x )
assume x in dom ((- (((id Z) ^) (#) arctan)) `| Z) ; :: thesis: ((- (((id Z) ^) (#) arctan)) `| Z) . x = f . x
then A12: x in Z by A3, FDIFF_1:def 7;
then ((- (((id Z) ^) (#) arctan)) `| Z) . x = ((arctan . x) / (x ^2)) - (1 / (x * (1 + (x ^2)))) by A1, Th54
.= f . x by A8, A12 ;
hence ((- (((id Z) ^) (#) arctan)) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((- (((id Z) ^) (#) arctan)) `| Z) = dom f by A1, A3, FDIFF_1:def 7;
then (- (((id Z) ^) (#) arctan)) `| Z = f by A11, PARTFUN1:5;
hence integral (f,A) = ((- (((id Z) ^) (#) arctan)) . (upper_bound A)) - ((- (((id Z) ^) (#) arctan)) . (lower_bound A)) by A1, A2, A3, INTEGRA5:13; :: thesis: verum