let n be Element of NAT ; :: thesis: for G, H being Group
for a being Element of G
for g being Homomorphism of G,H holds g . (a |^ n) = (g . a) |^ n
let G, H be Group; :: thesis: for a being Element of G
for g being Homomorphism of G,H holds g . (a |^ n) = (g . a) |^ n
let a be Element of G; :: thesis: for g being Homomorphism of G,H holds g . (a |^ n) = (g . a) |^ n
let g be Homomorphism of G,H; :: thesis: g . (a |^ n) = (g . a) |^ n
defpred S₁[ Nat] means g . (a |^ $1) = (g . a) |^ $1;
A1: for n being Nat st S₁[n] holds
S₁[n + 1]

proof

let n be Nat; :: thesis: ( S₁[n] implies S₁[n + 1] )
assume A2: S₁[n] ; :: thesis: S₁[n + 1]
thus g . (a |^ (n + 1)) = g . ((a |^ n) * a) by GROUP_1:34
.= ((g . a) |^ n) * (g . a) by A2, Def6
.= (g . a) |^ (n + 1) by GROUP_1:34 ; :: thesis: verum

end;

g . (a |^ 0) = g . (1_ G) by GROUP_1:25
.= 1_ H by Th31
.= (g . a) |^ 0 by GROUP_1:25 ;
then A3: S₁[ 0 ] ;
for n being Nat holds S₁[n] from NAT_1:sch 2(A3, A1);
hence g . (a |^ n) = (g . a) |^ n ; :: thesis: verum