let A be non empty closed_interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & Z = dom f & f = (exp_R * sin) (#) cos holds
integral (f,A) = ((exp_R * sin) . (upper_bound A)) - ((exp_R * sin) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & Z = dom f & f = (exp_R * sin) (#) cos holds
integral (f,A) = ((exp_R * sin) . (upper_bound A)) - ((exp_R * sin) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & Z = dom f & f = (exp_R * sin) (#) cos implies integral (f,A) = ((exp_R * sin) . (upper_bound A)) - ((exp_R * sin) . (lower_bound A)) )
assume A1: ( A c= Z & Z = dom f & f = (exp_R * sin) (#) cos ) ; :: thesis: integral (f,A) = ((exp_R * sin) . (upper_bound A)) - ((exp_R * sin) . (lower_bound A))
then Z = (dom (exp_R * sin)) /\ (dom cos) by VALUED_1:def 4;
then A2: Z c= dom (exp_R * sin) by XBOOLE_1:18;
then A3: exp_R * sin is_differentiable_on Z by FDIFF_7:37;
cos is_differentiable_on Z by FDIFF_1:26, SIN_COS:67;
then f | Z is continuous by A1, A3, FDIFF_1:21, FDIFF_1:25;
then f | A is continuous by A1, FCONT_1:16;
then A4: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A5: for x being Real st x in Z holds
f . x = (exp_R . (sin . x)) * (cos . x)

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . (sin . x)) * (cos . x) )
assume A6: x in Z ; :: thesis: f . x = (exp_R . (sin . x)) * (cos . x)
then ((exp_R * sin) (#) cos) . x = ((exp_R * sin) . x) * (cos . x) by A1, VALUED_1:def 4
.= (exp_R . (sin . x)) * (cos . x) by A2, A6, FUNCT_1:12 ;
hence f . x = (exp_R . (sin . x)) * (cos . x) by A1; :: thesis: verum

end;

A7: for x being Element of REAL st x in dom ((exp_R * sin) `| Z) holds
((exp_R * sin) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((exp_R * sin) `| Z) implies ((exp_R * sin) `| Z) . x = f . x )
assume x in dom ((exp_R * sin) `| Z) ; :: thesis: ((exp_R * sin) `| Z) . x = f . x
then A8: x in Z by A3, FDIFF_1:def 7;
then ((exp_R * sin) `| Z) . x = (exp_R . (sin . x)) * (cos . x) by A2, FDIFF_7:37
.= f . x by A5, A8 ;
hence ((exp_R * sin) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((exp_R * sin) `| Z) = dom f by A1, A3, FDIFF_1:def 7;
then (exp_R * sin) `| Z = f by A7, PARTFUN1:5;
hence integral (f,A) = ((exp_R * sin) . (upper_bound A)) - ((exp_R * sin) . (lower_bound A)) by A1, A2, A4, FDIFF_7:37, INTEGRA5:13; :: thesis: verum