let A be non empty closed_interval Subset of REAL; :: thesis: for Z being open Subset of REAL
for f being PartFunc of REAL,REAL st not 0 in Z & A c= Z & ( for x being Real st x in Z holds
( x <> 0 & f . x = - (1 / (x ^2)) ) ) & dom f = Z & f | A is continuous holds
integral (f,A) = (((id Z) ^) . (upper_bound A)) - (((id Z) ^) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL st not 0 in Z & A c= Z & ( for x being Real st x in Z holds
( x <> 0 & f . x = - (1 / (x ^2)) ) ) & dom f = Z & f | A is continuous holds
integral (f,A) = (((id Z) ^) . (upper_bound A)) - (((id Z) ^) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: ( not 0 in Z & A c= Z & ( for x being Real st x in Z holds
( x <> 0 & f . x = - (1 / (x ^2)) ) ) & dom f = Z & f | A is continuous implies integral (f,A) = (((id Z) ^) . (upper_bound A)) - (((id Z) ^) . (lower_bound A)) )
set g = id Z;
assume that
A1: not 0 in Z and
A2: A c= Z and
A3: for x being Real st x in Z holds
( x <> 0 & f . x = - (1 / (x ^2)) ) and
A4: dom f = Z and
A5: f | A is continuous ; :: thesis: integral (f,A) = (((id Z) ^) . (upper_bound A)) - (((id Z) ^) . (lower_bound A))
A6: f is_integrable_on A by A2, A4, A5, INTEGRA5:11;
A7: (id Z) ^ is_differentiable_on Z by A1, FDIFF_5:4;
A8: for x being Element of REAL st x in dom (((id Z) ^) `| Z) holds
(((id Z) ^) `| Z) . x = f . x

proof

let x be Element of REAL ; :: thesis: ( x in dom (((id Z) ^) `| Z) implies (((id Z) ^) `| Z) . x = f . x )
assume x in dom (((id Z) ^) `| Z) ; :: thesis: (((id Z) ^) `| Z) . x = f . x
then A9: x in Z by A7, FDIFF_1:def 7;
then (((id Z) ^) `| Z) . x = - (1 / (x ^2)) by A1, FDIFF_5:4
.= f . x by A3, A9 ;
hence (((id Z) ^) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((id Z) ^) `| Z) = dom f by A4, A7, FDIFF_1:def 7;
then ((id Z) ^) `| Z = f by A8, PARTFUN1:5;
hence integral (f,A) = (((id Z) ^) . (upper_bound A)) - (((id Z) ^) . (lower_bound A)) by A2, A4, A5, A6, A7, INTEGRA5:10, INTEGRA5:13; :: thesis: verum