let j be Nat; :: thesis: for G being Go-board st j <= width G holds
Int (h_strip (G,j)) is convex
let G be Go-board; :: thesis: ( j <= width G implies Int (h_strip (G,j)) is convex )
assume A1: j <= width G ; :: thesis: Int (h_strip (G,j)) is convex

per cases ( j = 0 or j = width G or ( 1 <= j & j < width G ) ) by A1, NAT_1:14, XXREAL_0:1;

suppose j = 0 ; :: thesis: Int (h_strip (G,j)) is convex

then Int (h_strip (G,j)) = { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } by GOBOARD6:15;
hence Int (h_strip (G,j)) is convex by JORDAN1:17; :: thesis: verum

end;

suppose j = width G ; :: thesis: Int (h_strip (G,j)) is convex

then Int (h_strip (G,j)) = { |[r,s]| where r, s is Real : (G * (1,(width G))) `2 < s } by GOBOARD6:16;
hence Int (h_strip (G,j)) is convex by JORDAN1:15; :: thesis: verum

end;

suppose ( 1 <= j & j < width G ) ; :: thesis: Int (h_strip (G,j)) is convex

then A2: Int (h_strip (G,j)) = { |[r,s]| where r, s is Real : ( (G * (1,j)) `2 < s & s < (G * (1,(j + 1))) `2 ) } by GOBOARD6:17;
A3: { |[r,s]| where r, s is Real : (G * (1,j)) `2 < s } c= the carrier of (TOP-REAL 2)

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in { |[r,s]| where r, s is Real : (G * (1,j)) `2 < s } or x in the carrier of (TOP-REAL 2) )
assume x in { |[r,s]| where r, s is Real : (G * (1,j)) `2 < s } ; :: thesis: x in the carrier of (TOP-REAL 2)
then ex r, s being Real st
( x = |[r,s]| & (G * (1,j)) `2 < s ) ;
hence x in the carrier of (TOP-REAL 2) ; :: thesis: verum

end;

{ |[r,s]| where r, s is Real : s < (G * (1,(j + 1))) `2 } c= the carrier of (TOP-REAL 2)

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in { |[r,s]| where r, s is Real : s < (G * (1,(j + 1))) `2 } or x in the carrier of (TOP-REAL 2) )
assume x in { |[r,s]| where r, s is Real : s < (G * (1,(j + 1))) `2 } ; :: thesis: x in the carrier of (TOP-REAL 2)
then ex r, s being Real st
( x = |[r,s]| & s < (G * (1,(j + 1))) `2 ) ;
hence x in the carrier of (TOP-REAL 2) ; :: thesis: verum

end;

then reconsider P = { |[r,s]| where r, s is Real : (G * (1,j)) `2 < s } , Q = { |[r,s]| where r, s is Real : s < (G * (1,(j + 1))) `2 } as Subset of (TOP-REAL 2) by A3;
A4: Int (h_strip (G,j)) = P /\ Q

proof

hereby :: according to TARSKI:def 3,XBOOLE_0:def 10 :: thesis: P /\ Q c= Int (h_strip (G,j))

let x be object ; :: thesis: ( x in Int (h_strip (G,j)) implies x in P /\ Q )
assume x in Int (h_strip (G,j)) ; :: thesis: x in P /\ Q
then A5: ex r, s being Real st
( x = |[r,s]| & (G * (1,j)) `2 < s & s < (G * (1,(j + 1))) `2 ) by A2;
then A6: x in P ;
x in Q by A5;
hence x in P /\ Q by A6, XBOOLE_0:def 4; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in P /\ Q or x in Int (h_strip (G,j)) )
assume A7: x in P /\ Q ; :: thesis: x in Int (h_strip (G,j))
then x in P by XBOOLE_0:def 4;
then consider r1, s1 being Real such that
A8: x = |[r1,s1]| and
A9: (G * (1,j)) `2 < s1 ;
x in Q by A7, XBOOLE_0:def 4;
then consider r2, s2 being Real such that
A10: x = |[r2,s2]| and
A11: s2 < (G * (1,(j + 1))) `2 ;
s1 = s2 by A8, A10, SPPOL_2:1;
hence x in Int (h_strip (G,j)) by A2, A8, A9, A11; :: thesis: verum

end;

A12: P is convex by JORDAN1:15;
Q is convex by JORDAN1:17;
hence Int (h_strip (G,j)) is convex by A4, A12, Th5; :: thesis: verum

end;

end;