let G1, G2 be _Graph; :: thesis: for F being directed PGraphMapping of G1,G2
for X, Y being Subset of (the_Vertices_of G1) st F is weak_SG-embedding holds
card (G1 .edgesDBetween (X,Y)) c= card (G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y)))
let F be directed PGraphMapping of G1,G2; :: thesis: for X, Y being Subset of (the_Vertices_of G1) st F is weak_SG-embedding holds
card (G1 .edgesDBetween (X,Y)) c= card (G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y)))
let X, Y be Subset of (the_Vertices_of G1); :: thesis: ( F is weak_SG-embedding implies card (G1 .edgesDBetween (X,Y)) c= card (G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y))) )
assume A1: F is weak_SG-embedding ; :: thesis: card (G1 .edgesDBetween (X,Y)) c= card (G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y)))
set f = (F _E) | (G1 .edgesDBetween (X,Y));
A2: dom ((F _E) | (G1 .edgesDBetween (X,Y))) = (dom (F _E)) /\ (G1 .edgesDBetween (X,Y)) by RELAT_1:61
.= (the_Edges_of G1) /\ (G1 .edgesDBetween (X,Y)) by A1, Def11
.= G1 .edgesDBetween (X,Y) by XBOOLE_1:28 ;
for y being object st y in rng ((F _E) | (G1 .edgesDBetween (X,Y))) holds
y in G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y))

proof

let y be object ; :: thesis: ( y in rng ((F _E) | (G1 .edgesDBetween (X,Y))) implies y in G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y)) )
assume y in rng ((F _E) | (G1 .edgesDBetween (X,Y))) ; :: thesis: y in G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y))
then consider x being object such that
A3: ( x in dom ((F _E) | (G1 .edgesDBetween (X,Y))) & ((F _E) | (G1 .edgesDBetween (X,Y))) . x = y ) by FUNCT_1:def 3;
set v = (the_Source_of G1) . x;
set w = (the_Target_of G1) . x;
A4: x DSJoins X,Y,G1 by A2, A3, GLIB_000:def 31;
then A5: ( (the_Source_of G1) . x in X & (the_Target_of G1) . x in Y ) by GLIB_000:def 16;
then ( (the_Source_of G1) . x in the_Vertices_of G1 & (the_Target_of G1) . x in the_Vertices_of G1 ) ;
then A6: ( (the_Source_of G1) . x in dom (F _V) & (the_Target_of G1) . x in dom (F _V) ) by A1, Def11;
A7: x in the_Edges_of G1 by A4, GLIB_000:def 16;
then A8: x in dom (F _E) by A1, Def11;
x DJoins (the_Source_of G1) . x,(the_Target_of G1) . x,G1 by A7, GLIB_000:def 14;
then (F _E) . x DJoins (F _V) . ((the_Source_of G1) . x),(F _V) . ((the_Target_of G1) . x),G2 by A6, A8, Def14;
then A9: y DJoins (F _V) . ((the_Source_of G1) . x),(F _V) . ((the_Target_of G1) . x),G2 by A3, FUNCT_1:47;
( (F _V) . ((the_Source_of G1) . x) in (F _V) .: X & (F _V) . ((the_Target_of G1) . x) in (F _V) .: Y ) by A5, A6, FUNCT_1:def 6;
then y DSJoins (F _V) .: X,(F _V) .: Y,G2 by A9, GLIB_000:126;
hence y in G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y)) by GLIB_000:def 31; :: thesis: verum

end;

then A10: rng ((F _E) | (G1 .edgesDBetween (X,Y))) c= G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y)) by TARSKI:def 3;
(F _E) | (G1 .edgesDBetween (X,Y)) is one-to-one by A1, FUNCT_1:52;
hence card (G1 .edgesDBetween (X,Y)) c= card (G2 .edgesDBetween (((F _V) .: X),((F _V) .: Y))) by A2, A10, CARD_1:10; :: thesis: verum