let F1, F2 be Field; :: thesis: for E1 being FieldExtension of F1
for E2 being FieldExtension of F2
for f being F1 -fixing Automorphism of E1 st E1 == E2 & F1 == F2 holds
f is F2 -fixing Automorphism of E2

let E1 be FieldExtension of F1; :: thesis: for E2 being FieldExtension of F2
for f being F1 -fixing Automorphism of E1 st E1 == E2 & F1 == F2 holds
f is F2 -fixing Automorphism of E2

let E2 be FieldExtension of F2; :: thesis: for f being F1 -fixing Automorphism of E1 st E1 == E2 & F1 == F2 holds
f is F2 -fixing Automorphism of E2

let f be F1 -fixing Automorphism of E1; :: thesis: ( E1 == E2 & F1 == F2 implies f is F2 -fixing Automorphism of E2 )
assume AS: ( E1 == E2 & F1 == F2 ) ; :: thesis: f is F2 -fixing Automorphism of E2
then reconsider g = f as Function of E2,E2 ;
A: g is F2 -fixing by AS, FIELD_8:def 2;
now :: thesis: for a2, b2 being Element of E2 holds
( g . (a2 + b2) = (g . a2) + (g . b2) & g . (a2 * b2) = (g . a2) * (g . b2) )
let a2, b2 be Element of E2; :: thesis: ( g . (a2 + b2) = (g . a2) + (g . b2) & g . (a2 * b2) = (g . a2) * (g . b2) )
reconsider a1 = a2, b1 = b2 as Element of E1 by AS;
a1 + b1 = a2 + b2 by AS;
hence g . (a2 + b2) = (f . a1) + (f . b1) by VECTSP_1:def 20
.= (g . a2) + (g . b2) by AS ;
:: thesis: g . (a2 * b2) = (g . a2) * (g . b2)
a1 * b1 = a2 * b2 by AS;
hence g . (a2 * b2) = (f . a1) * (f . b1) by GROUP_6:def 6
.= (g . a2) * (g . b2) by AS ;
:: thesis: verum
end;
then B: ( g is additive & g is multiplicative ) ;
g . (1_ E2) = 1_ E1 by AS, GROUP_1:def 13
.= 1_ E2 by AS ;
then g is unity-preserving ;
hence f is F2 -fixing Automorphism of E2 by A, B, AS; :: thesis: verum