let F be Field; :: thesis: for E being F -finite FieldExtension of F ex p being non constant Element of the carrier of (Polynom-Ring F) ex K being SplittingField of p st K is E -extending
let E be F -finite FieldExtension of F; :: thesis: ex p being non constant Element of the carrier of (Polynom-Ring F) ex K being SplittingField of p st K is E -extending
consider T being finite F -algebraic Subset of E such that
A: E == FAdj (F,T) by FIELD_7:37;
per cases ( T = {} or T <> {} ) ;
suppose T = {} ; :: thesis: ex p being non constant Element of the carrier of (Polynom-Ring F) ex K being SplittingField of p st K is E -extending
then T c= the carrier of F ;
then FAdj (F,T) == F by FIELD_7:3;
then A2: E == F by A;
set a = the Element of F;
set p = X- the Element of F;
F is SplittingField of X- the Element of F by FIELD_13:17;
then reconsider K = E as SplittingField of X- the Element of F by A2, FIELD_13:16;
take X- the Element of F ; :: thesis: ex K being SplittingField of X- the Element of F st K is E -extending
take K ; :: thesis: K is E -extending
E is Subfield of E by FIELD_4:1;
hence K is E -extending by FIELD_4:7; :: thesis: verum
end;
suppose T <> {} ; :: thesis: ex p being non constant Element of the carrier of (Polynom-Ring F) ex K being SplittingField of p st K is E -extending
then reconsider T = T as non empty finite F -algebraic Subset of E ;
set p = ProductMinPolys T;
set f = FinSeq_MinPolys T;
set S = MinPolys T;
take ProductMinPolys T ; :: thesis: ex K being SplittingField of ProductMinPolys T st K is E -extending
the carrier of (Polynom-Ring F) c= the carrier of (Polynom-Ring E) by FIELD_4:10;
then reconsider p1 = ProductMinPolys T as Element of the carrier of (Polynom-Ring E) ;
( deg (ProductMinPolys T) > 0 & deg p1 = deg (ProductMinPolys T) ) by FIELD_4:20, RING_4:def 4;
then reconsider p1 = p1 as non constant Element of the carrier of (Polynom-Ring E) by RING_4:def 4;
set K = the SplittingField of p1;
reconsider K = the SplittingField of p1 as E -extending FieldExtension of F ;
E0: E is Subfield of K by FIELD_4:7;
now :: thesis: for o being object st o in T holds
o in Roots (K,p1)
let o be object ; :: thesis: ( o in T implies o in Roots (K,p1) )
assume E1: o in T ; :: thesis: o in Roots (K,p1)
then reconsider a = o as Element of E ;
the carrier of E c= the carrier of K by E0, EC_PF_1:def 1;
then reconsider a1 = a as Element of K ;
( MinPoly (a,F) in MinPolys T & rng (FinSeq_MinPolys T) = MinPolys T ) by E1, FUNCT_2:def 3;
then consider i being object such that
E2: ( i in dom (FinSeq_MinPolys T) & MinPoly (a,F) = (FinSeq_MinPolys T) . i ) by FUNCT_1:def 3;
reconsider i = i as Element of dom (FinSeq_MinPolys T) by E2;
Ext_eval ((MinPoly (a,F)),a) = 0. E by FIELD_6:52;
then 0. E = Ext_eval ((ProductMinPolys T),a) by E2, FIELD_13:4
.= Ext_eval ((ProductMinPolys T),a1) by FIELD_7:14
.= Ext_eval (p1,a1) by FIELD_7:15 ;
then Ext_eval (p1,a1) = 0. K by E0, EC_PF_1:def 1;
then E3: a1 is_a_root_of p1,K by FIELD_4:def 2;
Roots (K,p1) = { a where a is Element of K : a is_a_root_of p1,K } by FIELD_4:def 4;
hence o in Roots (K,p1) by E3; :: thesis: verum
end;
then T c= Roots (K,p1) ;
then reconsider K = K as SplittingField of ProductMinPolys T by A, FIELD_13:23;
take K ; :: thesis: K is E -extending
thus K is E -extending ; :: thesis: verum
end;
end;