let F be Field; :: thesis: for E being FieldExtension of F
for p being non zero Element of the carrier of (Polynom-Ring F) st Roots (E,p) <> {} & E == FAdj (F,(Roots (E,p))) holds
Action-Roots (E,p) is faithful

let E be FieldExtension of F; :: thesis: for p being non zero Element of the carrier of (Polynom-Ring F) st Roots (E,p) <> {} & E == FAdj (F,(Roots (E,p))) holds
Action-Roots (E,p) is faithful

let p be non zero Element of the carrier of (Polynom-Ring F); :: thesis: ( Roots (E,p) <> {} & E == FAdj (F,(Roots (E,p))) implies Action-Roots (E,p) is faithful )
assume AS: ( Roots (E,p) <> {} & E == FAdj (F,(Roots (E,p))) ) ; :: thesis: Action-Roots (E,p) is faithful
then reconsider T = Roots (E,p) as non empty finite F -algebraic Subset of E ;
reconsider A = Action-Roots (E,p) as Action of Aut (E,F),T ;
set G = Aut (E,F);
set f = canHom A;
reconsider B = (Action-Aut (E,F)) | [: the carrier of (Aut (E,F)),T:] as Action of Aut (E,F),T by TH1;
[: the carrier of (Aut (E,F)),T:] c= [: the carrier of (Aut (E,F)), the carrier of E:] by ZFMISC_1:96;
then [: the carrier of (Aut (E,F)),T:] c= dom (Action-Aut (E,F)) by FUNCT_2:def 1;
then (dom (Action-Aut (E,F))) /\ [: the carrier of (Aut (E,F)),T:] = [: the carrier of (Aut (E,F)),T:] by XBOOLE_1:28;
then dom B = [: the carrier of (Aut (E,F)),T:] by RELAT_1:61;
then H0: dom A = [: the carrier of (Aut (E,F)),T:] by dar;
H1: 1_ (Aut (E,F)) = 1_ (Aut E) by GROUP_2:44
.= id E by GALOIS_1:6 ;
then H2: (canHom A) . (id E) = 1_ (SymGr T) by GROUP_6:31;
the carrier of (Ker (canHom A)) = { a where a is Element of (Aut (E,F)) : (canHom A) . a = 1_ (SymGr T) } by GROUP_6:def 9;
then id E in the carrier of (Ker (canHom A)) by H1, H2;
then H2: {(id E)} c= the carrier of (Ker (canHom A)) by TARSKI:def 1;
now :: thesis: for o being object st o in the carrier of (Ker (canHom A)) holds
o in {(id E)}
let o be object ; :: thesis: ( o in the carrier of (Ker (canHom A)) implies o in {(id E)} )
assume H3: o in the carrier of (Ker (canHom A)) ; :: thesis: o in {(id E)}
the carrier of (Ker (canHom A)) c= the carrier of (Aut (E,F)) by GROUP_2:def 5;
then reconsider g1 = o as Element of the carrier of (Aut (E,F)) by H3;
reconsider g = g1 as F -fixing Automorphism of E ;
H4: ( g is F -fixing Automorphism of (FAdj (F,T)) & id E is F -fixing Automorphism of (FAdj (F,T)) ) by AS, lemBB;
now :: thesis: for a being Element of E st a in T holds
(id E) . a = g . a
let a be Element of E; :: thesis: ( a in T implies (id E) . a = g . a )
assume K: a in T ; :: thesis: (id E) . a = g . a
then reconsider a1 = a as Element of T ;
H5: ( g1 in Ker (canHom A) & [g,a] in dom A ) by K, H3, H0, ZFMISC_1:def 2;
H6: apply (A,g1) = (canHom A) . g1 by defHom
.= 1_ (SymGr T) by H5, GROUP_6:41
.= id T by Th6 ;
thus (id E) . a = (id T) . a1
.= (Action-Roots (E,p)) . (g,a) by H6, defApp
.= ((Action-Aut (E,F)) | [: the carrier of (Aut (E,F)),T:]) . (g,a) by dar
.= (Action-Aut (E,F)) . (g,a) by H5, FUNCT_1:49
.= g . a by EF ; :: thesis: verum
end;
then g = id E by H4, TH2a;
hence o in {(id E)} by TARSKI:def 1; :: thesis: verum
end;
then the carrier of (Ker (canHom A)) c= {(id E)} ;
then Ker (canHom A) = (1). (Aut (E,F)) by H1, H2, XBOOLE_0:def 10, GROUP_2:def 7;
then canHom A is one-to-one by GROUP_6:56;
hence Action-Roots (E,p) is faithful by TF2; :: thesis: verum