let A be non empty closed_interval Subset of REAL; :: thesis: for Z being open Subset of REAL
for f being PartFunc of REAL,REAL st A c= Z & ( for x being Real st x in Z holds
( f . x = - (1 / ((sin . x) ^2)) & sin . x <> 0 ) ) & dom cot = Z & Z = dom f & f | A is continuous holds
integral (f,A) = (cot . (upper_bound A)) - (cot . (lower_bound A))
let Z be open Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL st A c= Z & ( for x being Real st x in Z holds
( f . x = - (1 / ((sin . x) ^2)) & sin . x <> 0 ) ) & dom cot = Z & Z = dom f & f | A is continuous holds
integral (f,A) = (cot . (upper_bound A)) - (cot . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
( f . x = - (1 / ((sin . x) ^2)) & sin . x <> 0 ) ) & dom cot = Z & Z = dom f & f | A is continuous implies integral (f,A) = (cot . (upper_bound A)) - (cot . (lower_bound A)) )
assume that
A1: A c= Z and
A2: for x being Real st x in Z holds
( f . x = - (1 / ((sin . x) ^2)) & sin . x <> 0 ) and
A3: dom cot = Z and
A4: Z = dom f and
A5: f | A is continuous ; :: thesis: integral (f,A) = (cot . (upper_bound A)) - (cot . (lower_bound A))
A6: f is_integrable_on A by A1, A4, A5, INTEGRA5:11;
A7: cot is_differentiable_on Z by A3, INTEGRA8:34;
A8: for x being Element of REAL st x in dom (cot `| Z) holds
(cot `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom (cot `| Z) implies (cot `| Z) . x = f . x )
assume x in dom (cot `| Z) ; :: thesis: (cot `| Z) . x = f . x
then A9: x in Z by A7, FDIFF_1:def 7;
then (cot `| Z) . x = - (1 / ((sin . x) ^2)) by A3, INTEGRA8:34
.= f . x by A2, A9 ;
hence (cot `| Z) . x = f . x ; :: thesis: verum

end;

dom (cot `| Z) = dom f by A4, A7, FDIFF_1:def 7;
then cot `| Z = f by A8, PARTFUN1:5;
hence integral (f,A) = (cot . (upper_bound A)) - (cot . (lower_bound A)) by A1, A4, A5, A6, A7, INTEGRA5:10, INTEGRA5:13; :: thesis: verum