let i be Nat; :: thesis: for G being Go-board st i <= len G holds
Int (v_strip (G,i)) is convex
let G be Go-board; :: thesis: ( i <= len G implies Int (v_strip (G,i)) is convex )
assume A1: i <= len G ; :: thesis: Int (v_strip (G,i)) is convex

per cases ( i = 0 or i = len G or ( 1 <= i & i < len G ) ) by A1, NAT_1:14, XXREAL_0:1;

suppose i = 0 ; :: thesis: Int (v_strip (G,i)) is convex

then Int (v_strip (G,i)) = { |[r,s]| where r, s is Real : r < (G * (1,1)) `1 } by GOBOARD6:12;
hence Int (v_strip (G,i)) is convex by JORDAN1:13; :: thesis: verum

end;

suppose i = len G ; :: thesis: Int (v_strip (G,i)) is convex

then Int (v_strip (G,i)) = { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } by GOBOARD6:13;
hence Int (v_strip (G,i)) is convex by JORDAN1:11; :: thesis: verum

end;

suppose ( 1 <= i & i < len G ) ; :: thesis: Int (v_strip (G,i)) is convex

then A2: Int (v_strip (G,i)) = { |[r,s]| where r, s is Real : ( (G * (i,1)) `1 < r & r < (G * ((i + 1),1)) `1 ) } by GOBOARD6:14;
A3: { |[r,s]| where r, s is Real : (G * (i,1)) `1 < r } c= the carrier of (TOP-REAL 2)

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in { |[r,s]| where r, s is Real : (G * (i,1)) `1 < r } or x in the carrier of (TOP-REAL 2) )
assume x in { |[r,s]| where r, s is Real : (G * (i,1)) `1 < r } ; :: thesis: x in the carrier of (TOP-REAL 2)
then ex r, s being Real st
( x = |[r,s]| & (G * (i,1)) `1 < r ) ;
hence x in the carrier of (TOP-REAL 2) ; :: thesis: verum

end;

{ |[r,s]| where r, s is Real : r < (G * ((i + 1),1)) `1 } c= the carrier of (TOP-REAL 2)

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in { |[r,s]| where r, s is Real : r < (G * ((i + 1),1)) `1 } or x in the carrier of (TOP-REAL 2) )
assume x in { |[r,s]| where r, s is Real : r < (G * ((i + 1),1)) `1 } ; :: thesis: x in the carrier of (TOP-REAL 2)
then ex r, s being Real st
( x = |[r,s]| & r < (G * ((i + 1),1)) `1 ) ;
hence x in the carrier of (TOP-REAL 2) ; :: thesis: verum

end;

then reconsider P = { |[r,s]| where r, s is Real : (G * (i,1)) `1 < r } , Q = { |[r,s]| where r, s is Real : r < (G * ((i + 1),1)) `1 } as Subset of (TOP-REAL 2) by A3;
A4: Int (v_strip (G,i)) = P /\ Q

proof

hereby :: according to TARSKI:def 3,XBOOLE_0:def 10 :: thesis: P /\ Q c= Int (v_strip (G,i))

let x be object ; :: thesis: ( x in Int (v_strip (G,i)) implies x in P /\ Q )
assume x in Int (v_strip (G,i)) ; :: thesis: x in P /\ Q
then A5: ex r, s being Real st
( x = |[r,s]| & (G * (i,1)) `1 < r & r < (G * ((i + 1),1)) `1 ) by A2;
then A6: x in P ;
x in Q by A5;
hence x in P /\ Q by A6, XBOOLE_0:def 4; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in P /\ Q or x in Int (v_strip (G,i)) )
assume A7: x in P /\ Q ; :: thesis: x in Int (v_strip (G,i))
then x in P by XBOOLE_0:def 4;
then consider r1, s1 being Real such that
A8: x = |[r1,s1]| and
A9: (G * (i,1)) `1 < r1 ;
x in Q by A7, XBOOLE_0:def 4;
then consider r2, s2 being Real such that
A10: x = |[r2,s2]| and
A11: r2 < (G * ((i + 1),1)) `1 ;
r1 = r2 by A8, A10, SPPOL_2:1;
hence x in Int (v_strip (G,i)) by A2, A8, A9, A11; :: thesis: verum

end;

A12: P is convex by JORDAN1:11;
Q is convex by JORDAN1:13;
hence Int (v_strip (G,i)) is convex by A4, A12, Th5; :: thesis: verum

end;

end;