let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arccot - ((id Z) / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous holds
integral (f,A) = (((id Z) (#) arccot) . (upper_bound A)) - (((id Z) (#) arccot) . (lower_bound A))
let f, f1 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arccot - ((id Z) / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous holds
integral (f,A) = (((id Z) (#) arccot) . (upper_bound A)) - (((id Z) (#) arccot) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arccot - ((id Z) / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous implies integral (f,A) = (((id Z) (#) arccot) . (upper_bound A)) - (((id Z) (#) arccot) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arccot - ((id Z) / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = (((id Z) (#) arccot) . (upper_bound A)) - (((id Z) (#) arccot) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
Z = (dom arccot) /\ (dom ((id Z) / (f1 + (#Z 2)))) by A1, VALUED_1:12;
then A3: ( Z c= dom arccot & Z c= dom ((id Z) / (f1 + (#Z 2))) ) by XBOOLE_1:18;
then Z c= (dom (id Z)) /\ ((dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0})) by RFUNCT_1:def 1;
then A4: Z c= (dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0}) by XBOOLE_1:18;
A5: (id Z) (#) arccot is_differentiable_on Z by A1, SIN_COS9:96;
A6: Z c= dom ((f1 + (#Z 2)) ^) by A4, RFUNCT_1:def 2;
dom ((f1 + (#Z 2)) ^) c= dom (f1 + (#Z 2)) by RFUNCT_1:1;
then A7: Z c= dom (f1 + (#Z 2)) by A6;
A8: for x being Real st x in Z holds
f . x = (arccot . x) - (x / (1 + (x ^2)))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (arccot . x) - (x / (1 + (x ^2))) )
assume A9: x in Z ; :: thesis: f . x = (arccot . x) - (x / (1 + (x ^2)))
then (arccot - ((id Z) / (f1 + (#Z 2)))) . x = (arccot . x) - (((id Z) / (f1 + (#Z 2))) . x) by A1, VALUED_1:13
.= (arccot . x) - (((id Z) . x) / ((f1 + (#Z 2)) . x)) by A3, A9, RFUNCT_1:def 1
.= (arccot . x) - (x / ((f1 + (#Z 2)) . x)) by A9, FUNCT_1:18
.= (arccot . x) - (x / ((f1 . x) + ((#Z 2) . x))) by A7, A9, VALUED_1:def 1
.= (arccot . x) - (x / (1 + ((#Z 2) . x))) by A1, A9
.= (arccot . x) - (x / (1 + (x #Z 2))) by TAYLOR_1:def 1
.= (arccot . x) - (x / (1 + (x ^2))) by FDIFF_7:1 ;
hence f . x = (arccot . x) - (x / (1 + (x ^2))) by A1; :: thesis: verum

end;

A10: for x being Element of REAL st x in dom (((id Z) (#) arccot) `| Z) holds
(((id Z) (#) arccot) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom (((id Z) (#) arccot) `| Z) implies (((id Z) (#) arccot) `| Z) . x = f . x )
assume x in dom (((id Z) (#) arccot) `| Z) ; :: thesis: (((id Z) (#) arccot) `| Z) . x = f . x
then A11: x in Z by A5, FDIFF_1:def 7;
then (((id Z) (#) arccot) `| Z) . x = (arccot . x) - (x / (1 + (x ^2))) by A1, SIN_COS9:96
.= f . x by A11, A8 ;
hence (((id Z) (#) arccot) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((id Z) (#) arccot) `| Z) = dom f by A1, A5, FDIFF_1:def 7;
then ((id Z) (#) arccot) `| Z = f by A10, PARTFUN1:5;
hence integral (f,A) = (((id Z) (#) arccot) . (upper_bound A)) - (((id Z) (#) arccot) . (lower_bound A)) by A1, A2, INTEGRA5:13, SIN_COS9:96; :: thesis: verum