let F be Field; :: thesis: for E being F -finite GaloisExtension of F
for K1, K2 being IntermediateField of E,F holds
( Aut (E,(K1 "/\" K2)) = (Aut (E,K1)) "\/" (Aut (E,K2)) & Aut (E,(K1 "\/" K2)) = (Aut (E,K1)) /\ (Aut (E,K2)) )

let E be F -finite GaloisExtension of F; :: thesis: for K1, K2 being IntermediateField of E,F holds
( Aut (E,(K1 "/\" K2)) = (Aut (E,K1)) "\/" (Aut (E,K2)) & Aut (E,(K1 "\/" K2)) = (Aut (E,K1)) /\ (Aut (E,K2)) )

let K1, K2 be IntermediateField of E,F; :: thesis: ( Aut (E,(K1 "/\" K2)) = (Aut (E,K1)) "\/" (Aut (E,K2)) & Aut (E,(K1 "\/" K2)) = (Aut (E,K1)) /\ (Aut (E,K2)) )
N: ( Aut (E,K1) is Subgroup of Aut (E,F) & Aut (E,K2) is Subgroup of Aut (E,F) ) by GALOIS_1:18;
then ( Aut (E,K1) in Subgroups (Aut (E,F)) & Aut (E,K2) in Subgroups (Aut (E,F)) ) by GROUP_3:def 1;
then reconsider G1 = Aut (E,K1), G2 = Aut (E,K2) as SubGroup of Aut (E,F) by N, GALOIS_0:def 10;
G1 "\/" G2 in Subgroups (Aut (E,F)) by GROUP_3:def 1;
then reconsider G = G1 "\/" G2 as SubGroup of Aut (E,F) by GALOIS_0:def 10;
A: (Aut (E,K1)) "\/" (Aut (E,K2)) is Subgroup of Aut (E,(K1 "/\" K2)) by lat1;
B: Aut (E,(Fix (E,G))) = G1 "\/" G2 by G2;
C: ( Fix (E,G1) = K1 & Fix (E,G2) = K2 ) by G1;
Fix (E,(G1 "\/" G2)) is Subfield of (Fix (E,G1)) "/\" (Fix (E,G2)) by lat3;
then Aut (E,((Fix (E,G1)) "/\" (Fix (E,G2)))) is Subgroup of Aut (E,(Fix (E,G))) by GALOIS_1:19;
then Aut (E,(K1 "/\" K2)) is Subgroup of (Aut (E,K1)) "\/" (Aut (E,K2)) by C, B, GALOIS_0:8;
hence Aut (E,(K1 "/\" K2)) = (Aut (E,K1)) "\/" (Aut (E,K2)) by A, GROUP_2:55; :: thesis: Aut (E,(K1 "\/" K2)) = (Aut (E,K1)) /\ (Aut (E,K2))
G1 /\ G2 in Subgroups (Aut (E,F)) by GROUP_3:def 1;
then reconsider G = G1 /\ G2 as SubGroup of Aut (E,F) by GALOIS_0:def 10;
A: Aut (E,(K1 "\/" K2)) is Subgroup of (Aut (E,K1)) /\ (Aut (E,K2)) by lat1;
B: Aut (E,(Fix (E,G))) = G1 /\ G2 by G2;
C: ( Fix (E,G1) = K1 & Fix (E,G2) = K2 ) by G1;
(Fix (E,G1)) "\/" (Fix (E,G2)) is Subfield of Fix (E,(G1 /\ G2)) by lat3;
then Aut (E,(Fix (E,G))) is Subgroup of Aut (E,((Fix (E,G1)) "\/" (Fix (E,G2)))) by GALOIS_1:19;
then (Aut (E,K1)) /\ (Aut (E,K2)) is Subgroup of Aut (E,(K1 "\/" K2)) by C, B, GALOIS_0:8;
hence Aut (E,(K1 "\/" K2)) = (Aut (E,K1)) /\ (Aut (E,K2)) by A, GROUP_2:55; :: thesis: verum