let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1, f2 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous holds
integral (f,A) = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A))
let f, f1, f2 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous holds
integral (f,A) = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous implies integral (f,A) = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A)) )
assume A1: ( A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: Z c= dom ((1 / 2) (#) (ln * (f1 + f2))) by A1, VALUED_1:def 5;
Z c= (dom (id Z)) /\ ((dom (f1 + f2)) \ ((f1 + f2) " {0})) by A1, RFUNCT_1:def 1;
then Z c= (dom (f1 + f2)) \ ((f1 + f2) " {0}) by XBOOLE_1:18;
then A4: Z c= dom ((f1 + f2) ^) by RFUNCT_1:def 2;
dom ((f1 + f2) ^) c= dom (f1 + f2) by RFUNCT_1:1;
then A5: Z c= dom (f1 + f2) by A4;
A6: (1 / 2) (#) (ln * (f1 + f2)) is_differentiable_on Z by A1, A3, SIN_COS9:102;
A7: for x being Real st x in Z holds
f . x = x / (1 + (x ^2))

proof

let x be Real; :: thesis: ( x in Z implies f . x = x / (1 + (x ^2)) )
assume A8: x in Z ; :: thesis: f . x = x / (1 + (x ^2))
then ((id Z) / (f1 + f2)) . x = ((id Z) . x) / ((f1 + f2) . x) by A1, RFUNCT_1:def 1
.= x / ((f1 + f2) . x) by A8, FUNCT_1:18
.= x / ((f1 . x) + (f2 . x)) by A5, A8, VALUED_1:def 1
.= x / (1 + ((#Z 2) . x)) by A1, A8
.= x / (1 + (x #Z 2)) by TAYLOR_1:def 1
.= x / (1 + (x ^2)) by FDIFF_7:1 ;
hence f . x = x / (1 + (x ^2)) by A1; :: thesis: verum

end;

A9: for x being Element of REAL st x in dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) holds
(((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) implies (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x )
assume x in dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) ; :: thesis: (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x
then A10: x in Z by A6, FDIFF_1:def 7;
then (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = x / (1 + (x ^2)) by A1, A3, SIN_COS9:102
.= f . x by A10, A7 ;
hence (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) = dom f by A1, A6, FDIFF_1:def 7;
then ((1 / 2) (#) (ln * (f1 + f2))) `| Z = f by A9, PARTFUN1:5;
hence integral (f,A) = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A)) by A1, A2, A6, INTEGRA5:13; :: thesis: verum