let G2 be _Graph; :: thesis: for v, w being Vertex of G2
for e being object
for G1 being addEdge of G2,v,e,w holds
( not v <> w or G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )
let v, w be Vertex of G2; :: thesis: for e being object
for G1 being addEdge of G2,v,e,w holds
( not v <> w or G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )
let e be object ; :: thesis: for G1 being addEdge of G2,v,e,w holds
( not v <> w or G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )
let G1 be addEdge of G2,v,e,w; :: thesis: ( not v <> w or G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )
assume A1: v <> w ; :: thesis: ( G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )

per cases ( not e in the_Edges_of G2 or e in the_Edges_of G2 ) ;

suppose A2: not e in the_Edges_of G2 ; :: thesis: ( G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )

then A3: the_Vertices_of G1 = the_Vertices_of G2 by GLIB_006:def 11;
then reconsider v9 = v, w9 = w as Vertex of G1 ;
consider v1 being Vertex of G1 such that
A4: v1 .outDegree() = G1 .minOutDegree() and
A5: for w1 being Vertex of G1 holds v1 .outDegree() c= w1 .outDegree() by Th38;
reconsider v4 = v1 as Vertex of G2 by A3;
consider v2 being Vertex of G2 such that
A6: v2 .outDegree() = G2 .minOutDegree() and
A7: for w2 being Vertex of G2 holds v2 .outDegree() c= w2 .outDegree() by Th38;
reconsider v3 = v2 as Vertex of G1 by A3;
A8: ( v2 .outDegree() c= v4 .outDegree() & v1 .outDegree() c= v3 .outDegree() ) by A5, A7;
G2 is Subgraph of G1 by GLIB_006:57;
then ( v4 .outDegree() c= v1 .outDegree() & v2 .outDegree() c= v3 .outDegree() ) by CARD_1:11, GLIB_000:78;
then A9: ( v2 .outDegree() c= v1 .outDegree() & v4 .outDegree() c= v3 .outDegree() ) by A8, XBOOLE_1:1;
assume G1 .minOutDegree() <> G2 .minOutDegree() ; :: thesis: G1 .minOutDegree() = (v .outDegree()) +` 1
then A10: v1 .outDegree() <> v2 .outDegree() by A4, A6;
then A11: (v2 .outDegree()) +` 1 c= v1 .outDegree() by A9, Lm1;
A12: v2 = v

proof

assume A13: v2 <> v ; :: thesis: contradiction
A14: v2 .outDegree() = v3 .outDegree()

proof

per cases ( v2 = w or v2 <> w ) ;

suppose v2 = w ; :: thesis: v2 .outDegree() = v3 .outDegree()

hence v2 .outDegree() = v3 .outDegree() by A1, A2, GLIBPRE0:48; :: thesis: verum

end;

suppose v2 <> w ; :: thesis: v2 .outDegree() = v3 .outDegree()

hence v2 .outDegree() = v3 .outDegree() by A13, GLIBPRE0:46; :: thesis: verum

end;

end;

end;

then A15: (v3 .outDegree()) +` 1 c= v3 .outDegree() by A8, A11, XBOOLE_1:1;
v3 .outDegree() c= (v3 .outDegree()) +` 1 by CARD_2:94;
then v3 .outDegree() = (v3 .outDegree()) +` 1 by A15, XBOOLE_0:def 10;
hence contradiction by A8, A10, A11, A14, XBOOLE_0:def 10; :: thesis: verum

end;

then v3 .outDegree() = (v2 .outDegree()) +` 1 by A1, A2, GLIBPRE0:47;
hence G1 .minOutDegree() = (v .outDegree()) +` 1 by A4, A8, A11, A12, XBOOLE_0:def 10; :: thesis: verum

end;

suppose e in the_Edges_of G2 ; :: thesis: ( G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 )

then G1 == G2 by GLIB_006:def 11;
hence ( G1 .minOutDegree() = G2 .minOutDegree() or G1 .minOutDegree() = (v .outDegree()) +` 1 ) by Th62; :: thesis: verum

end;

end;