let Z be open Subset of REAL; :: thesis: ( Z c= dom (((id Z) ^) (#) arccot) & Z c= ].(- 1),1.[ implies ( - (((id Z) ^) (#) arccot) is_differentiable_on Z & ( for x being Real st x in Z holds
((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2)))) ) ) )
set f = id Z;
assume that
A1: Z c= dom (((id Z) ^) (#) arccot) and
A2: Z c= ].(- 1),1.[ ; :: thesis: ( - (((id Z) ^) (#) arccot) is_differentiable_on Z & ( for x being Real st x in Z holds
((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2)))) ) )
A3: Z c= dom (- (((id Z) ^) (#) arccot)) by A1, VALUED_1:8;
A4: for x being Real st x in Z holds
(id Z) . x = x by FUNCT_1:18;
Z c= (dom ((id Z) ^)) /\ (dom arccot) by A1, VALUED_1:def 4;
then A5: Z c= dom ((id Z) ^) by XBOOLE_1:18;
A6: not 0 in Z

proof

assume A7: 0 in Z ; :: thesis: contradiction
dom ((id Z) ^) = (dom (id Z)) \ ((id Z) " {0}) by RFUNCT_1:def 2
.= (dom (id Z)) \ {0} by Lm1, A7 ;
then not 0 in {0} by A7, A5, XBOOLE_0:def 5;
hence contradiction by TARSKI:def 1; :: thesis: verum

end;

then A8: ( (id Z) ^ is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) ^) `| Z) . x = - (1 / (x ^2)) ) ) by FDIFF_5:4;
A9: arccot is_differentiable_on Z by A2, SIN_COS9:82;
A10: ((id Z) ^) (#) arccot is_differentiable_on Z by A6, A1, A2, SIN_COS9:130;
then A11: (- 1) (#) (((id Z) ^) (#) arccot) is_differentiable_on Z by A3, FDIFF_1:20;
for x being Real st x in Z holds
((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2))))

proof

let x be Real; :: thesis: ( x in Z implies ((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2)))) )
assume A12: x in Z ; :: thesis: ((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2))))
then A13: ((id Z) ^) (#) arccot is_differentiable_in x by A10, FDIFF_1:9;
A14: (id Z) ^ is_differentiable_in x by A8, A12, FDIFF_1:9;
A15: arccot is_differentiable_in x by A9, A12, FDIFF_1:9;
((- (((id Z) ^) (#) arccot)) `| Z) . x = diff ((- (((id Z) ^) (#) arccot)),x) by A11, A12, FDIFF_1:def 7
.= (- 1) * (diff ((((id Z) ^) (#) arccot),x)) by A13, FDIFF_1:15
.= (- 1) * (((arccot . x) * (diff (((id Z) ^),x))) + ((((id Z) ^) . x) * (diff (arccot,x)))) by A14, A15, FDIFF_1:16
.= (- 1) * (((arccot . x) * ((((id Z) ^) `| Z) . x)) + ((((id Z) ^) . x) * (diff (arccot,x)))) by A8, A12, FDIFF_1:def 7
.= (- 1) * (((arccot . x) * (- (1 / (x ^2)))) + ((((id Z) ^) . x) * (diff (arccot,x)))) by A12, A6, FDIFF_5:4
.= (- 1) * ((- ((arccot . x) * (1 / (x ^2)))) + ((((id Z) ^) . x) * ((arccot `| Z) . x))) by A9, A12, FDIFF_1:def 7
.= (- 1) * ((- ((arccot . x) * (1 / (x ^2)))) + ((((id Z) ^) . x) * (- (1 / (1 + (x ^2)))))) by A2, A12, SIN_COS9:82
.= (- 1) * ((- (((arccot . x) * 1) / (x ^2))) - ((((id Z) ^) . x) * (1 / (1 + (x ^2)))))
.= (- 1) * ((- ((arccot . x) / (x ^2))) - ((((id Z) . x) ") * (1 / (1 + (x ^2))))) by A5, A12, RFUNCT_1:def 2
.= (- 1) * ((- ((arccot . x) / (x ^2))) - ((1 / x) * (1 / (1 + (x ^2))))) by A4, A12
.= (- 1) * ((- ((arccot . x) / (x ^2))) - ((1 * 1) / (x * (1 + (x ^2))))) by XCMPLX_1:76
.= ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2)))) ;
hence ((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2)))) ; :: thesis: verum

end;

hence ( - (((id Z) ^) (#) arccot) is_differentiable_on Z & ( for x being Real st x in Z holds
((- (((id Z) ^) (#) arccot)) `| Z) . x = ((arccot . x) / (x ^2)) + (1 / (x * (1 + (x ^2)))) ) ) by A11; :: thesis: verum