let G be Group; :: thesis: for a, b being Element of G
for H being Subgroup of G holds a * H,b * H are_equipotent
let a, b be Element of G; :: thesis: for H being Subgroup of G holds a * H,b * H are_equipotent
let H be Subgroup of G; :: thesis: a * H,b * H are_equipotent
defpred S₁[ object , object ] means ex g1 being Element of G st
( $1 = g1 & $2 = (b * (a ")) * g1 );
A1: for x being object st x in a * H holds
ex y being object st S₁[x,y]

proof

let x be object ; :: thesis: ( x in a * H implies ex y being object st S₁[x,y] )
assume x in a * H ; :: thesis: ex y being object st S₁[x,y]
then reconsider g = x as Element of G ;
reconsider y = (b * (a ")) * g as set ;
take y ; :: thesis: S₁[x,y]
take g ; :: thesis: ( x = g & y = (b * (a ")) * g )
thus ( x = g & y = (b * (a ")) * g ) ; :: thesis: verum

end;

consider f being Function such that
A2: dom f = a * H and
A3: for x being object st x in a * H holds
S₁[x,f . x] from CLASSES1:sch 1(A1);
A4: rng f = b * H

proof

thus rng f c= b * H :: according to XBOOLE_0:def 10 :: thesis: b * H c= rng f

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in rng f or x in b * H )
assume x in rng f ; :: thesis: x in b * H
then consider y being object such that
A5: y in dom f and
A6: f . y = x by FUNCT_1:def 3;
consider g being Element of G such that
A7: y = g and
A8: x = (b * (a ")) * g by A2, A3, A5, A6;
consider g1 being Element of G such that
A9: g = a * g1 and
A10: g1 in H by A2, A5, A7, Th103;
x = ((b * (a ")) * a) * g1 by A8, A9, GROUP_1:def 3
.= (b * ((a ") * a)) * g1 by GROUP_1:def 3
.= (b * (1_ G)) * g1 by GROUP_1:def 5
.= b * g1 by GROUP_1:def 4 ;
hence x in b * H by A10, Th103; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in b * H or x in rng f )
assume x in b * H ; :: thesis: x in rng f
then consider g being Element of G such that
A11: x = b * g and
A12: g in H by Th103;
A13: a * g in dom f by A2, A12, Th103;
then ex g1 being Element of G st
( g1 = a * g & f . (a * g) = (b * (a ")) * g1 ) by A2, A3;
then f . (a * g) = ((b * (a ")) * a) * g by GROUP_1:def 3
.= (b * ((a ") * a)) * g by GROUP_1:def 3
.= (b * (1_ G)) * g by GROUP_1:def 5
.= x by A11, GROUP_1:def 4 ;
hence x in rng f by A13, FUNCT_1:def 3; :: thesis: verum

end;

f is one-to-one

proof

let x, y be object ; :: according to FUNCT_1:def 4 :: thesis: ( not x in dom f or not y in dom f or not f . x = f . y or x = y )
assume that
A14: ( x in dom f & y in dom f ) and
A15: f . x = f . y ; :: thesis: x = y
( ex g1 being Element of G st
( x = g1 & f . x = (b * (a ")) * g1 ) & ex g2 being Element of G st
( y = g2 & f . y = (b * (a ")) * g2 ) ) by A2, A3, A14;
hence x = y by A15, GROUP_1:6; :: thesis: verum

end;

hence a * H,b * H are_equipotent by A2, A4, WELLORD2:def 4; :: thesis: verum