let F be Field; :: thesis: for E being FieldExtension of F
for T being finite Subset of E holds
( FAdj (F,T) is F -separable iff for a being Element of E st a in T holds
a is F -separable )

let E be FieldExtension of F; :: thesis: for T being finite Subset of E holds
( FAdj (F,T) is F -separable iff for a being Element of E st a in T holds
a is F -separable )

let T be finite Subset of E; :: thesis: ( FAdj (F,T) is F -separable iff for a being Element of E st a in T holds
a is F -separable )

I: now :: thesis: ( ( for a being Element of E st a in T holds
a is F -separable ) implies FAdj (F,T) is F -separable )
assume A: for a being Element of E st a in T holds
a is F -separable ; :: thesis: FAdj (F,T) is F -separable
per cases ( T = {} or T <> {} ) ;
suppose T = {} ; :: thesis: FAdj (F,T) is F -separable
then T c= the carrier of F ;
then A1: FAdj (F,T) == F by FIELD_7:3;
set a = the Element of F;
set p = X- the Element of F;
F is SplittingField of X- the Element of F by FIELD_13:17;
then reconsider K = FAdj (F,T) as SplittingField of X- the Element of F by A1, FIELD_13:16;
K is F -Galois ;
hence FAdj (F,T) is F -separable ; :: thesis: verum
end;
suppose T <> {} ; :: thesis: FAdj (F,T) is F -separable
then reconsider T1 = T as non empty finite F -separable Subset of E by A, defT;
set p = ProductMinPolys T1;
set f = FinSeq_MinPolys T1;
set S = MinPolys T1;
the carrier of (Polynom-Ring F) c= the carrier of (Polynom-Ring (FAdj (F,T))) by FIELD_4:10;
then reconsider p1 = ProductMinPolys T1 as Element of the carrier of (Polynom-Ring (FAdj (F,T))) ;
( deg (ProductMinPolys T1) > 0 & deg p1 = deg (ProductMinPolys T1) ) by FIELD_4:20, RING_4:def 4;
then reconsider p1 = p1 as non constant Element of the carrier of (Polynom-Ring (FAdj (F,T))) by RING_4:def 4;
set K = the SplittingField of p1;
reconsider K = the SplittingField of p1 as FAdj (F,T) -extending FieldExtension of F ;
reconsider T2 = T1 as finite F -algebraic Subset of (FAdj (F,T)) by FIELD_6:35;
H: E is FAdj (F,T) -extending by FIELD_4:7;
E0: ( FAdj (F,T) is Subfield of K & FAdj (F,T) is Subfield of E ) by FIELD_4:7;
now :: thesis: for o being object st o in T2 holds
o in Roots (K,p1)
let o be object ; :: thesis: ( o in T2 implies o in Roots (K,p1) )
assume E1: o in T2 ; :: thesis: o in Roots (K,p1)
then reconsider a = o as F -algebraic Element of (FAdj (F,T)) ;
reconsider a1 = a as F -algebraic Element of E by E1;
the carrier of (FAdj (F,T)) c= the carrier of K by E0, EC_PF_1:def 1;
then reconsider a2 = a1 as Element of K ;
( MinPoly (a1,F) in MinPolys T1 & rng (FinSeq_MinPolys T1) = MinPolys T1 ) by E1, FUNCT_2:def 3;
then consider i being object such that
E2: ( i in dom (FinSeq_MinPolys T1) & MinPoly (a1,F) = (FinSeq_MinPolys T1) . i ) by FUNCT_1:def 3;
reconsider i = i as Element of dom (FinSeq_MinPolys T1) by E2;
Ext_eval ((MinPoly (a1,F)),a1) = 0. E by FIELD_6:52;
then 0. E = Ext_eval ((ProductMinPolys T1),a1) by E2, FIELD_13:4
.= Ext_eval ((ProductMinPolys T1),a) by H, FIELD_7:14
.= Ext_eval ((ProductMinPolys T1),a2) by FIELD_7:14
.= Ext_eval (p1,a2) by FIELD_7:15 ;
then Ext_eval (p1,a2) = 0. (FAdj (F,T)) by EC_PF_1:def 1;
then Ext_eval (p1,a2) = 0. K by E0, EC_PF_1:def 1;
then E3: a2 is_a_root_of p1,K by FIELD_4:def 2;
Roots (K,p1) = { a where a is Element of K : a is_a_root_of p1,K } by FIELD_4:def 4;
hence o in Roots (K,p1) by E3; :: thesis: verum
end;
then ( T2 c= Roots (K,p1) & FAdj (F,T2) == FAdj (F,T) ) by H, FIELD_13:19;
then reconsider K = K as SplittingField of ProductMinPolys T1 by FIELD_13:23;
K is F -Galois ;
hence FAdj (F,T) is F -separable by FIELD_15:94; :: thesis: verum
end;
end;
end;
now :: thesis: ( FAdj (F,T) is F -separable implies for a being Element of E st a in T holds
a is F -separable )
assume A: FAdj (F,T) is F -separable ; :: thesis: for a being Element of E st a in T holds
a is F -separable

now :: thesis: for a being Element of E st a in T holds
a is F -separable
let a be Element of E; :: thesis: ( a in T implies a is F -separable )
assume B: a in T ; :: thesis: a is F -separable
T is Subset of (FAdj (F,T)) by FIELD_6:35;
then reconsider a1 = a as F -algebraic Element of (FAdj (F,T)) by A, B;
consider q being non zero Polynomial of F such that
H: Ext_eval (q,a1) = 0. (FAdj (F,T)) by FIELD_6:43;
( E is FAdj (F,T) -extending & q is Element of the carrier of (Polynom-Ring F) ) by POLYNOM3:def 10, FIELD_4:7;
then ( Ext_eval (q,a) = Ext_eval (q,a1) & 0. (FAdj (F,T)) = 0. E ) by FIELD_6:11, EC_PF_1:def 1;
then reconsider a2 = a as F -algebraic Element of E by H, FIELD_6:43;
E is FAdj (F,T) -extending by FIELD_4:7;
then MinPoly (a1,F) = MinPoly (a2,F) by FIELD_10:10;
hence a is F -separable by A, FIELD_15:def 5; :: thesis: verum
end;
hence for a being Element of E st a in T holds
a is F -separable ; :: thesis: verum
end;
hence ( FAdj (F,T) is F -separable iff for a being Element of E st a in T holds
a is F -separable ) by I; :: thesis: verum