let H be addLoops of G,V; :: thesis: H is with_max_out_degree

per cases ( V c= the_Vertices_of G or not V c= the_Vertices_of G ) ;

suppose A3: V c= the_Vertices_of G ; :: thesis: H is with_max_out_degree

consider v0 being Vertex of G such that
A4: for w0 being Vertex of G holds w0 .outDegree() c= v0 .outDegree() by Def14;
A5: the_Vertices_of G = the_Vertices_of H by A3, GLIB_012:def 5;
then reconsider v = v0 as Vertex of H ;

per cases ( v0 in V or ( not v0 in V & ex w0 being Vertex of G st
( w0 in V & v0 .outDegree() c< (w0 .outDegree()) +` 1 ) ) or ( not v0 in V & ( for w0 being Vertex of G holds
( not w0 in V or not v0 .outDegree() c< (w0 .outDegree()) +` 1 ) ) ) ) ;

suppose v0 in V ; :: thesis: H is with_max_out_degree

then A6: v .outDegree() = (v0 .outDegree()) +` 1 by A3, GLIB_012:43;

now :: thesis: for w being Vertex of H holds w .outDegree() c= v .outDegree()

let w be Vertex of H; :: thesis: b₁ .outDegree() c= v .outDegree()
reconsider w0 = w as Vertex of G by A5;

per cases ( w0 in V or not w0 in V ) ;

suppose w0 in V ; :: thesis: b₁ .outDegree() c= v .outDegree()

then A7: w .outDegree() = (w0 .outDegree()) +` 1 by A3, GLIB_012:43;
( w0 .outDegree() c= v0 .outDegree() & 1 c= 1 ) by A4;
hence w .outDegree() c= v .outDegree() by A6, A7, CARD_2:83; :: thesis: verum

end;

suppose not w0 in V ; :: thesis: b₁ .outDegree() c= v .outDegree()

then A8: w .outDegree() = w0 .outDegree() by A3, GLIB_012:44
.= (w0 .outDegree()) +` 0 by CARD_2:18 ;
( w0 .outDegree() c= v0 .outDegree() & 0 c= 1 ) by A4, XBOOLE_1:2;
hence w .outDegree() c= v .outDegree() by A6, A8, CARD_2:83; :: thesis: verum

end;

end;

end;

hence H is with_max_out_degree ; :: thesis: verum

end;

suppose ( not v0 in V & ex w0 being Vertex of G st
( w0 in V & v0 .outDegree() c< (w0 .outDegree()) +` 1 ) ) ; :: thesis: H is with_max_out_degree

then consider w0 being Vertex of G such that
A9: ( w0 in V & v0 .outDegree() c< (w0 .outDegree()) +` 1 ) ;
reconsider w = w0 as Vertex of H by A5;
A10: w .outDegree() = (w0 .outDegree()) +` 1 by A3, A9, GLIB_012:43;
not (w0 .outDegree()) +` 1 c= v0 .outDegree() by A9, XBOOLE_0:def 8;
then A11: w0 .outDegree() = v0 .outDegree() by A4, Lm1;

now :: thesis: for u being Vertex of H holds u .outDegree() c= w .outDegree()

let u be Vertex of H; :: thesis: b₁ .outDegree() c= w .outDegree()
reconsider u0 = u as Vertex of G by A5;

per cases ( u0 in V or not u0 in V ) ;

suppose u0 in V ; :: thesis: b₁ .outDegree() c= w .outDegree()

then A12: u .outDegree() = (u0 .outDegree()) +` 1 by A3, GLIB_012:43;
( u0 .outDegree() c= w0 .outDegree() & 1 c= 1 ) by A4, A11;
hence u .outDegree() c= w .outDegree() by A10, A12, CARD_2:83; :: thesis: verum

end;

suppose not u0 in V ; :: thesis: b₁ .outDegree() c= w .outDegree()

then A13: u .outDegree() = u0 .outDegree() by A3, GLIB_012:44
.= (u0 .outDegree()) +` 0 by CARD_2:18 ;
( u0 .outDegree() c= w0 .outDegree() & 0 c= 1 ) by A4, A11, XBOOLE_1:2;
hence u .outDegree() c= w .outDegree() by A10, A13, CARD_2:83; :: thesis: verum

end;

end;

end;

hence H is with_max_out_degree ; :: thesis: verum

end;

suppose A14: ( not v0 in V & ( for w0 being Vertex of G holds
( not w0 in V or not v0 .outDegree() c< (w0 .outDegree()) +` 1 ) ) ) ; :: thesis: H is with_max_out_degree

then A15: v .outDegree() = v0 .outDegree() by A3, GLIB_012:44;

now :: thesis: for w being Vertex of H holds w .outDegree() c= v .outDegree()

let w be Vertex of H; :: thesis: b₁ .outDegree() c= v .outDegree()
reconsider w0 = w as Vertex of G by A5;

per cases ( w0 in V or not w0 in V ) ;

suppose A16: w0 in V ; :: thesis: b₁ .outDegree() c= v .outDegree()

then w .outDegree() = (w0 .outDegree()) +` 1 by A3, GLIB_012:43;
hence w .outDegree() c= v .outDegree() by A14, A15, A16, XBOOLE_0:def 8; :: thesis: verum

end;

suppose not w0 in V ; :: thesis: b₁ .outDegree() c= v .outDegree()

then w .outDegree() = w0 .outDegree() by A3, GLIB_012:44;
hence w .outDegree() c= v .outDegree() by A4, A15; :: thesis: verum

end;

end;

end;

hence H is with_max_out_degree ; :: thesis: verum

end;

end;

end;

suppose not V c= the_Vertices_of G ; :: thesis: H is with_max_out_degree

then G == H by GLIB_012:def 5;
hence H is with_max_out_degree by Th85; :: thesis: verum

end;

end;