let F be Field; :: thesis: for E being F -finite GaloisExtension of F
for K1, K2 being IntermediateField of E,F holds
( K1 is Subfield of K2 iff Aut (E,K2) is Subgroup of Aut (E,K1) )

let E be F -finite GaloisExtension of F; :: thesis: for K1, K2 being IntermediateField of E,F holds
( K1 is Subfield of K2 iff Aut (E,K2) is Subgroup of Aut (E,K1) )

let K1, K2 be IntermediateField of E,F; :: thesis: ( K1 is Subfield of K2 iff Aut (E,K2) is Subgroup of Aut (E,K1) )
set L = IntermediateFields E;
set P = LattPOSet (IntermediateFields E);
M: ( IntermediateFields E = LattStr(# (IntermediateFields (E,F)),(SubJoin E),(SubMeet E) #) & LattPOSet (IntermediateFields E) = RelStr(# the carrier of (IntermediateFields E),(LattRel (IntermediateFields E)) #) ) by LATTICE3:def 2;
reconsider K3 = K1, K4 = K2 as Element of the carrier of (LattPOSet (IntermediateFields E)) by M, GALOIS_0:def 5;
set L = SubgroupsAut E;
set G = Aut (E,F);
set R = LattPOSet (SubgroupsAut E);
M: ( SubgroupsAut E = LattStr(# (Subgroups (Aut (E,F))),(SubJoin (Aut (E,F))),(SubMeet (Aut (E,F))) #) & LattPOSet (SubgroupsAut E) = RelStr(# the carrier of (SubgroupsAut E),(LattRel (SubgroupsAut E)) #) ) by GROUP_4:def 12, LATTICE3:def 2;
( Aut (E,K1) is Subgroup of Aut (E,F) & Aut (E,K2) is Subgroup of Aut (E,F) ) by GALOIS_1:18;
then reconsider G1 = Aut (E,K1), G2 = Aut (E,K2) as Element of the carrier of (LattPOSet (SubgroupsAut E)) by M, GROUP_3:def 1;
N: Aut (E,K1) is Subgroup of Aut (E,F) by GALOIS_1:18;
then Aut (E,K1) in Subgroups (Aut (E,F)) by GROUP_3:def 1;
then reconsider G3 = Aut (E,K1) as SubGroup of Aut (E,F) by N, GALOIS_0:def 10;
N: Aut (E,K2) is Subgroup of Aut (E,F) by GALOIS_1:18;
then Aut (E,K2) in Subgroups (Aut (E,F)) by GROUP_3:def 1;
then reconsider G4 = Aut (E,K2) as SubGroup of Aut (E,F) by N, GALOIS_0:def 10;
H1: ( (Psi E) . K3 = G1 & (Psi E) . K4 = G2 ) by GALOIS_3:def 14;
H2: (Phi E) . G3 = Fix (E,G3) by GALOIS_3:def 15
.= K1 by G1 ;
H3: (Phi E) . G4 = Fix (E,G4) by GALOIS_3:def 15
.= K2 by G1 ;
A: now :: thesis: ( K1 is Subfield of K2 implies Aut (E,K2) is Subgroup of Aut (E,K1) )
assume K1 is Subfield of K2 ; :: thesis: Aut (E,K2) is Subgroup of Aut (E,K1)
then K3 <= K4 by GALOIS_0:32;
hence Aut (E,K2) is Subgroup of Aut (E,K1) by H1, GALOIS_0:15, WAYBEL_0:def 5; :: thesis: verum
end;
now :: thesis: ( Aut (E,K2) is Subgroup of Aut (E,K1) implies K1 is Subfield of K2 )
assume Aut (E,K2) is Subgroup of Aut (E,K1) ; :: thesis: K1 is Subfield of K2
then (Phi E) . G2 >= (Phi E) . G1 by GALOIS_0:15, WAYBEL_0:def 5;
hence K1 is Subfield of K2 by H2, H3, GALOIS_0:32; :: thesis: verum
end;
hence ( K1 is Subfield of K2 iff Aut (E,K2) is Subgroup of Aut (E,K1) ) by A; :: thesis: verum