let F be Field; :: thesis: for p being non constant Element of the carrier of (Polynom-Ring F)
for E being SplittingField of p
for a, b being Element of E st a in Roots (E,p) & b in Roots (E,p) & MinPoly (a,F) = MinPoly (b,F) holds
ex h being F -fixing Automorphism of E st h . a = b

let p be non constant Element of the carrier of (Polynom-Ring F); :: thesis: for E being SplittingField of p
for a, b being Element of E st a in Roots (E,p) & b in Roots (E,p) & MinPoly (a,F) = MinPoly (b,F) holds
ex h being F -fixing Automorphism of E st h . a = b

let E be SplittingField of p; :: thesis: for a, b being Element of E st a in Roots (E,p) & b in Roots (E,p) & MinPoly (a,F) = MinPoly (b,F) holds
ex h being F -fixing Automorphism of E st h . a = b

let a, b be Element of E; :: thesis: ( a in Roots (E,p) & b in Roots (E,p) & MinPoly (a,F) = MinPoly (b,F) implies ex h being F -fixing Automorphism of E st h . a = b )
assume AS: ( a in Roots (E,p) & b in Roots (E,p) & MinPoly (a,F) = MinPoly (b,F) ) ; :: thesis: ex h being F -fixing Automorphism of E st h . a = b
set q = MinPoly (a,F);
id F is isomorphism ;
then reconsider F1 = F as F -homomorphic F -isomorphic Field by RING_3:def 4, RING_2:def 4;
reconsider h = id F as Isomorphism of F,F1 ;
reconsider E1 = E as FieldExtension of F1 ;
reconsider b1 = b as Element of E1 ;
A: Ext_eval ((MinPoly (a,F)),a) = 0. E by FIELD_6:52;
now :: thesis: for i being Nat holds ((PolyHom h) . (MinPoly (a,F))) . i = (MinPoly (a,F)) . i
let i be Nat; :: thesis: ((PolyHom h) . (MinPoly (a,F))) . i = (MinPoly (a,F)) . i
thus ((PolyHom h) . (MinPoly (a,F))) . i = h . ((MinPoly (a,F)) . i) by FIELD_1:def 2
.= (MinPoly (a,F)) . i ; :: thesis: verum
end;
then (PolyHom h) . (MinPoly (a,F)) = MinPoly (a,F) ;
then B: Ext_eval (((PolyHom h) . (MinPoly (a,F))),b) = 0. E1 by AS, FIELD_6:52;
then C: ( Psi (a,b1,h,(MinPoly (a,F))) is h -extending & Psi (a,b1,h,(MinPoly (a,F))) is isomorphism ) by A, FIELD_8:55;
then reconsider K1 = FAdj (F,{b}) as FAdj (F,{a}) -homomorphic FAdj (F,{a}) -isomorphic Field by RING_3:def 4, RING_2:def 4;
reconsider g = Psi (a,b1,h,(MinPoly (a,F))) as Isomorphism of (FAdj (F,{a})),K1 by C;
the carrier of (Polynom-Ring F) c= the carrier of (Polynom-Ring (FAdj (F,{a}))) by FIELD_4:10;
then reconsider p1 = p as Element of the carrier of (Polynom-Ring (FAdj (F,{a}))) ;
( deg p > 0 & deg p = deg p1 ) by RING_4:def 4, FIELD_4:20;
then reconsider p1 = p1 as non constant Element of the carrier of (Polynom-Ring (FAdj (F,{a}))) by RING_4:def 4;
E is FAdj (F,{a}) -extending by FIELD_4:7;
then reconsider E2 = E as SplittingField of p1 by FIELD_8:53;
now :: thesis: for i being Nat holds ((PolyHom g) . p1) . i = p1 . i
let i be Nat; :: thesis: ((PolyHom g) . p1) . i = p1 . i
thus ((PolyHom g) . p1) . i = g . (p . i) by FIELD_1:def 2
.= h . (p . i) by C
.= p1 . i ; :: thesis: verum
end;
then (PolyHom g) . p1 = p1 ;
then reconsider E3 = E as SplittingField of (PolyHom g) . p1 by spl1;
consider f being Function of E2,E3 such that
D: ( f is g -extending & f is isomorphism ) by FIELD_8:57;
reconsider f = f as Automorphism of E by D;
now :: thesis: for c being Element of F holds f . c = c
let c be Element of F; :: thesis: f . c = c
F is Subfield of FAdj (F,{a}) by FIELD_4:7;
then the carrier of F c= the carrier of (FAdj (F,{a})) by EC_PF_1:def 1;
then c in FAdj (F,{a}) ;
hence f . c = g . c by D
.= h . c by C
.= c ;
:: thesis: verum
end;
then f is F -fixing ;
then reconsider f = f as F -fixing Automorphism of E ;
take f ; :: thesis: f . a = b
( a in {a} & {a} is Subset of (FAdj (F,{a})) ) by TARSKI:def 1, FIELD_6:35;
hence f . a = g . a by D
.= b by A, B, FIELD_13:26 ;
:: thesis: verum