let F be Field; :: thesis: for E being FieldExtension of F
for K being IntermediateField of E,F
for f being Element of the carrier of (Aut E) holds
( (Aut (E,(f .: K))) |^ f = Aut (E,K) & (Aut (E,K)) |^ (f ") = Aut (E,(f .: K)) )

let E be FieldExtension of F; :: thesis: for K being IntermediateField of E,F
for f being Element of the carrier of (Aut E) holds
( (Aut (E,(f .: K))) |^ f = Aut (E,K) & (Aut (E,K)) |^ (f ") = Aut (E,(f .: K)) )

let K be IntermediateField of E,F; :: thesis: for f being Element of the carrier of (Aut E) holds
( (Aut (E,(f .: K))) |^ f = Aut (E,K) & (Aut (E,K)) |^ (f ") = Aut (E,(f .: K)) )

let f be Element of the carrier of (Aut E); :: thesis: ( (Aut (E,(f .: K))) |^ f = Aut (E,K) & (Aut (E,K)) |^ (f ") = Aut (E,(f .: K)) )
reconsider E1 = E as FieldExtension of f .: K by FIELD_4:7;
H1: Aut (E,(f .: K)) = Aut ((FieldExt (E,(f .: K))),(f .: K)) by GALOIS_1:def 7
.= Aut (E1,(f .: K)) ;
H2: ( Aut (E1,(f .: K)) = multMagma(# (Auts (E1,(f .: K))),(AutComp (E1,(f .: K))) #) & Aut ((FieldExt (E,K)),K) = multMagma(# (Auts ((FieldExt (E,K)),K)),(AutComp ((FieldExt (E,K)),K)) #) ) by GALOIS_1:def 6;
K in IntermediateFields (E,F) by GALOIS_0:def 5;
then K is Subfield of E by FIELD_14:4;
then H3: the carrier of K c= the carrier of E by EC_PF_1:def 1;
H4: Aut (E,K) = Aut ((FieldExt (E,K)),K) by GALOIS_1:def 8;
H5: the carrier of (Aut (E,K)) c= the carrier of (Aut E) by GROUP_2:def 5;
reconsider f1 = f as Automorphism of E ;
A: now :: thesis: for o being object st o in the carrier of ((Aut (E,K)) |^ (f ")) holds
o in the carrier of (Aut (E,(f .: K)))
let o be object ; :: thesis: ( o in the carrier of ((Aut (E,K)) |^ (f ")) implies o in the carrier of (Aut (E,(f .: K))) )
assume o in the carrier of ((Aut (E,K)) |^ (f ")) ; :: thesis: o in the carrier of (Aut (E,(f .: K)))
then o in (Aut (E,K)) |^ (f ") ;
then consider g being Element of the carrier of (Aut E) such that
A1: ( o = g |^ (f ") & g in Aut (E,K) ) by GROUP_3:58;
reconsider g1 = g as K -fixing Automorphism of (FieldExt (E,K)) by A1, H4;
A2: o = (f1 * g1) * (f1 ")
proof
B: f1 " = f " by GALOIS_2:2;
then (f1 ") " = (f ") " by GALOIS_2:2;
then ((f1 ") ") * g1 = ((f ") ") * g by GALOIS_2:1;
then (((f1 ") ") * g1) * (f1 ") = (((f ") ") * g) * (f ") by B, GALOIS_2:1;
then (f1 * g1) * (f1 ") = (((f ") ") * g) * (f ") by FUNCT_1:43;
hence o = (f1 * g1) * (f1 ") by A1, GROUP_3:def 2; :: thesis: verum
end;
reconsider h = (f1 * g1) * (f1 ") as Automorphism of E1 ;
now :: thesis: for a being Element of (f .: K) holds ((f1 * g1) * (f1 ")) . a = a
let a be Element of (f .: K); :: thesis: ((f1 * g1) * (f1 ")) . a = a
a in the carrier of (f .: K) ;
then a in rng (f1,K) by FIELD_16:def 3;
then consider x being object such that
A3: ( x in dom (f | the carrier of K) & (f | the carrier of K) . x = a ) by FUNCT_1:def 3;
dom (f | the carrier of K) = (dom f) /\ the carrier of K by RELAT_1:61
.= the carrier of E /\ the carrier of K by FUNCT_2:def 1
.= the carrier of K by H3, XBOOLE_1:28 ;
then reconsider x = x as Element of K by A3;
A5: f1 . x = a by A3, FUNCT_1:49;
A7: ( dom (f1 ") = the carrier of E & dom g1 = the carrier of E & dom f1 = the carrier of E ) by FUNCT_2:def 1;
then x in dom f1 by H3;
then A6: (f1 ") . a = x by A5, FUNCT_1:34;
A8: the carrier of (f .: K) c= the carrier of E by EC_PF_1:def 1;
thus ((f1 * g1) * (f1 ")) . a = (f1 * g1) . x by A6, A7, A8, FUNCT_1:13
.= f1 . (g1 . x) by A7, A3, FUNCT_1:13
.= a by A5, FIELD_8:def 2 ; :: thesis: verum
end;
then h is f .: K -fixing ;
then o in { h where h is f .: K -fixing Automorphism of E1 : verum } by A2;
hence o in the carrier of (Aut (E,(f .: K))) by H1, H2, GALOIS_1:def 4; :: thesis: verum
end;
now :: thesis: for o being object st o in the carrier of (Aut (E,(f .: K))) holds
o in the carrier of ((Aut (E,K)) |^ (f "))
let o be object ; :: thesis: ( o in the carrier of (Aut (E,(f .: K))) implies o in the carrier of ((Aut (E,K)) |^ (f ")) )
assume o in the carrier of (Aut (E,(f .: K))) ; :: thesis: o in the carrier of ((Aut (E,K)) |^ (f "))
then o in { h where h is f .: K -fixing Automorphism of E1 : verum } by H1, H2, GALOIS_1:def 4;
then consider g1 being f .: K -fixing Automorphism of E1 such that
B0: o = g1 ;
reconsider h1 = ((f1 ") * g1) * f1 as Automorphism of (FieldExt (E,K)) ;
B2: ( dom (f1 ") = the carrier of E & dom g1 = the carrier of E & dom f1 = the carrier of E ) by FUNCT_2:def 1;
now :: thesis: for a being Element of K holds (((f1 ") * g1) * f1) . a = a
let a be Element of K; :: thesis: (((f1 ") * g1) * f1) . a = a
dom (f | the carrier of K) = (dom f) /\ the carrier of K by RELAT_1:61
.= the carrier of E /\ the carrier of K by FUNCT_2:def 1
.= the carrier of K by H3, XBOOLE_1:28 ;
then (f1 | the carrier of K) . a in rng (f1 | the carrier of K) by FUNCT_1:3;
then f1 . a in rng (f,K) by FUNCT_1:49;
then B1: f1 . a in f .: K by FIELD_16:def 3;
B3: ( rng f1 c= the carrier of E & a in dom f1 ) by B2, H3, RELAT_1:def 19;
then B4: f1 . a in the carrier of E by FUNCT_1:3;
thus (((f1 ") * g1) * f1) . a = ((f1 ") * g1) . (f1 . a) by H3, B2, FUNCT_1:13
.= (f1 ") . (g1 . (f1 . a)) by B4, B2, FUNCT_1:13
.= (f1 ") . (f1 . a) by B1, FIELD_8:def 2
.= a by B3, FUNCT_1:34 ; :: thesis: verum
end;
then h1 is K -fixing ;
then h1 in { h where h is K -fixing Automorphism of (FieldExt (E,K)) : verum } ;
then h1 in Auts ((FieldExt (E,K)),K) by GALOIS_1:def 4;
then C: h1 in Aut (E,K) by H2, GALOIS_1:def 8;
then reconsider h = h1 as Element of (Aut E) by H5;
D: (((f1 ") ") * h1) * (f1 ") = (((f ") ") * h) * (f ")
proof
B: f1 " = f " by GALOIS_2:2;
then (f1 ") " = (f ") " by GALOIS_2:2;
then ((f1 ") ") * h1 = ((f ") ") * h by GALOIS_2:1;
hence (((f1 ") ") * h1) * (f1 ") = (((f ") ") * h) * (f ") by B, GALOIS_2:1; :: thesis: verum
end;
E: rng f1 = the carrier of E by FUNCT_2:def 3;
(((f1 ") ") * h1) * (f1 ") = (f1 * (((f1 ") * g1) * f1)) * (f1 ") by FUNCT_1:43
.= (f1 * ((f1 ") * (g1 * f1))) * (f1 ") by RELAT_1:36
.= ((f1 * (f1 ")) * (g1 * f1)) * (f1 ") by RELAT_1:36
.= ((id E) * (g1 * f1)) * (f1 ") by E, FUNCT_2:29
.= (g1 * f1) * (f1 ") by FUNCT_2:17
.= g1 * (f1 * (f1 ")) by RELAT_1:36
.= g1 * (id E) by E, FUNCT_2:29
.= g1 by FUNCT_2:17 ;
then g1 = h |^ (f ") by D, GROUP_3:def 2;
then g1 in (Aut (E,K)) |^ (f ") by C, GROUP_3:58;
hence o in the carrier of ((Aut (E,K)) |^ (f ")) by B0; :: thesis: verum
end;
then (Aut (E,K)) |^ (f ") = Aut (E,(f .: K)) by A, TARSKI:2, GROUP_2:59;
hence ( (Aut (E,(f .: K))) |^ f = Aut (E,K) & (Aut (E,K)) |^ (f ") = Aut (E,(f .: K)) ) by GROUP_3:62; :: thesis: verum