let n be Element of NAT ; :: thesis: for A being non empty closed_interval Subset of REAL
for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = (n (#) ((#Z (n - 1)) * cos)) / ((#Z (n + 1)) * sin) & 1 <= n & Z c= dom ((#Z n) * cot) & Z = dom f holds
integral (f,A) = ((- ((#Z n) * cot)) . (upper_bound A)) - ((- ((#Z n) * cot)) . (lower_bound A))
let A be non empty closed_interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = (n (#) ((#Z (n - 1)) * cos)) / ((#Z (n + 1)) * sin) & 1 <= n & Z c= dom ((#Z n) * cot) & Z = dom f holds
integral (f,A) = ((- ((#Z n) * cot)) . (upper_bound A)) - ((- ((#Z n) * cot)) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & f = (n (#) ((#Z (n - 1)) * cos)) / ((#Z (n + 1)) * sin) & 1 <= n & Z c= dom ((#Z n) * cot) & Z = dom f holds
integral (f,A) = ((- ((#Z n) * cot)) . (upper_bound A)) - ((- ((#Z n) * cot)) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & f = (n (#) ((#Z (n - 1)) * cos)) / ((#Z (n + 1)) * sin) & 1 <= n & Z c= dom ((#Z n) * cot) & Z = dom f implies integral (f,A) = ((- ((#Z n) * cot)) . (upper_bound A)) - ((- ((#Z n) * cot)) . (lower_bound A)) )
assume A1: ( A c= Z & f = (n (#) ((#Z (n - 1)) * cos)) / ((#Z (n + 1)) * sin) & 1 <= n & Z c= dom ((#Z n) * cot) & Z = dom f ) ; :: thesis: integral (f,A) = ((- ((#Z n) * cot)) . (upper_bound A)) - ((- ((#Z n) * cot)) . (lower_bound A))
then Z = (dom (n (#) ((#Z (n - 1)) * cos))) /\ ((dom ((#Z (n + 1)) * sin)) \ (((#Z (n + 1)) * sin) " {0})) by RFUNCT_1:def 1;
then A2: ( Z c= dom (n (#) ((#Z (n - 1)) * cos)) & Z c= (dom ((#Z (n + 1)) * sin)) \ (((#Z (n + 1)) * sin) " {0}) ) by XBOOLE_1:18;
then A3: Z c= dom (((#Z (n + 1)) * sin) ^) by RFUNCT_1:def 2;
dom (((#Z (n + 1)) * sin) ^) c= dom ((#Z (n + 1)) * sin) by RFUNCT_1:1;
then A4: Z c= dom ((#Z (n + 1)) * sin) by A3;
A5: for x being Real st x in Z holds
((#Z (n + 1)) * sin) . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies ((#Z (n + 1)) * sin) . x <> 0 )
assume x in Z ; :: thesis: ((#Z (n + 1)) * sin) . x <> 0
then x in (dom (n (#) ((#Z (n - 1)) * cos))) /\ ((dom ((#Z (n + 1)) * sin)) \ (((#Z (n + 1)) * sin) " {0})) by A1, RFUNCT_1:def 1;
then x in (dom ((#Z (n + 1)) * sin)) \ (((#Z (n + 1)) * sin) " {0}) by XBOOLE_0:def 4;
then x in dom (((#Z (n + 1)) * sin) ^) by RFUNCT_1:def 2;
hence ((#Z (n + 1)) * sin) . x <> 0 by RFUNCT_1:3; :: thesis: verum

end;

A6: Z c= dom ((#Z (n - 1)) * cos) by A2, VALUED_1:def 5;
A7: for x being Real holds (#Z (n - 1)) * cos is_differentiable_in x

proof

let x be Real; :: thesis: (#Z (n - 1)) * cos is_differentiable_in x
consider m being Nat such that
A8: n = m + 1 by A1, NAT_1:6;
cos is_differentiable_in x by SIN_COS:63;
hence (#Z (n - 1)) * cos is_differentiable_in x by A8, TAYLOR_1:3; :: thesis: verum

end;

(#Z (n - 1)) * cos is_differentiable_on Z

proof

for x being Real st x in Z holds
(#Z (n - 1)) * cos is_differentiable_in x by A7;
hence (#Z (n - 1)) * cos is_differentiable_on Z by A6, FDIFF_1:9; :: thesis: verum

end;

then A9: n (#) ((#Z (n - 1)) * cos) is_differentiable_on Z by A2, FDIFF_1:20;
A10: for x being Real holds (#Z (n + 1)) * sin is_differentiable_in x

proof

let x be Real; :: thesis: (#Z (n + 1)) * sin is_differentiable_in x
sin is_differentiable_in x by SIN_COS:64;
hence (#Z (n + 1)) * sin is_differentiable_in x by TAYLOR_1:3; :: thesis: verum

end;

(#Z (n + 1)) * sin is_differentiable_on Z

proof

for x being Real st x in Z holds
(#Z (n + 1)) * sin is_differentiable_in x by A10;
hence (#Z (n + 1)) * sin is_differentiable_on Z by A4, FDIFF_1:9; :: thesis: verum

end;

then f | Z is continuous by A1, A5, A9, FDIFF_1:25, FDIFF_2:21;
then f | A is continuous by A1, FCONT_1:16;
then A11: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A12: (#Z n) * cot is_differentiable_on Z by A1, FDIFF_8:21;
A13: dom ((#Z n) * cot) c= dom cot by RELAT_1:25;
A14: Z c= dom (- ((#Z n) * cot)) by A1, VALUED_1:8;
then A15: (- 1) (#) ((#Z n) * cot) is_differentiable_on Z by A12, FDIFF_1:20;
A16: for x being Real st x in Z holds
sin . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies sin . x <> 0 )
assume x in Z ; :: thesis: sin . x <> 0
then x in dom (cos / sin) by A1, FUNCT_1:11;
hence sin . x <> 0 by FDIFF_8:2; :: thesis: verum

end;

A17: for x being Real st x in Z holds
((- ((#Z n) * cot)) `| Z) . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1))

proof

let x be Real; :: thesis: ( x in Z implies ((- ((#Z n) * cot)) `| Z) . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) )
assume A18: x in Z ; :: thesis: ((- ((#Z n) * cot)) `| Z) . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1))
then A19: sin . x <> 0 by A16;
then A20: cot is_differentiable_in x by FDIFF_7:47;
consider m being Nat such that
A21: n = m + 1 by A1, NAT_1:6;
set m = n - 1;
A22: (#Z n) * cot is_differentiable_in x by A12, A18, FDIFF_1:9;
((- ((#Z n) * cot)) `| Z) . x = diff ((- ((#Z n) * cot)),x) by A15, A18, FDIFF_1:def 7
.= (- 1) * (diff (((#Z n) * cot),x)) by A22, FDIFF_1:15
.= (- 1) * ((n * ((cot . x) #Z (n - 1))) * (diff (cot,x))) by A20, TAYLOR_1:3
.= (- 1) * ((n * ((cot . x) #Z (n - 1))) * (- (1 / ((sin . x) ^2)))) by A19, FDIFF_7:47
.= (- 1) * (- ((n * ((cot . x) #Z (n - 1))) / ((sin . x) ^2)))
.= (- 1) * (- ((n * (((cos . x) #Z (n - 1)) / ((sin . x) #Z (n - 1)))) / ((sin . x) ^2))) by A1, A13, A18, A21, FDIFF_8:3, XBOOLE_1:1
.= (- 1) * (- (((n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n - 1))) / ((sin . x) ^2)))
.= (- 1) * (- ((n * ((cos . x) #Z (n - 1))) / (((sin . x) #Z (n - 1)) * ((sin . x) ^2)))) by XCMPLX_1:78
.= (- 1) * (- ((n * ((cos . x) #Z (n - 1))) / (((sin . x) #Z (n - 1)) * ((sin . x) #Z 2)))) by FDIFF_7:1
.= (- 1) * (- ((n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z ((n - 1) + 2)))) by A16, A18, PREPOWER:44
.= (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) ;
hence ((- ((#Z n) * cot)) `| Z) . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) ; :: thesis: verum

end;

A23: for x being Real st x in Z holds
f . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) )
assume A24: x in Z ; :: thesis: f . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1))
then ((n (#) ((#Z (n - 1)) * cos)) / ((#Z (n + 1)) * sin)) . x = ((n (#) ((#Z (n - 1)) * cos)) . x) / (((#Z (n + 1)) * sin) . x) by A1, RFUNCT_1:def 1
.= (n * (((#Z (n - 1)) * cos) . x)) / (((#Z (n + 1)) * sin) . x) by VALUED_1:6
.= (n * ((#Z (n - 1)) . (cos . x))) / (((#Z (n + 1)) * sin) . x) by A6, A24, FUNCT_1:12
.= (n * ((cos . x) #Z (n - 1))) / (((#Z (n + 1)) * sin) . x) by TAYLOR_1:def 1
.= (n * ((cos . x) #Z (n - 1))) / ((#Z (n + 1)) . (sin . x)) by A4, A24, FUNCT_1:12
.= (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) by TAYLOR_1:def 1 ;
hence f . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) by A1; :: thesis: verum

end;

A25: for x being Element of REAL st x in dom ((- ((#Z n) * cot)) `| Z) holds
((- ((#Z n) * cot)) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom ((- ((#Z n) * cot)) `| Z) implies ((- ((#Z n) * cot)) `| Z) . x = f . x )
assume x in dom ((- ((#Z n) * cot)) `| Z) ; :: thesis: ((- ((#Z n) * cot)) `| Z) . x = f . x
then A26: x in Z by A15, FDIFF_1:def 7;
then ((- ((#Z n) * cot)) `| Z) . x = (n * ((cos . x) #Z (n - 1))) / ((sin . x) #Z (n + 1)) by A17
.= f . x by A23, A26 ;
hence ((- ((#Z n) * cot)) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((- ((#Z n) * cot)) `| Z) = dom f by A1, A15, FDIFF_1:def 7;
then (- ((#Z n) * cot)) `| Z = f by A25, PARTFUN1:5;
hence integral (f,A) = ((- ((#Z n) * cot)) . (upper_bound A)) - ((- ((#Z n) * cot)) . (lower_bound A)) by A1, A11, A12, A14, FDIFF_1:20, INTEGRA5:13; :: thesis: verum