let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arctan / (f1 + (#Z 2)) & Z c= ].(- 1),1.[ & Z c= dom ((#Z 2) * arctan) & Z = dom f & f | A is continuous holds
integral (f,A) = (((1 / 2) (#) ((#Z 2) * arctan)) . (upper_bound A)) - (((1 / 2) (#) ((#Z 2) * arctan)) . (lower_bound A))
let f, f1 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arctan / (f1 + (#Z 2)) & Z c= ].(- 1),1.[ & Z c= dom ((#Z 2) * arctan) & Z = dom f & f | A is continuous holds
integral (f,A) = (((1 / 2) (#) ((#Z 2) * arctan)) . (upper_bound A)) - (((1 / 2) (#) ((#Z 2) * arctan)) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arctan / (f1 + (#Z 2)) & Z c= ].(- 1),1.[ & Z c= dom ((#Z 2) * arctan) & Z = dom f & f | A is continuous implies integral (f,A) = (((1 / 2) (#) ((#Z 2) * arctan)) . (upper_bound A)) - (((1 / 2) (#) ((#Z 2) * arctan)) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = arctan / (f1 + (#Z 2)) & Z c= ].(- 1),1.[ & Z c= dom ((#Z 2) * arctan) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = (((1 / 2) (#) ((#Z 2) * arctan)) . (upper_bound A)) - (((1 / 2) (#) ((#Z 2) * arctan)) . (lower_bound A))
then A2: Z c= dom ((1 / 2) (#) ((#Z 2) * arctan)) by VALUED_1:def 5;
A3: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A4: (1 / 2) (#) ((#Z 2) * arctan) is_differentiable_on Z by A1, A2, SIN_COS9:93;
Z c= (dom arctan) /\ ((dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0})) by A1, RFUNCT_1:def 1;
then Z c= (dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0}) by XBOOLE_1:18;
then A5: Z c= dom ((f1 + (#Z 2)) ^) by RFUNCT_1:def 2;
dom ((f1 + (#Z 2)) ^) c= dom (f1 + (#Z 2)) by RFUNCT_1:1;
then A6: Z c= dom (f1 + (#Z 2)) by A5;
A7: for x being Real st x in Z holds
f . x = (arctan . x) / (1 + (x ^2))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (arctan . x) / (1 + (x ^2)) )
assume A8: x in Z ; :: thesis: f . x = (arctan . x) / (1 + (x ^2))
then (arctan / (f1 + (#Z 2))) . x = (arctan . x) / ((f1 + (#Z 2)) . x) by A1, RFUNCT_1:def 1
.= (arctan . x) / ((f1 . x) + ((#Z 2) . x)) by A6, A8, VALUED_1:def 1
.= (arctan . x) / ((f1 . x) + (x #Z 2)) by TAYLOR_1:def 1
.= (arctan . x) / (1 + (x #Z 2)) by A1, A8
.= (arctan . x) / (1 + (x ^2)) by FDIFF_7:1 ;
hence f . x = (arctan . x) / (1 + (x ^2)) by A1; :: thesis: verum

end;

A9: for x being Element of REAL st x in dom (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) holds
(((1 / 2) (#) ((#Z 2) * arctan)) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) implies (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) . x = f . x )
assume x in dom (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) ; :: thesis: (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) . x = f . x
then A10: x in Z by A4, FDIFF_1:def 7;
then (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) . x = (arctan . x) / (1 + (x ^2)) by A1, A2, SIN_COS9:93
.= f . x by A7, A10 ;
hence (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((1 / 2) (#) ((#Z 2) * arctan)) `| Z) = dom f by A1, A4, FDIFF_1:def 7;
then ((1 / 2) (#) ((#Z 2) * arctan)) `| Z = f by A9, PARTFUN1:5;
hence integral (f,A) = (((1 / 2) (#) ((#Z 2) * arctan)) . (upper_bound A)) - (((1 / 2) (#) ((#Z 2) * arctan)) . (lower_bound A)) by A1, A2, A3, INTEGRA5:13, SIN_COS9:93; :: thesis: verum