let A be non empty closed_interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = ((id Z) (#) ((sin * ln) ^2)) ^ & Z c= dom (cot * ln) & Z = dom f & f | A is continuous holds
integral (f,A) = ((- (cot * ln)) . (upper_bound A)) - ((- (cot * ln)) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & f = ((id Z) (#) ((sin * ln) ^2)) ^ & Z c= dom (cot * ln) & Z = dom f & f | A is continuous holds
integral (f,A) = ((- (cot * ln)) . (upper_bound A)) - ((- (cot * ln)) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & f = ((id Z) (#) ((sin * ln) ^2)) ^ & Z c= dom (cot * ln) & Z = dom f & f | A is continuous implies integral (f,A) = ((- (cot * ln)) . (upper_bound A)) - ((- (cot * ln)) . (lower_bound A)) )
assume A1: ( A c= Z & f = ((id Z) (#) ((sin * ln) ^2)) ^ & Z c= dom (cot * ln) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((- (cot * ln)) . (upper_bound A)) - ((- (cot * ln)) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: - (cot * ln) is_differentiable_on Z by A1, Th27;
Z c= dom ((id Z) (#) ((sin * ln) ^2)) by A1, RFUNCT_1:1;
then Z c= (dom (id Z)) /\ (dom ((sin * ln) ^2)) by VALUED_1:def 4;
then Z c= dom ((sin * ln) ^2) by XBOOLE_1:18;
then A4: Z c= dom (sin * ln) by VALUED_1:11;
A5: for x being Real st x in Z holds
f . x = 1 / (x * ((sin . (ln . x)) ^2))

proof

let x be Real; :: thesis: ( x in Z implies f . x = 1 / (x * ((sin . (ln . x)) ^2)) )
assume A6: x in Z ; :: thesis: f . x = 1 / (x * ((sin . (ln . x)) ^2))
then (((id Z) (#) ((sin * ln) ^2)) ^) . x = 1 / (((id Z) (#) ((sin * ln) ^2)) . x) by A1, RFUNCT_1:def 2
.= 1 / (((id Z) . x) * (((sin * ln) ^2) . x)) by VALUED_1:5
.= 1 / (x * (((sin * ln) ^2) . x)) by A6, FUNCT_1:18
.= 1 / (x * (((sin * ln) . x) ^2)) by VALUED_1:11
.= 1 / (x * ((sin . (ln . x)) ^2)) by A4, A6, FUNCT_1:12 ;
hence f . x = 1 / (x * ((sin . (ln . x)) ^2)) by A1; :: thesis: verum

end;

A7: for x being Element of REAL st x in dom ((- (cot * ln)) `| Z) holds
((- (cot * ln)) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((- (cot * ln)) `| Z) implies ((- (cot * ln)) `| Z) . x = f . x )
assume x in dom ((- (cot * ln)) `| Z) ; :: thesis: ((- (cot * ln)) `| Z) . x = f . x
then A8: x in Z by A3, FDIFF_1:def 7;
then ((- (cot * ln)) `| Z) . x = 1 / (x * ((sin . (ln . x)) ^2)) by A1, Th27
.= f . x by A5, A8 ;
hence ((- (cot * ln)) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((- (cot * ln)) `| Z) = dom f by A1, A3, FDIFF_1:def 7;
then (- (cot * ln)) `| Z = f by A7, PARTFUN1:5;
hence integral (f,A) = ((- (cot * ln)) . (upper_bound A)) - ((- (cot * ln)) . (lower_bound A)) by A1, A2, Th27, INTEGRA5:13; :: thesis: verum