let G be Group; :: thesis: for H being Subgroup of G holds
( H is normal iff for g, h being Element of G st h in H holds
h |^ g in H )

let H be Subgroup of G; :: thesis: ( H is normal iff for g, h being Element of G st h in H holds
h |^ g in H )

hereby :: thesis: ( ( for g, h being Element of G st h in H holds
h |^ g in H ) implies H is normal )
assume H is normal ; :: thesis: for g, h being Element of G st h in H holds
h |^ g in H

then A1: for a being Element of G holds H |^ a = multMagma(# the carrier of H, the multF of H #) by GROUP_3:def 13;
thus for g, h being Element of G st h in H holds
h |^ g in H :: thesis: verum
proof
let g, h be Element of G; :: thesis: ( h in H implies h |^ g in H )
assume h in H ; :: thesis: h |^ g in H
then (g ") * (h * g) in (g ") * (H * g) by GROUP_2:104, GROUP_2:27;
then ((g ") * h) * g in (g ") * (H * g) by GROUP_1:def 3;
then ((g ") * h) * g in ((g ") * H) * g by GROUP_2:106;
then ((g ") * h) * g in H |^ g by GROUP_3:59;
then ((g ") * h) * g in H by A1;
hence h |^ g in H by GROUP_3:def 2; :: thesis: verum
end;
end;
assume B: for g, h being Element of G st h in H holds
h |^ g in H ; :: thesis: H is normal
now :: thesis: for a being Element of G holds H |^ a = multMagma(# the carrier of H, the multF of H #)
let a be Element of G; :: thesis: H |^ a = multMagma(# the carrier of H, the multF of H #)
B2: now :: thesis: for o being object st o in the carrier of (H |^ a) holds
o in the carrier of H
let o be object ; :: thesis: ( o in the carrier of (H |^ a) implies o in the carrier of H )
assume o in the carrier of (H |^ a) ; :: thesis: o in the carrier of H
then o in H |^ a ;
then consider b being Element of G such that
B3: ( o = b |^ a & b in H ) by GROUP_3:58;
b |^ a in H by B, B3;
hence o in the carrier of H by B3; :: thesis: verum
end;
now :: thesis: for o being object st o in the carrier of H holds
o in the carrier of (H |^ a)
let o be object ; :: thesis: ( o in the carrier of H implies o in the carrier of (H |^ a) )
assume C1: o in the carrier of H ; :: thesis: o in the carrier of (H |^ a)
the carrier of H c= the carrier of G by GROUP_2:def 5;
then reconsider b = o as Element of G by C1;
b in H by C1;
then b |^ (a ") in H by B;
then (((a ") ") * b) * (a ") in H by GROUP_3:def 2;
then ((a * b) * (a ")) * a in H * a by GROUP_2:104;
then (a * b) * ((a ") * a) in H * a by GROUP_1:def 3;
then (a * b) * (1_ G) in H * a by GROUP_1:def 5;
then a * b in H * a by GROUP_1:def 4;
then (a ") * (a * b) in (a ") * (H * a) by GROUP_2:27;
then ((a ") * a) * b in (a ") * (H * a) by GROUP_1:def 3;
then (1_ G) * b in (a ") * (H * a) by GROUP_1:def 5;
then b in (a ") * (H * a) by GROUP_1:def 4;
then b in ((a ") * H) * a by GROUP_2:106;
hence o in the carrier of (H |^ a) by GROUP_3:59; :: thesis: verum
end;
hence H |^ a = multMagma(# the carrier of H, the multF of H #) by B2, TARSKI:2, GROUP_2:59; :: thesis: verum
end;
hence H is normal by GROUP_3:def 13; :: thesis: verum