let f be PartFunc of REAL,REAL; :: thesis: for a, b being Real st a < b & ['a,b'] c= dom f & f is_left_ext_Riemann_integrable_on a,b holds
for r being Real holds
( r (#) f is_left_ext_Riemann_integrable_on a,b & ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) )
let a, b be Real; :: thesis: ( a < b & ['a,b'] c= dom f & f is_left_ext_Riemann_integrable_on a,b implies for r being Real holds
( r (#) f is_left_ext_Riemann_integrable_on a,b & ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) ) )
assume that
A1: a < b and
A2: ['a,b'] c= dom f and
A3: f is_left_ext_Riemann_integrable_on a,b ; :: thesis: for r being Real holds
( r (#) f is_left_ext_Riemann_integrable_on a,b & ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) )
for r being Real holds
( r (#) f is_left_ext_Riemann_integrable_on a,b & ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) )

proof

let r be Real; :: thesis: ( r (#) f is_left_ext_Riemann_integrable_on a,b & ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) )
consider Intf being PartFunc of REAL,REAL such that
A4: dom Intf = ].a,b.] and
A5: for x being Real st x in dom Intf holds
Intf . x = integral (f,x,b) and
A6: Intf is_right_convergent_in a and
A7: ext_left_integral (f,a,b) = lim_right (Intf,a) by A3, Def4;
set Intfg = r (#) Intf;
A8: r (#) Intf is_right_convergent_in a by A6, LIMFUNC2:52;
A9: ( dom (r (#) Intf) = ].a,b.] & ( for x being Real st x in dom (r (#) Intf) holds
(r (#) Intf) . x = integral ((r (#) f),x,b) ) )

proof

A10: ['a,b'] = [.a,b.] by A1, INTEGRA5:def 3;
thus A11: dom (r (#) Intf) = ].a,b.] by A4, VALUED_1:def 5; :: thesis: for x being Real st x in dom (r (#) Intf) holds
(r (#) Intf) . x = integral ((r (#) f),x,b)
let x be Real; :: thesis: ( x in dom (r (#) Intf) implies (r (#) Intf) . x = integral ((r (#) f),x,b) )
assume A12: x in dom (r (#) Intf) ; :: thesis: (r (#) Intf) . x = integral ((r (#) f),x,b)
then A13: a < x by A11, XXREAL_1:2;
then A14: [.x,b.] c= [.a,b.] by XXREAL_1:34;
A15: x <= b by A11, A12, XXREAL_1:2;
then A16: ['x,b'] = [.x,b.] by INTEGRA5:def 3;
A17: ( f is_integrable_on ['x,b'] & f | ['x,b'] is bounded ) by A3, A13, A15;
thus (r (#) Intf) . x = r * (Intf . x) by A12, VALUED_1:def 5
.= r * (integral (f,x,b)) by A4, A5, A11, A12
.= integral ((r (#) f),x,b) by A2, A15, A16, A10, A14, A17, INTEGRA6:10, XBOOLE_1:1 ; :: thesis: verum

end;

for d being Real st a < d & d <= b holds
( r (#) f is_integrable_on ['d,b'] & (r (#) f) | ['d,b'] is bounded )

proof

let d be Real; :: thesis: ( a < d & d <= b implies ( r (#) f is_integrable_on ['d,b'] & (r (#) f) | ['d,b'] is bounded ) )
assume A18: ( a < d & d <= b ) ; :: thesis: ( r (#) f is_integrable_on ['d,b'] & (r (#) f) | ['d,b'] is bounded )
then A19: ( ['d,b'] = [.d,b.] & [.d,b.] c= [.a,b.] ) by INTEGRA5:def 3, XXREAL_1:34;
A20: ( f is_integrable_on ['d,b'] & f | ['d,b'] is bounded ) by A3, A18;
['a,b'] = [.a,b.] by A1, INTEGRA5:def 3;
then ['d,b'] c= dom f by A2, A19;
hence ( r (#) f is_integrable_on ['d,b'] & (r (#) f) | ['d,b'] is bounded ) by A20, INTEGRA6:9, RFUNCT_1:80; :: thesis: verum

end;

hence A21: r (#) f is_left_ext_Riemann_integrable_on a,b by A9, A8; :: thesis: ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b))
lim_right ((r (#) Intf),a) = r * (ext_left_integral (f,a,b)) by A6, A7, LIMFUNC2:52;
hence ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) by A9, A8, A21, Def4; :: thesis: verum

end;

hence for r being Real holds
( r (#) f is_left_ext_Riemann_integrable_on a,b & ext_left_integral ((r (#) f),a,b) = r * (ext_left_integral (f,a,b)) ) ; :: thesis: verum