let A be non empty closed_interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = exp_R / ((cos * exp_R) ^2) & Z c= dom (tan * exp_R) & Z = dom f & f | A is continuous holds
integral (f,A) = ((tan * exp_R) . (upper_bound A)) - ((tan * exp_R) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & f = exp_R / ((cos * exp_R) ^2) & Z c= dom (tan * exp_R) & Z = dom f & f | A is continuous holds
integral (f,A) = ((tan * exp_R) . (upper_bound A)) - ((tan * exp_R) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & f = exp_R / ((cos * exp_R) ^2) & Z c= dom (tan * exp_R) & Z = dom f & f | A is continuous implies integral (f,A) = ((tan * exp_R) . (upper_bound A)) - ((tan * exp_R) . (lower_bound A)) )
assume A1: ( A c= Z & f = exp_R / ((cos * exp_R) ^2) & Z c= dom (tan * exp_R) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((tan * exp_R) . (upper_bound A)) - ((tan * exp_R) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: tan * exp_R is_differentiable_on Z by A1, FDIFF_8:12;
Z = (dom exp_R) /\ ((dom ((cos * exp_R) ^2)) \ (((cos * exp_R) ^2) " {0})) by A1, RFUNCT_1:def 1;
then Z c= (dom ((cos * exp_R) ^2)) \ (((cos * exp_R) ^2) " {0}) by XBOOLE_1:18;
then A4: Z c= dom (((cos * exp_R) ^2) ^) by RFUNCT_1:def 2;
dom (((cos * exp_R) ^2) ^) c= dom ((cos * exp_R) ^2) by RFUNCT_1:1;
then Z c= dom ((cos * exp_R) ^2) by A4;
then A5: Z c= dom (cos * exp_R) by VALUED_1:11;
A6: for x being Real st x in Z holds
f . x = (exp_R . x) / ((cos . (exp_R . x)) ^2)

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . x) / ((cos . (exp_R . x)) ^2) )
assume A7: x in Z ; :: thesis: f . x = (exp_R . x) / ((cos . (exp_R . x)) ^2)
then (exp_R / ((cos * exp_R) ^2)) . x = (exp_R . x) / (((cos * exp_R) ^2) . x) by A1, RFUNCT_1:def 1
.= (exp_R . x) / (((cos * exp_R) . x) ^2) by VALUED_1:11
.= (exp_R . x) / ((cos . (exp_R . x)) ^2) by A5, A7, FUNCT_1:12 ;
hence f . x = (exp_R . x) / ((cos . (exp_R . x)) ^2) by A1; :: thesis: verum

end;

A8: for x being Element of REAL st x in dom ((tan * exp_R) `| Z) holds
((tan * exp_R) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((tan * exp_R) `| Z) implies ((tan * exp_R) `| Z) . x = f . x )
assume x in dom ((tan * exp_R) `| Z) ; :: thesis: ((tan * exp_R) `| Z) . x = f . x
then A9: x in Z by A3, FDIFF_1:def 7;
then ((tan * exp_R) `| Z) . x = (exp_R . x) / ((cos . (exp_R . x)) ^2) by A1, FDIFF_8:12
.= f . x by A6, A9 ;
hence ((tan * exp_R) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((tan * exp_R) `| Z) = dom f by A1, A3, FDIFF_1:def 7;
then (tan * exp_R) `| Z = f by A8, PARTFUN1:5;
hence integral (f,A) = ((tan * exp_R) . (upper_bound A)) - ((tan * exp_R) . (lower_bound A)) by A1, A2, FDIFF_8:12, INTEGRA5:13; :: thesis: verum