let F be Field; :: thesis: for E being F -finite FieldExtension of F
for K being IntermediateField of E,F st K is F -normal holds
Fix (K,(Aut (K,F))) is Subfield of Fix (E,(Aut (E,F)))

let E be F -finite FieldExtension of F; :: thesis: for K being IntermediateField of E,F st K is F -normal holds
Fix (K,(Aut (K,F))) is Subfield of Fix (E,(Aut (E,F)))

let K be IntermediateField of E,F; :: thesis: ( K is F -normal implies Fix (K,(Aut (K,F))) is Subfield of Fix (E,(Aut (E,F))) )
assume AS: K is F -normal ; :: thesis: Fix (K,(Aut (K,F))) is Subfield of Fix (E,(Aut (E,F)))
set G = Aut (K,F);
K in IntermediateFields (E,F) by GALOIS_0:def 5;
then I: K is Subfield of E by FIELD_14:4;
then H: Fix (K,(Aut (K,F))) is Subfield of E by EC_PF_1:5;
set fG = Fixed_Elements (K,(Aut (K,F)));
set fE = Fixed_Elements (E,(Aut (E,F)));
J: ( Fixed_Elements (K,(Aut (K,F))) = { a where a is Element of K : for f being Function of K,K st f in Aut (K,F) holds
f . a = a
}
& Fixed_Elements (E,(Aut (E,F))) = { a where a is Element of E : for f being Function of E,E st f in Aut (E,F) holds
f . a = a
}
) by GALOIS_1:def 16;
K: Aut (K,F) = multMagma(# (Auts (K,F)),(AutComp (K,F)) #) by GALOIS_1:def 6;
now :: thesis: for o being object st o in Fixed_Elements (K,(Aut (K,F))) holds
o in Fixed_Elements (E,(Aut (E,F)))
let o be object ; :: thesis: ( o in Fixed_Elements (K,(Aut (K,F))) implies o in Fixed_Elements (E,(Aut (E,F))) )
assume o in Fixed_Elements (K,(Aut (K,F))) ; :: thesis: o in Fixed_Elements (E,(Aut (E,F)))
then consider a being Element of K such that
A: ( o = a & ( for f being Function of K,K st f in Aut (K,F) holds
f . a = a ) ) by J;
the carrier of K c= the carrier of E by I, EC_PF_1:def 1;
then reconsider a1 = a as Element of E ;
now :: thesis: for f being Function of E,E st f in Aut (E,F) holds
f . a1 = a1
let f be Function of E,E; :: thesis: ( f in Aut (E,F) implies f . a1 = a1 )
assume f in Aut (E,F) ; :: thesis: f . a1 = a1
then reconsider f1 = f as F -fixing Automorphism of E ;
reconsider g = f1 | the carrier of K as F -fixing Automorphism of K by AS, T4a;
g in { f where f is F -fixing Automorphism of K : verum } ;
then B1: g in Aut (K,F) by K, GALOIS_1:def 4;
thus f . a1 = g . a by FUNCT_1:49
.= a1 by A, B1 ; :: thesis: verum
end;
hence o in Fixed_Elements (E,(Aut (E,F))) by A, J; :: thesis: verum
end;
then Fixed_Elements (K,(Aut (K,F))) c= Fixed_Elements (E,(Aut (E,F))) ;
then the carrier of (Fix (K,(Aut (K,F)))) c= Fixed_Elements (E,(Aut (E,F))) by GALOIS_1:def 17;
then C: the carrier of (Fix (K,(Aut (K,F)))) c= the carrier of (Fix (E,(Aut (E,F)))) by GALOIS_1:def 17;
then C1: [: the carrier of (Fix (K,(Aut (K,F)))), the carrier of (Fix (K,(Aut (K,F)))):] c= [: the carrier of (Fix (E,(Aut (E,F)))), the carrier of (Fix (E,(Aut (E,F)))):] by ZFMISC_1:96;
D: the addF of (Fix (K,(Aut (K,F)))) = the addF of E || the carrier of (Fix (K,(Aut (K,F)))) by H, EC_PF_1:def 1
.= ( the addF of E || the carrier of (Fix (E,(Aut (E,F))))) || the carrier of (Fix (K,(Aut (K,F)))) by C1, FUNCT_1:51
.= the addF of (Fix (E,(Aut (E,F)))) || the carrier of (Fix (K,(Aut (K,F)))) by EC_PF_1:def 1 ;
E: the multF of (Fix (K,(Aut (K,F)))) = the multF of E || the carrier of (Fix (K,(Aut (K,F)))) by H, EC_PF_1:def 1
.= ( the multF of E || the carrier of (Fix (E,(Aut (E,F))))) || the carrier of (Fix (K,(Aut (K,F)))) by C1, FUNCT_1:51
.= the multF of (Fix (E,(Aut (E,F)))) || the carrier of (Fix (K,(Aut (K,F)))) by EC_PF_1:def 1 ;
F: 1. (Fix (K,(Aut (K,F)))) = 1. E by H, EC_PF_1:def 1
.= 1. (Fix (E,(Aut (E,F)))) by EC_PF_1:def 1 ;
0. (Fix (K,(Aut (K,F)))) = 0. E by H, EC_PF_1:def 1
.= 0. (Fix (E,(Aut (E,F)))) by EC_PF_1:def 1 ;
hence Fix (K,(Aut (K,F))) is Subfield of Fix (E,(Aut (E,F))) by C, D, E, F, EC_PF_1:def 1; :: thesis: verum