let F be Field; :: thesis: for E being FieldExtension of F
for f being non empty FinSequence of the carrier of (Polynom-Ring F)
for q being Polynomial of F
for a being Element of E st q = Product f & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) holds
Ext_eval (q,a) <> 0. E

let E be FieldExtension of F; :: thesis: for f being non empty FinSequence of the carrier of (Polynom-Ring F)
for q being Polynomial of F
for a being Element of E st q = Product f & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) holds
Ext_eval (q,a) <> 0. E

let f be non empty FinSequence of the carrier of (Polynom-Ring F); :: thesis: for q being Polynomial of F
for a being Element of E st q = Product f & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) holds
Ext_eval (q,a) <> 0. E

let q be Polynomial of F; :: thesis: for a being Element of E st q = Product f & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) holds
Ext_eval (q,a) <> 0. E

let a be Element of E; :: thesis: ( q = Product f & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) implies Ext_eval (q,a) <> 0. E )

assume AS: ( q = Product f & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) ) ; :: thesis: Ext_eval (q,a) <> 0. E
defpred S1[ Nat] means for f being non empty FinSequence of the carrier of (Polynom-Ring F)
for q being Polynomial of F
for a being Element of E st q = Product f & len f = $1 & ( for i being Element of dom f
for p being Polynomial of F st p = f . i holds
Ext_eval (p,a) <> 0. E ) holds
Ext_eval (q,a) <> 0. E;
IA: S1[ 0 ] ;
IS: now :: thesis: for k being Nat st S1[k] holds
S1[k + 1]
let k be Nat; :: thesis: ( S1[k] implies S1[k + 1] )
assume IV: S1[k] ; :: thesis: S1[k + 1]
now :: thesis: for f being non empty FinSequence of (Polynom-Ring F)
for p being Element of the carrier of (Polynom-Ring F)
for a being Element of E st p = Product f & len f = k + 1 & ( for i being Element of dom f
for q being Polynomial of F st q = f . i holds
Ext_eval (q,a) <> 0. E ) holds
Ext_eval (p,a) <> 0. E
let f be non empty FinSequence of (Polynom-Ring F); :: thesis: for p being Element of the carrier of (Polynom-Ring F)
for a being Element of E st p = Product f & len f = k + 1 & ( for i being Element of dom f
for q being Polynomial of F st q = f . i holds
Ext_eval (q,a) <> 0. E ) holds
Ext_eval (b4,b5) <> 0. E

let p be Element of the carrier of (Polynom-Ring F); :: thesis: for a being Element of E st p = Product f & len f = k + 1 & ( for i being Element of dom f
for q being Polynomial of F st q = f . i holds
Ext_eval (q,a) <> 0. E ) holds
Ext_eval (b3,b4) <> 0. E

let a be Element of E; :: thesis: ( p = Product f & len f = k + 1 & ( for i being Element of dom f
for q being Polynomial of F st q = f . i holds
Ext_eval (q,a) <> 0. E ) implies Ext_eval (b2,b3) <> 0. E )

assume A1: ( p = Product f & len f = k + 1 & ( for i being Element of dom f
for q being Polynomial of F st q = f . i holds
Ext_eval (q,a) <> 0. E ) ) ; :: thesis: Ext_eval (b2,b3) <> 0. E
consider g being FinSequence of the carrier of (Polynom-Ring F), r1 being Element of the carrier of (Polynom-Ring F) such that
A3: f = g ^ <*r1*> by A1, FINSEQ_2:19;
A4: len f = (len g) + 1 by A3, FINSEQ_2:16;
reconsider q = Product g, r2 = r1 as Polynomial of F by POLYNOM3:def 10;
A5: p = (Product g) * r1 by A1, A3, GROUP_4:6
.= q *' r2 by POLYNOM3:def 10 ;
F is Subring of E by FIELD_4:def 1;
then A8: Ext_eval (p,a) = (Ext_eval (q,a)) * (Ext_eval (r2,a)) by A5, ALGNUM_1:20;
A6: ( f . (len f) = r2 & 1 <= len f ) by A3, A4, FINSEQ_1:42, FINSEQ_1:20;
then len f in Seg (len f) ;
then A7: len f in dom f by FINSEQ_1:def 3;
then A9: Ext_eval (r2,a) <> 0. E by A6, A1;
per cases ( g = {} or g <> {} ) ;
suppose g = {} ; :: thesis: Ext_eval (b2,b3) <> 0. E
then g = <*> the carrier of (Polynom-Ring F) ;
then q = 1_ (Polynom-Ring F) by GROUP_4:8
.= 1_. F by POLYNOM3:def 10 ;
hence Ext_eval (p,a) <> 0. E by A5, A7, A6, A1; :: thesis: verum
end;
suppose g <> {} ; :: thesis: Ext_eval (b2,b3) <> 0. E
then reconsider g = g as non empty FinSequence of the carrier of (Polynom-Ring F) ;
now :: thesis: for i being Element of dom g
for r being Polynomial of F st r = g . i holds
Ext_eval (r,a) <> 0. E
let i be Element of dom g; :: thesis: for r being Polynomial of F st r = g . i holds
Ext_eval (r,a) <> 0. E

let r be Polynomial of F; :: thesis: ( r = g . i implies Ext_eval (r,a) <> 0. E )
assume B1: r = g . i ; :: thesis: Ext_eval (r,a) <> 0. E
i in dom g ;
then i in Seg (len g) by FINSEQ_1:def 3;
then B3: ( 1 <= i & i <= len g ) by FINSEQ_1:1;
then i + 0 < len f by A4, XREAL_1:8;
then i in Seg (len f) by B3;
then B4: i in dom f by FINSEQ_1:def 3;
r = f . i by A3, B1, FINSEQ_1:def 7;
hence Ext_eval (r,a) <> 0. E by B4, A1; :: thesis: verum
end;
then Ext_eval (q,a) <> 0. E by A4, A1, IV;
hence Ext_eval (p,a) <> 0. E by A9, A8, VECTSP_2:def 1; :: thesis: verum
end;
end;
end;
hence S1[k + 1] ; :: thesis: verum
end;
I: for k being Nat holds S1[k] from NAT_1:sch 2(IA, IS);
consider n being Nat such that
H: len f = n ;
thus Ext_eval (q,a) <> 0. E by I, H, AS; :: thesis: verum