let Z be open Subset of REAL; :: thesis: ( Z c= dom (tan * ((id Z) ^)) implies ( - (tan * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2)) ) ) )
set f = id Z;
assume A1: Z c= dom (tan * ((id Z) ^)) ; :: thesis: ( - (tan * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2)) ) )
dom (tan * ((id Z) ^)) c= dom ((id Z) ^) by RELAT_1:25;
then A2: Z c= dom ((id Z) ^) by A1;
A3: not 0 in Z

proof

assume A4: 0 in Z ; :: thesis: contradiction
dom ((id Z) ^) = (dom (id Z)) \ ((id Z) " {0}) by RFUNCT_1:def 2
.= (dom (id Z)) \ {0} by Lm1, A4 ;
then not 0 in {0} by A4, A2, XBOOLE_0:def 5;
hence contradiction by TARSKI:def 1; :: thesis: verum

end;

A5: Z c= dom (- (tan * ((id Z) ^))) by A1, VALUED_1:8;
A6: tan * ((id Z) ^) is_differentiable_on Z by A1, A3, FDIFF_8:8;
then A7: (- 1) (#) (tan * ((id Z) ^)) is_differentiable_on Z by A5, FDIFF_1:20;
A8: ( (id Z) ^ is_differentiable_on Z & ( for x being Real st x in Z holds
(((id Z) ^) `| Z) . x = - (1 / (x ^2)) ) ) by A3, FDIFF_5:4;
A9: for x being Real st x in Z holds
cos . (((id Z) ^) . x) <> 0

proof

let x be Real; :: thesis: ( x in Z implies cos . (((id Z) ^) . x) <> 0 )
assume x in Z ; :: thesis: cos . (((id Z) ^) . x) <> 0
then ((id Z) ^) . x in dom (sin / cos) by A1, FUNCT_1:11;
hence cos . (((id Z) ^) . x) <> 0 by FDIFF_8:1; :: thesis: verum

end;

for x being Real st x in Z holds
((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2))

proof

let x be Real; :: thesis: ( x in Z implies ((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2)) )
assume A10: x in Z ; :: thesis: ((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2))
then A11: (id Z) ^ is_differentiable_in x by A8, FDIFF_1:9;
A12: cos . (((id Z) ^) . x) <> 0 by A9, A10;
then A13: tan is_differentiable_in ((id Z) ^) . x by FDIFF_7:46;
A14: tan * ((id Z) ^) is_differentiable_in x by A6, A10, FDIFF_1:9;
((- (tan * ((id Z) ^))) `| Z) . x = diff ((- (tan * ((id Z) ^))),x) by A7, A10, FDIFF_1:def 7
.= (- 1) * (diff ((tan * ((id Z) ^)),x)) by A14, FDIFF_1:15
.= (- 1) * ((diff (tan,(((id Z) ^) . x))) * (diff (((id Z) ^),x))) by A11, A13, FDIFF_2:13
.= (- 1) * ((1 / ((cos . (((id Z) ^) . x)) ^2)) * (diff (((id Z) ^),x))) by A12, FDIFF_7:46
.= (- 1) * ((diff (((id Z) ^),x)) / ((cos . (((id Z) . x) ")) ^2)) by A2, A10, RFUNCT_1:def 2
.= (- 1) * ((diff (((id Z) ^),x)) / ((cos . (1 * (x "))) ^2)) by A10, FUNCT_1:18
.= (- 1) * (((((id Z) ^) `| Z) . x) / ((cos . (1 * (x "))) ^2)) by A8, A10, FDIFF_1:def 7
.= (- 1) * ((- (1 / (x ^2))) / ((cos . (1 * (x "))) ^2)) by A10, A3, FDIFF_5:4
.= (- 1) * (((- 1) / (x ^2)) / ((cos . (1 / x)) ^2))
.= (- 1) * ((- 1) / ((x ^2) * ((cos . (1 / x)) ^2))) by XCMPLX_1:78
.= 1 / ((x ^2) * ((cos . (1 / x)) ^2)) ;
hence ((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2)) ; :: thesis: verum

end;

hence ( - (tan * ((id Z) ^)) is_differentiable_on Z & ( for x being Real st x in Z holds
((- (tan * ((id Z) ^))) `| Z) . x = 1 / ((x ^2) * ((cos . (1 / x)) ^2)) ) ) by A7; :: thesis: verum