let G2 be _Graph; :: thesis: for c being Cardinal
for v, e, w being object
for G1 being addEdge of G2,v,e,w st v <> w & G2 is c -vcolorable holds
G1 is c +` 1 -vcolorable
let c be Cardinal; :: thesis: for v, e, w being object
for G1 being addEdge of G2,v,e,w st v <> w & G2 is c -vcolorable holds
G1 is c +` 1 -vcolorable
let v, e, w be object ; :: thesis: for G1 being addEdge of G2,v,e,w st v <> w & G2 is c -vcolorable holds
G1 is c +` 1 -vcolorable
let G1 be addEdge of G2,v,e,w; :: thesis: ( v <> w & G2 is c -vcolorable implies G1 is c +` 1 -vcolorable )
assume A1: ( v <> w & G2 is c -vcolorable ) ; :: thesis: G1 is c +` 1 -vcolorable

per cases ( ( not e in the_Edges_of G2 & v in the_Vertices_of G2 & w in the_Vertices_of G2 ) or e in the_Edges_of G2 or not v in the_Vertices_of G2 or not w in the_Vertices_of G2 ) ;

suppose A2: ( not e in the_Edges_of G2 & v in the_Vertices_of G2 & w in the_Vertices_of G2 ) ; :: thesis: G1 is c +` 1 -vcolorable

consider f2 being VColoring of G2 such that
A3: ( f2 is proper & card (rng f2) c= c ) by A1;
set h = w .--> (rng f2);
set f1 = f2 +* (w .--> (rng f2));
reconsider f1 = f2 +* (w .--> (rng f2)) as VColoring of G2 by A2;
the_Vertices_of G1 = the_Vertices_of G2 by A2, GLIB_006:102;
then reconsider f1 = f1 as VColoring of G1 ;
not rng f2 in rng f2 ;
then A4: f1 is proper by A1, A2, A3, Th22;
(rng f2) \/ (rng (w .--> (rng f2))) = (rng f2) \/ (rng {[w,(rng f2)]}) by FUNCT_4:82
.= (rng f2) \/ {(rng f2)} by RELAT_1:9 ;
then A5: card (rng f1) c= card ((rng f2) \/ {(rng f2)}) by FUNCT_4:17, CARD_1:11;
card ((rng f2) \/ {(rng f2)}) c= (card (rng f2)) +` (card {(rng f2)}) by CARD_2:34;
then card ((rng f2) \/ {(rng f2)}) c= (card (rng f2)) +` 1 by CARD_1:30;
then A6: card (rng f1) c= (card (rng f2)) +` 1 by A5, XBOOLE_1:1;
(card (rng f2)) +` 1 c= c +` 1 by A3, CARD_2:83;
hence G1 is c +` 1 -vcolorable by A4, A6, XBOOLE_1:1; :: thesis: verum

end;

suppose ( e in the_Edges_of G2 or not v in the_Vertices_of G2 or not w in the_Vertices_of G2 ) ; :: thesis: G1 is c +` 1 -vcolorable

then G1 == G2 by GLIB_006:def 11;
then G1 is c -vcolorable by A1, Th32;
hence G1 is c +` 1 -vcolorable by Th27, CARD_2:94; :: thesis: verum

end;

end;