let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (id Z)) + (ln / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous holds
integral (f,A) = ((ln (#) arctan) . (upper_bound A)) - ((ln (#) arctan) . (lower_bound A))
let f, f1 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (id Z)) + (ln / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous holds
integral (f,A) = ((ln (#) arctan) . (upper_bound A)) - ((ln (#) arctan) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (id Z)) + (ln / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous implies integral (f,A) = ((ln (#) arctan) . (upper_bound A)) - ((ln (#) arctan) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & f = (arctan / (id Z)) + (ln / (f1 + (#Z 2))) & Z c= ].(- 1),1.[ & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((ln (#) arctan) . (upper_bound A)) - ((ln (#) arctan) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
Z = (dom (arctan / (id Z))) /\ (dom (ln / (f1 + (#Z 2)))) by A1, VALUED_1:def 1;
then A3: ( Z c= dom (arctan / (id Z)) & Z c= dom (ln / (f1 + (#Z 2))) ) by XBOOLE_1:18;
then Z c= (dom arctan) /\ ((dom (id Z)) \ ((id Z) " {0})) by RFUNCT_1:def 1;
then A4: Z c= dom arctan by XBOOLE_1:18;
Z c= (dom ln) /\ ((dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0})) by A3, RFUNCT_1:def 1;
then A5: ( Z c= dom ln & Z c= (dom (f1 + (#Z 2))) \ ((f1 + (#Z 2)) " {0}) ) by XBOOLE_1:18;
then Z c= (dom arctan) /\ (dom ln) by A4, XBOOLE_1:19;
then A6: Z c= dom (ln (#) arctan) by VALUED_1:def 4;
then A7: ln (#) arctan is_differentiable_on Z by A1, SIN_COS9:127;
A8: Z c= dom ((f1 + (#Z 2)) ^) by A5, RFUNCT_1:def 2;
dom ((f1 + (#Z 2)) ^) c= dom (f1 + (#Z 2)) by RFUNCT_1:1;
then A9: Z c= dom (f1 + (#Z 2)) by A8;
A10: for x being Real st x in Z holds
f . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2)))

proof

let x be Real; :: thesis: ( x in Z implies f . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2))) )
assume A11: x in Z ; :: thesis: f . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2)))
then ((arctan / (id Z)) + (ln / (f1 + (#Z 2)))) . x = ((arctan / (id Z)) . x) + ((ln / (f1 + (#Z 2))) . x) by A1, VALUED_1:def 1
.= ((arctan . x) * (((id Z) . x) ")) + ((ln / (f1 + (#Z 2))) . x) by A3, A11, RFUNCT_1:def 1
.= ((arctan . x) * (((id Z) . x) ")) + ((ln . x) * (((f1 + (#Z 2)) . x) ")) by A3, A11, RFUNCT_1:def 1
.= ((arctan . x) / x) + ((ln . x) / ((f1 + (#Z 2)) . x)) by A11, FUNCT_1:18
.= ((arctan . x) / x) + ((ln . x) / ((f1 . x) + ((#Z 2) . x))) by A9, A11, VALUED_1:def 1
.= ((arctan . x) / x) + ((ln . x) / (1 + ((#Z 2) . x))) by A1, A11
.= ((arctan . x) / x) + ((ln . x) / (1 + (x #Z 2))) by TAYLOR_1:def 1
.= ((arctan . x) / x) + ((ln . x) / (1 + (x ^2))) by FDIFF_7:1 ;
hence f . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2))) by A1; :: thesis: verum

end;

A12: for x being Element of REAL st x in dom ((ln (#) arctan) `| Z) holds
((ln (#) arctan) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((ln (#) arctan) `| Z) implies ((ln (#) arctan) `| Z) . x = f . x )
assume x in dom ((ln (#) arctan) `| Z) ; :: thesis: ((ln (#) arctan) `| Z) . x = f . x
then A13: x in Z by A7, FDIFF_1:def 7;
then ((ln (#) arctan) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2))) by A1, A6, SIN_COS9:127
.= f . x by A13, A10 ;
hence ((ln (#) arctan) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((ln (#) arctan) `| Z) = dom f by A1, A7, FDIFF_1:def 7;
then (ln (#) arctan) `| Z = f by A12, PARTFUN1:5;
hence integral (f,A) = ((ln (#) arctan) . (upper_bound A)) - ((ln (#) arctan) . (lower_bound A)) by A1, A2, A6, INTEGRA5:13, SIN_COS9:127; :: thesis: verum