let A be non empty closed_interval Subset of REAL; :: thesis: for f, f1 being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = arcsin + ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2)))) holds
integral (f,A) = (((id Z) (#) arcsin) . (upper_bound A)) - (((id Z) (#) arcsin) . (lower_bound A))
let f, f1 be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = arcsin + ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2)))) holds
integral (f,A) = (((id Z) (#) arcsin) . (upper_bound A)) - (((id Z) (#) arcsin) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = arcsin + ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2)))) implies integral (f,A) = (((id Z) (#) arcsin) . (upper_bound A)) - (((id Z) (#) arcsin) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z c= ].(- 1),1.[ & Z = dom f & f = arcsin + ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2)))) ) ; :: thesis: integral (f,A) = (((id Z) (#) arcsin) . (upper_bound A)) - (((id Z) (#) arcsin) . (lower_bound A))
then Z = (dom arcsin) /\ (dom ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2))))) by VALUED_1:def 1;
then A2: ( Z c= dom arcsin & Z c= dom ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2)))) ) by XBOOLE_1:18;
A3: Z = dom (id Z) ;
Z c= (dom (id Z)) /\ (dom arcsin) by A2, XBOOLE_1:19;
then A4: Z c= dom ((id Z) (#) arcsin) by VALUED_1:def 4;
A5: arcsin is_differentiable_on Z by A1, FDIFF_1:26, SIN_COS6:83;
for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:18;
then A6: id Z is_differentiable_on Z by A3, FDIFF_1:23;
Z c= (dom (id Z)) /\ ((dom ((#R (1 / 2)) * (f1 - (#Z 2)))) \ (((#R (1 / 2)) * (f1 - (#Z 2))) " {0})) by A2, RFUNCT_1:def 1;
then Z c= (dom ((#R (1 / 2)) * (f1 - (#Z 2)))) \ (((#R (1 / 2)) * (f1 - (#Z 2))) " {0}) by XBOOLE_1:18;
then A7: Z c= dom (((#R (1 / 2)) * (f1 - (#Z 2))) ^) by RFUNCT_1:def 2;
dom (((#R (1 / 2)) * (f1 - (#Z 2))) ^) c= dom ((#R (1 / 2)) * (f1 - (#Z 2))) by RFUNCT_1:1;
then A8: Z c= dom ((#R (1 / 2)) * (f1 - (#Z 2))) by A7;
set f2 = #Z 2;
for x being Real st x in Z holds
(f1 - (#Z 2)) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (f1 - (#Z 2)) . x > 0 )
assume A9: x in Z ; :: thesis: (f1 - (#Z 2)) . x > 0
then ( - 1 < x & x < 1 ) by A1, XXREAL_1:4;
then ( 0 < 1 + x & 0 < 1 - x ) by XREAL_1:50, XREAL_1:148;
then A10: 0 < (1 + x) * (1 - x) by XREAL_1:129;
for x being Real st x in Z holds
x in dom (f1 - (#Z 2)) by A8, FUNCT_1:11;
then (f1 - (#Z 2)) . x = (f1 . x) - ((#Z 2) . x) by A9, VALUED_1:13
.= (f1 . x) - (x #Z (1 + 1)) by TAYLOR_1:def 1
.= (f1 . x) - ((x #Z 1) * (x #Z 1)) by TAYLOR_1:1
.= (f1 . x) - (x * (x #Z 1)) by PREPOWER:35
.= (f1 . x) - (x * x) by PREPOWER:35
.= 1 - (x * x) by A1, A9 ;
hence (f1 - (#Z 2)) . x > 0 by A10; :: thesis: verum

end;

then for x being Real st x in Z holds
( f1 . x = 1 & (f1 - (#Z 2)) . x > 0 ) by A1;
then A11: (#R (1 / 2)) * (f1 - (#Z 2)) is_differentiable_on Z by A8, FDIFF_7:22;
for x being Real st x in Z holds
((#R (1 / 2)) * (f1 - (#Z 2))) . x <> 0 by A7, RFUNCT_1:3;
then (id Z) / ((#R (1 / 2)) * (f1 - (#Z 2))) is_differentiable_on Z by A6, A11, FDIFF_2:21;
then f | Z is continuous by A1, A5, FDIFF_1:18, FDIFF_1:25;
then f | A is continuous by A1, FCONT_1:16;
then A12: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A13: (id Z) (#) arcsin is_differentiable_on Z by A1, A4, FDIFF_7:16;
A14: for x being Real st x in Z holds
f . x = (arcsin . x) + (x / (sqrt (1 - (x ^2))))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (arcsin . x) + (x / (sqrt (1 - (x ^2)))) )
assume A15: x in Z ; :: thesis: f . x = (arcsin . x) + (x / (sqrt (1 - (x ^2))))
then A16: ( x in dom (f1 - (#Z 2)) & (f1 - (#Z 2)) . x in dom (#R (1 / 2)) ) by A8, FUNCT_1:11;
then A17: (f1 - (#Z 2)) . x in right_open_halfline 0 by TAYLOR_1:def 4;
( - 1 < x & x < 1 ) by A1, A15, XXREAL_1:4;
then ( 0 < 1 + x & 0 < 1 - x ) by XREAL_1:50, XREAL_1:148;
then A18: 0 < (1 + x) * (1 - x) by XREAL_1:129;
(arcsin + ((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2))))) . x = (arcsin . x) + (((id Z) / ((#R (1 / 2)) * (f1 - (#Z 2)))) . x) by A1, A15, VALUED_1:def 1
.= (arcsin . x) + (((id Z) . x) / (((#R (1 / 2)) * (f1 - (#Z 2))) . x)) by A2, A15, RFUNCT_1:def 1
.= (arcsin . x) + (x / (((#R (1 / 2)) * (f1 - (#Z 2))) . x)) by A15, FUNCT_1:18
.= (arcsin . x) + (x / ((#R (1 / 2)) . ((f1 - (#Z 2)) . x))) by A8, A15, FUNCT_1:12
.= (arcsin . x) + (x / (((f1 - (#Z 2)) . x) #R (1 / 2))) by A17, TAYLOR_1:def 4
.= (arcsin . x) + (x / (((f1 . x) - ((#Z 2) . x)) #R (1 / 2))) by A16, VALUED_1:13
.= (arcsin . x) + (x / (((f1 . x) - (x #Z 2)) #R (1 / 2))) by TAYLOR_1:def 1
.= (arcsin . x) + (x / (((f1 . x) - (x ^2)) #R (1 / 2))) by FDIFF_7:1
.= (arcsin . x) + (x / ((1 - (x ^2)) #R (1 / 2))) by A1, A15
.= (arcsin . x) + (x / (sqrt (1 - (x ^2)))) by A18, FDIFF_7:2 ;
hence f . x = (arcsin . x) + (x / (sqrt (1 - (x ^2)))) by A1; :: thesis: verum

end;

A19: for x being Element of REAL st x in dom (((id Z) (#) arcsin) `| Z) holds
(((id Z) (#) arcsin) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom (((id Z) (#) arcsin) `| Z) implies (((id Z) (#) arcsin) `| Z) . x = f . x )
assume x in dom (((id Z) (#) arcsin) `| Z) ; :: thesis: (((id Z) (#) arcsin) `| Z) . x = f . x
then A20: x in Z by A13, FDIFF_1:def 7;
then (((id Z) (#) arcsin) `| Z) . x = (arcsin . x) + (x / (sqrt (1 - (x ^2)))) by A1, A4, FDIFF_7:16
.= f . x by A14, A20 ;
hence (((id Z) (#) arcsin) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((id Z) (#) arcsin) `| Z) = dom f by A1, A13, FDIFF_1:def 7;
then ((id Z) (#) arcsin) `| Z = f by A19, PARTFUN1:5;
hence integral (f,A) = (((id Z) (#) arcsin) . (upper_bound A)) - (((id Z) (#) arcsin) . (lower_bound A)) by A1, A12, A4, FDIFF_7:16, INTEGRA5:13; :: thesis: verum