let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & Z c= ].(- 1),1.[ & f = - ((exp_R * arccot) / (f1 + (#Z 2))) & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous holds
integral (f,A) = ((exp_R * arccot) . (upper_bound A)) - ((exp_R * arccot) . (lower_bound A))
let f, f1 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & Z c= ].(- 1),1.[ & f = - ((exp_R * arccot) / (f1 + (#Z 2))) & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous holds
integral (f,A) = ((exp_R * arccot) . (upper_bound A)) - ((exp_R * arccot) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & Z c= ].(- 1),1.[ & f = - ((exp_R * arccot) / (f1 + (#Z 2))) & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous implies integral (f,A) = ((exp_R * arccot) . (upper_bound A)) - ((exp_R * arccot) . (lower_bound A)) )
assume A1: ( A c= Z & Z c= ].(- 1),1.[ & f = - ((exp_R * arccot) / (f1 + (#Z 2))) & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((exp_R * arccot) . (upper_bound A)) - ((exp_R * arccot) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: Z = dom ((exp_R * arccot) / (f1 + (#Z 2))) by A1, VALUED_1:8;
then Z = (dom (exp_R * arccot)) /\ ((dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0})) by RFUNCT_1:def 1;
then A4: ( Z c= dom (exp_R * arccot) & Z c= (dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0}) ) by XBOOLE_1:18;
then A5: Z c= dom ((f1 + (#Z 2)) ^) by RFUNCT_1:def 2;
dom ((f1 + (#Z 2)) ^) c= dom (f1 + (#Z 2)) by RFUNCT_1:1;
then A6: Z c= dom (f1 + (#Z 2)) by A5;
A7: exp_R * arccot is_differentiable_on Z by A1, A4, SIN_COS9:120;
A8: for x being Real st x in Z holds
f . x = - ((exp_R . (arccot . x)) / (1 + (x ^2)))

proof

let x be Real; :: thesis: ( x in Z implies f . x = - ((exp_R . (arccot . x)) / (1 + (x ^2))) )
assume A9: x in Z ; :: thesis: f . x = - ((exp_R . (arccot . x)) / (1 + (x ^2)))
(- ((exp_R * arccot) / (f1 + (#Z 2)))) . x = - (((exp_R * arccot) / (f1 + (#Z 2))) . x) by VALUED_1:8
.= - (((exp_R * arccot) . x) / ((f1 + (#Z 2)) . x)) by A9, A3, RFUNCT_1:def 1
.= - ((exp_R . (arccot . x)) / ((f1 + (#Z 2)) . x)) by A4, A9, FUNCT_1:12
.= - ((exp_R . (arccot . x)) / ((f1 . x) + ((#Z 2) . x))) by A6, A9, VALUED_1:def 1
.= - ((exp_R . (arccot . x)) / (1 + ((#Z 2) . x))) by A1, A9
.= - ((exp_R . (arccot . x)) / (1 + (x #Z 2))) by TAYLOR_1:def 1
.= - ((exp_R . (arccot . x)) / (1 + (x ^2))) by FDIFF_7:1 ;
hence f . x = - ((exp_R . (arccot . x)) / (1 + (x ^2))) by A1; :: thesis: verum

end;

A10: for x being Element of REAL st x in dom ((exp_R * arccot) `| Z) holds
((exp_R * arccot) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((exp_R * arccot) `| Z) implies ((exp_R * arccot) `| Z) . x = f . x )
assume x in dom ((exp_R * arccot) `| Z) ; :: thesis: ((exp_R * arccot) `| Z) . x = f . x
then A11: x in Z by A7, FDIFF_1:def 7;
then ((exp_R * arccot) `| Z) . x = - ((exp_R . (arccot . x)) / (1 + (x ^2))) by A1, A4, SIN_COS9:120
.= f . x by A11, A8 ;
hence ((exp_R * arccot) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((exp_R * arccot) `| Z) = dom f by A1, A7, FDIFF_1:def 7;
then (exp_R * arccot) `| Z = f by A10, PARTFUN1:5;
hence integral (f,A) = ((exp_R * arccot) . (upper_bound A)) - ((exp_R * arccot) . (lower_bound A)) by A1, A2, A4, INTEGRA5:13, SIN_COS9:120; :: thesis: verum