let G be Group; :: thesis: for X being non empty set
for A being Action of G,X holds
( Ker (canHom A) = (1). G iff for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G )

let X be non empty set ; :: thesis: for A being Action of G,X holds
( Ker (canHom A) = (1). G iff for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G )

let A be Action of G,X; :: thesis: ( Ker (canHom A) = (1). G iff for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G )

B: now :: thesis: ( Ker (canHom A) = (1). G implies for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G )
assume C: Ker (canHom A) = (1). G ; :: thesis: for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G

now :: thesis: for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G
let g be Element of G; :: thesis: ( ( for x being Element of X holds A . (g,x) = x ) implies g = 1_ G )
assume D: for x being Element of X holds A . (g,x) = x ; :: thesis: g = 1_ G
E: now :: thesis: for o being object st o in X holds
(apply (A,g)) . o = (id X) . o
let o be object ; :: thesis: ( o in X implies (apply (A,g)) . o = (id X) . o )
assume o in X ; :: thesis: (apply (A,g)) . o = (id X) . o
then reconsider x = o as Element of X ;
thus (apply (A,g)) . o = A . (g,x) by defApp
.= (id X) . o by D ; :: thesis: verum
end;
(canHom A) . g = apply (A,g) by defHom
.= id X by E
.= 1_ (SymGr X) by Th6 ;
then g in Ker (canHom A) by GROUP_6:41;
then g in {(1_ G)} by C, GROUP_2:def 7;
hence g = 1_ G by TARSKI:def 1; :: thesis: verum
end;
hence for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G ; :: thesis: verum
end;
now :: thesis: ( ( for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G ) implies Ker (canHom A) = (1). G )
assume C: for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G ; :: thesis: Ker (canHom A) = (1). G
D: now :: thesis: for o being object st o in the carrier of ((1). G) holds
o in the carrier of (Ker (canHom A))
let o be object ; :: thesis: ( o in the carrier of ((1). G) implies o in the carrier of (Ker (canHom A)) )
assume o in the carrier of ((1). G) ; :: thesis: o in the carrier of (Ker (canHom A))
then o in {(1_ G)} by GROUP_2:def 7;
then o = 1_ G by TARSKI:def 1;
then o in Ker (canHom A) by GROUP_2:46;
hence o in the carrier of (Ker (canHom A)) ; :: thesis: verum
end;
now :: thesis: for o being object st o in the carrier of (Ker (canHom A)) holds
o in the carrier of ((1). G)
let o be object ; :: thesis: ( o in the carrier of (Ker (canHom A)) implies o in the carrier of ((1). G) )
assume E: o in the carrier of (Ker (canHom A)) ; :: thesis: o in the carrier of ((1). G)
the carrier of (Ker (canHom A)) = { a where a is Element of G : (canHom A) . a = 1_ (SymGr X) } by GROUP_6:def 9;
then consider g being Element of G such that
F: ( o = g & (canHom A) . g = 1_ (SymGr X) ) by E;
now :: thesis: for x being Element of X holds A . (g,x) = x
let x be Element of X; :: thesis: A . (g,x) = x
thus A . (g,x) = (apply (A,g)) . x by defApp
.= ((canHom A) . g) . x by defHom
.= (id X) . x by F, Th6
.= x ; :: thesis: verum
end;
then g = 1_ G by C;
then g in {(1_ G)} by TARSKI:def 1;
hence o in the carrier of ((1). G) by F, GROUP_2:def 7; :: thesis: verum
end;
hence Ker (canHom A) = (1). G by D, TARSKI:2, GROUP_2:59; :: thesis: verum
end;
hence ( Ker (canHom A) = (1). G iff for g being Element of G st ( for x being Element of X holds A . (g,x) = x ) holds
g = 1_ G ) by B; :: thesis: verum