let A be non empty closed_interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = (tan / (id Z)) + (ln / (cos ^2)) & Z c= dom (ln (#) tan) & Z c= dom tan & Z = dom f & f | A is continuous holds
integral (f,A) = ((ln (#) tan) . (upper_bound A)) - ((ln (#) tan) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & f = (tan / (id Z)) + (ln / (cos ^2)) & Z c= dom (ln (#) tan) & Z c= dom tan & Z = dom f & f | A is continuous holds
integral (f,A) = ((ln (#) tan) . (upper_bound A)) - ((ln (#) tan) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & f = (tan / (id Z)) + (ln / (cos ^2)) & Z c= dom (ln (#) tan) & Z c= dom tan & Z = dom f & f | A is continuous implies integral (f,A) = ((ln (#) tan) . (upper_bound A)) - ((ln (#) tan) . (lower_bound A)) )
assume A1: ( A c= Z & f = (tan / (id Z)) + (ln / (cos ^2)) & Z c= dom (ln (#) tan) & Z c= dom tan & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((ln (#) tan) . (upper_bound A)) - ((ln (#) tan) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: ln (#) tan is_differentiable_on Z by A1, FDIFF_8:32;
Z = (dom (tan / (id Z))) /\ (dom (ln / (cos ^2))) by A1, VALUED_1:def 1;
then A4: ( Z c= dom (tan / (id Z)) & Z c= dom (ln / (cos ^2)) ) by XBOOLE_1:18;
A5: for x being Real st x in Z holds
f . x = ((tan . x) / x) + ((ln . x) / ((cos . x) ^2))

proof

let x be Real; :: thesis: ( x in Z implies f . x = ((tan . x) / x) + ((ln . x) / ((cos . x) ^2)) )
assume A6: x in Z ; :: thesis: f . x = ((tan . x) / x) + ((ln . x) / ((cos . x) ^2))
then ((tan / (id Z)) + (ln / (cos ^2))) . x = ((tan / (id Z)) . x) + ((ln / (cos ^2)) . x) by A1, VALUED_1:def 1
.= ((tan . x) / ((id Z) . x)) + ((ln / (cos ^2)) . x) by A6, A4, RFUNCT_1:def 1
.= ((tan . x) / x) + ((ln / (cos ^2)) . x) by A6, FUNCT_1:18
.= ((tan . x) / x) + ((ln . x) / ((cos ^2) . x)) by A6, A4, RFUNCT_1:def 1
.= ((tan . x) / x) + ((ln . x) / ((cos . x) ^2)) by VALUED_1:11 ;
hence f . x = ((tan . x) / x) + ((ln . x) / ((cos . x) ^2)) by A1; :: thesis: verum

end;

A7: for x being Element of REAL st x in dom ((ln (#) tan) `| Z) holds
((ln (#) tan) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((ln (#) tan) `| Z) implies ((ln (#) tan) `| Z) . x = f . x )
assume x in dom ((ln (#) tan) `| Z) ; :: thesis: ((ln (#) tan) `| Z) . x = f . x
then A8: x in Z by A3, FDIFF_1:def 7;
then ((ln (#) tan) `| Z) . x = ((tan x) / x) + ((ln . x) / ((cos . x) ^2)) by A1, FDIFF_8:32
.= ((tan . x) / x) + ((ln . x) / ((cos . x) ^2)) by A1, A8, FDIFF_8:1, SIN_COS9:15
.= f . x by A8, A5 ;
hence ((ln (#) tan) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((ln (#) tan) `| Z) = dom f by A1, A3, FDIFF_1:def 7;
then (ln (#) tan) `| Z = f by A7, PARTFUN1:5;
hence integral (f,A) = ((ln (#) tan) . (upper_bound A)) - ((ln (#) tan) . (lower_bound A)) by A1, A2, FDIFF_8:32, INTEGRA5:13; :: thesis: verum