let F be Field; :: thesis: for E being FieldExtension of F
for H being Subgroup of Aut (E,F)
for f being Element of the carrier of (Aut (E,F)) holds f .: (Fix (E,H)) = Fix (E,(H |^ (f ")))

let E be FieldExtension of F; :: thesis: for H being Subgroup of Aut (E,F)
for f being Element of the carrier of (Aut (E,F)) holds f .: (Fix (E,H)) = Fix (E,(H |^ (f ")))

let H be Subgroup of Aut (E,F); :: thesis: for f being Element of the carrier of (Aut (E,F)) holds f .: (Fix (E,H)) = Fix (E,(H |^ (f ")))
let f be Element of the carrier of (Aut (E,F)); :: thesis: f .: (Fix (E,H)) = Fix (E,(H |^ (f ")))
reconsider G = H |^ (f "), H1 = H as Subgroup of Aut E by GROUP_2:56;
A: the carrier of (Fix (E,G)) = Fixed_Elements (E,G) by GALOIS_1:def 17
.= { a where a is Element of E : for f being Function of E,E st f in G holds
f . a = a
}
by GALOIS_1:def 16 ;
B: the carrier of (f .: (Fix (E,H))) = rng (f,(Fix (E,H))) by FIELD_16:def 3;
reconsider f1 = f as F -fixing Automorphism of E ;
H1: ( dom f1 = the carrier of E & rng f1 = the carrier of E ) by FUNCT_2:def 1, FUNCT_2:def 3;
C: now :: thesis: for o being object st o in the carrier of (Fix (E,G)) holds
o in the carrier of (f .: (Fix (E,H)))
let o be object ; :: thesis: ( o in the carrier of (Fix (E,G)) implies o in the carrier of (f .: (Fix (E,H))) )
assume o in the carrier of (Fix (E,G)) ; :: thesis: o in the carrier of (f .: (Fix (E,H)))
then consider a being Element of E such that
C1: ( o = a & ( for g being Function of E,E st g in G holds
g . a = a ) ) by A;
set b = (f1 ") . a;
now :: thesis: for g being Function of E,E st g in H holds
g . ((f1 ") . a) = (f1 ") . a
let g be Function of E,E; :: thesis: ( g in H implies g . ((f1 ") . a) = (f1 ") . a )
assume D1: g in H ; :: thesis: g . ((f1 ") . a) = (f1 ") . a
the carrier of H c= the carrier of (Aut (E,F)) by GROUP_2:def 5;
then reconsider g1 = g as Element of (Aut (E,F)) by D1;
g1 |^ (f ") in G by D1, GROUP_3:58;
then D2: (((f ") ") * g1) * (f ") in G by GROUP_3:def 2;
( f * g1 = f1 * g & f " = f1 " ) by GALOIS_2:3, GALOIS_2:4;
then (f * g1) * (f ") = (f1 * g) * (f1 ") by GALOIS_2:3;
then D3: ((f1 * g) * (f1 ")) . a = a by D2, C1;
D4: ( dom (f1 ") = the carrier of E & dom (g * (f1 ")) = the carrier of E ) by FUNCT_2:def 1;
thus g . ((f1 ") . a) = (id the carrier of E) . (g . ((f1 ") . a))
.= ((f1 ") * f1) . (g . ((f1 ") . a)) by FUNCT_2:61
.= (f1 ") . (f1 . (g . ((f1 ") . a))) by H1, FUNCT_1:13
.= (f1 ") . (f1 . ((g * (f1 ")) . a)) by D4, FUNCT_1:13
.= (f1 ") . ((f1 * (g * (f1 "))) . a) by D4, FUNCT_1:13
.= (f1 ") . a by D3, RELAT_1:36 ; :: thesis: verum
end;
then (f1 ") . a in { a where a is Element of E : for f being Function of E,E st f in H holds
f . a = a
}
;
then (f1 ") . a in Fixed_El (E,H1) by GALOIS_1:def 16;
then C2: (f1 ") . a in the carrier of (Fix (E,H)) by GALOIS_1:def 17;
then (f1 ") . a in (dom f) /\ the carrier of (Fix (E,H)) by H1, XBOOLE_0:def 4;
then C3: (f1 ") . a in dom (f | the carrier of (Fix (E,H))) by RELAT_1:61;
(f | the carrier of (Fix (E,H))) . ((f1 ") . a) = f . ((f1 ") . a) by C2, FUNCT_1:49
.= a by H1, FUNCT_1:35 ;
hence o in the carrier of (f .: (Fix (E,H))) by B, C1, C3, FUNCT_1:def 3; :: thesis: verum
end;
now :: thesis: for o being object st o in the carrier of (f .: (Fix (E,H))) holds
o in the carrier of (Fix (E,G))
let o be object ; :: thesis: ( o in the carrier of (f .: (Fix (E,H))) implies o in the carrier of (Fix (E,G)) )
set h = f | the carrier of (Fix (E,H));
Fix (E,H1) is Subfield of E ;
then H0: the carrier of (Fix (E,H)) c= the carrier of E by EC_PF_1:def 1;
dom f = the carrier of E by FUNCT_2:def 1;
then (dom f) /\ the carrier of (Fix (E,H)) = the carrier of (Fix (E,H)) by H0, XBOOLE_1:28;
then H1: dom (f | the carrier of (Fix (E,H))) = the carrier of (Fix (E,H)) by RELAT_1:61;
assume o in the carrier of (f .: (Fix (E,H))) ; :: thesis: o in the carrier of (Fix (E,G))
then D0: o in rng (f,(Fix (E,H))) by FIELD_16:def 3;
consider y being object such that
D1: ( y in dom (f | the carrier of (Fix (E,H))) & (f | the carrier of (Fix (E,H))) . y = o ) by D0, FUNCT_1:def 3;
reconsider a = y, b = o as Element of E by D1, D0;
D2: now :: thesis: for g being Function of E,E st g in H holds
g . a = a
let g be Function of E,E; :: thesis: ( g in H implies g . a = a )
a in Fixed_El (E,H1) by D1, H1, GALOIS_1:def 17;
then a in { a where a is Element of E : for f being Function of E,E st f in H holds
f . a = a
}
by GALOIS_1:def 16;
then consider a1 being Element of E such that
D3: ( a1 = a & ( for f being Function of E,E st f in H holds
f . a1 = a1 ) ) ;
assume g in H ; :: thesis: g . a = a
hence g . a = a by D3; :: thesis: verum
end;
now :: thesis: for g being Function of E,E st g in G holds
g . b = b
let g be Function of E,E; :: thesis: ( g in G implies g . b = b )
assume g in G ; :: thesis: g . b = b
then consider g1 being Element of the carrier of (Aut (E,F)) such that
D3: ( g = g1 |^ (f ") & g1 in H ) by GROUP_3:58;
D4: g = (((f ") ") * g1) * (f ") by D3, GROUP_3:def 2;
( f * g1 = f1 * g1 & f " = f1 " ) by GALOIS_2:3, GALOIS_2:4;
then D5: (f * g1) * (f ") = (f1 * g1) * (f1 ") by GALOIS_2:3;
D6: ( dom f = the carrier of E & dom g1 = the carrier of E & dom (f1 ") = the carrier of E ) by FUNCT_2:def 1;
thus g . b = ((f1 * g1) * (f1 ")) . (f . a) by D5, D4, D1, H1, FUNCT_1:49
.= (f1 * g1) . ((f1 ") . (f . a)) by D6, FUNCT_1:13
.= (f1 * g1) . a by D6, FUNCT_1:34
.= f1 . (g1 . a) by D6, FUNCT_1:13
.= f1 . a by D2, D3
.= b by D1, H1, FUNCT_1:49 ; :: thesis: verum
end;
then b in { a where a is Element of E : for f being Function of E,E st f in G holds
f . a = a
}
;
then b in Fixed_El (E,G) by GALOIS_1:def 16;
hence o in the carrier of (Fix (E,G)) by GALOIS_1:def 17; :: thesis: verum
end;
hence f .: (Fix (E,H)) = Fix (E,(H |^ (f "))) by C, TARSKI:2, EC_PF_1:8; :: thesis: verum