let F be Field; :: thesis: for E being F -finite FieldExtension of F
for K being IntermediateField of E,F st K is F -normal holds
Ker (Restr K) = Aut (E,K)

let E be F -finite FieldExtension of F; :: thesis: for K being IntermediateField of E,F st K is F -normal holds
Ker (Restr K) = Aut (E,K)

let K be IntermediateField of E,F; :: thesis: ( K is F -normal implies Ker (Restr K) = Aut (E,K) )
assume AS: K is F -normal ; :: thesis: Ker (Restr K) = Aut (E,K)
K in IntermediateFields (E,F) by GALOIS_0:def 5;
then K is Subfield of E by FIELD_14:4;
then reconsider E1 = E as FieldExtension of K by FIELD_4:7;
H3: ( Aut (K,F) = multMagma(# (Auts (K,F)),(AutComp (K,F)) #) & Aut (E,F) = multMagma(# (Auts (E,F)),(AutComp (E,F)) #) & Aut (E1,K) = multMagma(# (Auts (E1,K)),(AutComp (E1,K)) #) ) by GALOIS_1:def 6;
H4: Aut (E,K) = Aut ((FieldExt (E,K)),K) by GALOIS_1:def 8
.= Aut (E1,K) ;
set f = Restr K;
K in IntermediateFields (E,F) by GALOIS_0:def 5;
then K is Subfield of E by FIELD_14:4;
then reconsider E1 = E as FieldExtension of K by FIELD_4:7;
C: now :: thesis: for o being object st o in the carrier of (Ker (Restr K)) holds
o in the carrier of (Aut (E,K))
let o be object ; :: thesis: ( o in the carrier of (Ker (Restr K)) implies o in the carrier of (Aut (E,K)) )
assume C1: o in the carrier of (Ker (Restr K)) ; :: thesis: o in the carrier of (Aut (E,K))
the carrier of (Ker (Restr K)) = { a where a is Element of (Aut (E,F)) : (Restr K) . a = 1_ (Aut (K,F)) } by GROUP_6:def 9;
then consider a being Element of the carrier of (Aut (E,F)) such that
C2: ( o = a & (Restr K) . a = 1_ (Aut (K,F)) ) by C1;
reconsider g = a as F -fixing Automorphism of E ;
g | K = a | the carrier of K by MATRLIN2:def 1
.= (Restr K) . a by AS, defR
.= 1_ (Aut K) by C2, GROUP_2:44
.= id K by GALOIS_1:6 ;
then g is K -fixing Automorphism of E1 by FIELD_8:35;
then o in { f where f is K -fixing Automorphism of E1 : verum } by C2;
hence o in the carrier of (Aut (E,K)) by H3, H4, GALOIS_1:def 4; :: thesis: verum
end;
D: now :: thesis: for o being object st o in the carrier of (Aut (E,K)) holds
o in the carrier of (Ker (Restr K))
let o be object ; :: thesis: ( o in the carrier of (Aut (E,K)) implies o in the carrier of (Ker (Restr K)) )
assume o in the carrier of (Aut (E,K)) ; :: thesis: o in the carrier of (Ker (Restr K))
then o in { f where f is K -fixing Automorphism of E1 : verum } by H3, H4, GALOIS_1:def 4;
then consider g being K -fixing Automorphism of E1 such that
C4: o = g ;
C5: the carrier of (Ker (Restr K)) = { a where a is Element of (Aut (E,F)) : (Restr K) . a = 1_ (Aut (K,F)) } by GROUP_6:def 9;
C6: g is F -fixing Automorphism of E by FIELD_8:37;
then g in { f where f is F -fixing Automorphism of E : verum } ;
then C7: g in Aut (E,F) by H3, GALOIS_1:def 4;
(Restr K) . g = g | the carrier of K by C6, AS, defR
.= g | K by MATRLIN2:def 1
.= id K by FIELD_8:35
.= 1_ (Aut K) by GALOIS_1:6
.= 1_ (Aut (K,F)) by GROUP_2:44 ;
hence o in the carrier of (Ker (Restr K)) by C7, C4, C5; :: thesis: verum
end;
Aut (E,K) is Subgroup of Aut (E,F) by GALOIS_1:18;
hence Ker (Restr K) = Aut (E,K) by C, D, TARSKI:2, GROUP_2:59; :: thesis: verum