let G be addGroup; :: thesis: for a being Element of G
for H being Subgroup of G holds
( a in H iff H + a = carr H )
let a be Element of G; :: thesis: for H being Subgroup of G holds
( a in H iff H + a = carr H )
let H be Subgroup of G; :: thesis: ( a in H iff H + a = carr H )
thus ( a in H implies H + a = carr H ) :: thesis: ( H + a = carr H implies a in H )

proof

assume A1: a in H ; :: thesis: H + a = carr H
thus H + a c= carr H :: according to XBOOLE_0:def 10 :: thesis: carr H c= H + a

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in H + a or x in carr H )
assume x in H + a ; :: thesis: x in carr H
then consider g being Element of G such that
A2: x = g + a and
A3: g in H by Th104;
g + a in H by A1, A3, Th50;
hence x in carr H by A2; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in carr H or x in H + a )
assume A4: x in carr H ; :: thesis: x in H + a
then A5: x in H ;
reconsider b = x as Element of G by A4;
A6: (b + (- a)) + a = b + ((- a) + a) by RLVECT_1:def 3
.= b + (0_ G) by Def5
.= x by Def4 ;
- a in H by A1, Th51;
hence x in H + a by A5, A6, Th50, Th104; :: thesis: verum

end;

assume A7: H + a = carr H ; :: thesis: a in H
( (0_ G) + a = a & 0_ G in H ) by Th46, Def4;
hence a in H by A7, Th104; :: thesis: verum