let G be Go-board; :: thesis: Int (v_strip (G,(len G))) = { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r }
0 <> width G by MATRIX_0:def 10;
then 1 <= width G by NAT_1:14;
then A1: v_strip (G,(len G)) = { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 <= r } by GOBOARD5:9;
thus Int (v_strip (G,(len G))) c= { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } :: according to XBOOLE_0:def 10 :: thesis: { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } c= Int (v_strip (G,(len G)))

proof

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in Int (v_strip (G,(len G))) or x in { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } )
assume A2: x in Int (v_strip (G,(len G))) ; :: thesis: x in { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r }
then reconsider u = x as Point of (Euclid 2) by Lm6;
consider r1 being Real such that
A3: r1 > 0 and
A4: Ball (u,r1) c= v_strip (G,(len G)) by A2, Th5;
reconsider p = u as Point of (TOP-REAL 2) by Lm6;
A5: p = |[(p `1),(p `2)]| by EUCLID:53;
set q = |[((p `1) - (r1 / 2)),((p `2) + 0)]|;
r1 / 2 < r1 by A3, XREAL_1:216;
then |[((p `1) - (r1 / 2)),((p `2) + 0)]| in Ball (u,r1) by A3, A5, Th9;
then |[((p `1) - (r1 / 2)),((p `2) + 0)]| in v_strip (G,(len G)) by A4;
then ex r2, s2 being Real st
( |[((p `1) - (r1 / 2)),((p `2) + 0)]| = |[r2,s2]| & (G * ((len G),1)) `1 <= r2 ) by A1;
then (G * ((len G),1)) `1 <= (p `1) - (r1 / 2) by SPPOL_2:1;
then A6: ((G * ((len G),1)) `1) + (r1 / 2) <= p `1 by XREAL_1:19;
(G * ((len G),1)) `1 < ((G * ((len G),1)) `1) + (r1 / 2) by A3, XREAL_1:29, XREAL_1:215;
then (G * ((len G),1)) `1 < p `1 by A6, XXREAL_0:2;
hence x in { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } by A5; :: thesis: verum

end;

let x be object ; :: according to TARSKI:def 3 :: thesis: ( not x in { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } or x in Int (v_strip (G,(len G))) )
assume x in { |[r,s]| where r, s is Real : (G * ((len G),1)) `1 < r } ; :: thesis: x in Int (v_strip (G,(len G)))
then consider r, s being Real such that
A7: x = |[r,s]| and
A8: (G * ((len G),1)) `1 < r ;
reconsider u = |[r,s]| as Point of (Euclid 2) by TOPREAL3:8;
A9: Ball (u,(r - ((G * ((len G),1)) `1))) c= v_strip (G,(len G))

proof

let y be object ; :: according to TARSKI:def 3 :: thesis: ( not y in Ball (u,(r - ((G * ((len G),1)) `1))) or y in v_strip (G,(len G)) )
A10: Ball (u,(r - ((G * ((len G),1)) `1))) = { v where v is Point of (Euclid 2) : dist (u,v) < r - ((G * ((len G),1)) `1) } by METRIC_1:17;
assume y in Ball (u,(r - ((G * ((len G),1)) `1))) ; :: thesis: y in v_strip (G,(len G))
then consider v being Point of (Euclid 2) such that
A11: v = y and
A12: dist (u,v) < r - ((G * ((len G),1)) `1) by A10;
reconsider q = v as Point of (TOP-REAL 2) by TOPREAL3:8;
( (r - (q `1)) ^2 >= 0 & ((r - (q `1)) ^2) + 0 <= ((r - (q `1)) ^2) + ((s - (q `2)) ^2) ) by XREAL_1:6, XREAL_1:63;
then A13: sqrt ((r - (q `1)) ^2) <= sqrt (((r - (q `1)) ^2) + ((s - (q `2)) ^2)) by SQUARE_1:26;
A14: q = |[(q `1),(q `2)]| by EUCLID:53;
then sqrt (((r - (q `1)) ^2) + ((s - (q `2)) ^2)) < r - ((G * ((len G),1)) `1) by A12, Th6;
then sqrt ((r - (q `1)) ^2) <= r - ((G * ((len G),1)) `1) by A13, XXREAL_0:2;
then A15: |.(r - (q `1)).| <= r - ((G * ((len G),1)) `1) by COMPLEX1:72;

per cases ( r >= q `1 or r <= q `1 ) ;

suppose r >= q `1 ; :: thesis: y in v_strip (G,(len G))

then r - (q `1) >= 0 by XREAL_1:48;
then |.(r - (q `1)).| = r - (q `1) by ABSVALUE:def 1;
then (G * ((len G),1)) `1 <= q `1 by A15, XREAL_1:10;
hence y in v_strip (G,(len G)) by A1, A11, A14; :: thesis: verum

end;

suppose r <= q `1 ; :: thesis: y in v_strip (G,(len G))

then (G * ((len G),1)) `1 <= q `1 by A8, XXREAL_0:2;
hence y in v_strip (G,(len G)) by A1, A11, A14; :: thesis: verum

end;

end;

end;

reconsider B = Ball (u,(r - ((G * ((len G),1)) `1))) as Subset of (TOP-REAL 2) by TOPREAL3:8;
A16: B is open by Th3;
u in Ball (u,(r - ((G * ((len G),1)) `1))) by A8, Th1, XREAL_1:50;
hence x in Int (v_strip (G,(len G))) by A7, A9, A16, TOPS_1:22; :: thesis: verum