let A be non empty closed_interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = (exp_R * tan) / (cos ^2) & Z = dom f & f | A is continuous holds
integral (f,A) = ((exp_R * tan) . (upper_bound A)) - ((exp_R * tan) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & f = (exp_R * tan) / (cos ^2) & Z = dom f & f | A is continuous holds
integral (f,A) = ((exp_R * tan) . (upper_bound A)) - ((exp_R * tan) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & f = (exp_R * tan) / (cos ^2) & Z = dom f & f | A is continuous implies integral (f,A) = ((exp_R * tan) . (upper_bound A)) - ((exp_R * tan) . (lower_bound A)) )
assume A1: ( A c= Z & f = (exp_R * tan) / (cos ^2) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((exp_R * tan) . (upper_bound A)) - ((exp_R * tan) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
Z = (dom (exp_R * tan)) /\ ((dom (cos ^2)) \ ((cos ^2) " {0})) by A1, RFUNCT_1:def 1;
then A3: Z c= dom (exp_R * tan) by XBOOLE_1:18;
then A4: exp_R * tan is_differentiable_on Z by FDIFF_8:16;
A5: for x being Real st x in Z holds
f . x = (exp_R . (tan . x)) / ((cos . x) ^2)

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . (tan . x)) / ((cos . x) ^2) )
assume A6: x in Z ; :: thesis: f . x = (exp_R . (tan . x)) / ((cos . x) ^2)
then ((exp_R * tan) / (cos ^2)) . x = ((exp_R * tan) . x) / ((cos ^2) . x) by A1, RFUNCT_1:def 1
.= (exp_R . (tan . x)) / ((cos ^2) . x) by A3, A6, FUNCT_1:12
.= (exp_R . (tan . x)) / ((cos . x) ^2) by VALUED_1:11 ;
hence f . x = (exp_R . (tan . x)) / ((cos . x) ^2) by A1; :: thesis: verum

end;

A7: for x being Element of REAL st x in dom ((exp_R * tan) `| Z) holds
((exp_R * tan) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((exp_R * tan) `| Z) implies ((exp_R * tan) `| Z) . x = f . x )
assume x in dom ((exp_R * tan) `| Z) ; :: thesis: ((exp_R * tan) `| Z) . x = f . x
then A8: x in Z by A4, FDIFF_1:def 7;
then ((exp_R * tan) `| Z) . x = (exp_R . (tan . x)) / ((cos . x) ^2) by A3, FDIFF_8:16
.= f . x by A5, A8 ;
hence ((exp_R * tan) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((exp_R * tan) `| Z) = dom f by A1, A4, FDIFF_1:def 7;
then (exp_R * tan) `| Z = f by A7, PARTFUN1:5;
hence integral (f,A) = ((exp_R * tan) . (upper_bound A)) - ((exp_R * tan) . (lower_bound A)) by A1, A2, A3, FDIFF_8:16, INTEGRA5:13; :: thesis: verum