let F be Field; :: thesis: for E being F -finite FieldExtension of F st E is F -normal & E is F -separable holds
ex p being non constant separable Element of (Polynom-Ring F) st E is SplittingField of p

let E be F -finite FieldExtension of F; :: thesis: ( E is F -normal & E is F -separable implies ex p being non constant separable Element of (Polynom-Ring F) st E is SplittingField of p )
assume AS: ( E is F -normal & E is F -separable ) ; :: thesis: ex p being non constant separable Element of (Polynom-Ring F) st E is SplittingField of p
consider T being finite F -algebraic Subset of E such that
A: E == FAdj (F,T) by FIELD_7:37;
consider u being non constant Element of the carrier of (Polynom-Ring F) such that
A0: E is SplittingField of u by AS, FIELD_13:55;
A1: FAdj (F,T) is F -normal by A, A0, FIELD_13:16;
per cases ( T = {} or T <> {} ) ;
suppose T = {} ; :: thesis: ex p being non constant separable Element of (Polynom-Ring F) st E is SplittingField of p
end;
suppose T <> {} ; :: thesis: ex p being non constant separable Element of (Polynom-Ring F) st E is SplittingField of p
then reconsider T = T as non empty finite F -separable Subset of E by AS;
set p = ProductMinPolys T;
set f = FinSeq_MinPolys T;
set S = MinPolys T;
deg (ProductMinPolys T) > 0 by RING_4:def 4;
then I: ProductMinPolys T is non constant Polynomial of F by RATFUNC1:def 2;
now :: thesis: for i being Element of dom (FinSeq_MinPolys T)
for q being Polynomial of F holds
( not q = (FinSeq_MinPolys T) . i or q is constant or q splits_in FAdj (F,T) )
let i be Element of dom (FinSeq_MinPolys T); :: thesis: for q being Polynomial of F holds
( not q = (FinSeq_MinPolys T) . i or q is constant or q splits_in FAdj (F,T) )

let q be Polynomial of F; :: thesis: ( not q = (FinSeq_MinPolys T) . i or q is constant or q splits_in FAdj (F,T) )
assume C3: q = (FinSeq_MinPolys T) . i ; :: thesis: ( q is constant or q splits_in FAdj (F,T) )
rng (FinSeq_MinPolys T) c= MinPolys T by FINSEQ_1:def 4;
then (FinSeq_MinPolys T) . i in MinPolys T by FUNCT_1:3;
then consider a being F -algebraic Element of E such that
C4: ( (FinSeq_MinPolys T) . i = MinPoly (a,F) & a in T ) ;
T is Subset of (FAdj (F,T)) by FIELD_6:35;
then reconsider a1 = a as Element of (FAdj (F,T)) by C4;
E is FAdj (F,T) -extending by FIELD_4:7;
then Ext_eval ((MinPoly (a,F)),a1) = Ext_eval ((MinPoly (a,F)),a) by FIELD_6:11
.= 0. E by FIELD_6:52
.= 0. (FAdj (F,T)) by EC_PF_1:def 1 ;
then a1 is_a_root_of MinPoly (a,F), FAdj (F,T) by FIELD_4:def 2;
hence ( q is constant or q splits_in FAdj (F,T) ) by A1, C3, C4, FIELD_13:def 5, FIELD_4:def 3; :: thesis: verum
end;
then E: ProductMinPolys T splits_in FAdj (F,T) by I, FIELD_13:6;
now :: thesis: for K being FieldExtension of F st ProductMinPolys T splits_in K & K is Subfield of FAdj (F,T) holds
K == FAdj (F,T)
let K be FieldExtension of F; :: thesis: ( ProductMinPolys T splits_in K & K is Subfield of FAdj (F,T) implies K == FAdj (F,T) )
assume E1: ( ProductMinPolys T splits_in K & K is Subfield of FAdj (F,T) ) ; :: thesis: K == FAdj (F,T)
then FAdj (F,T) is K -extending by FIELD_4:7;
then E2: Roots ((FAdj (F,T)),(ProductMinPolys T)) c= the carrier of K by E, E1, FIELD_8:27;
E3: ( K is Subfield of E & F is Subfield of K ) by E1, EC_PF_1:5, FIELD_4:7;
now :: thesis: for o being object st o in T holds
o in Roots ((FAdj (F,T)),(ProductMinPolys T))
let o be object ; :: thesis: ( o in T implies o in Roots ((FAdj (F,T)),(ProductMinPolys T)) )
assume E4: o in T ; :: thesis: o in Roots ((FAdj (F,T)),(ProductMinPolys T))
then reconsider a = o as F -algebraic Element of E ;
T is Subset of (FAdj (F,T)) by FIELD_6:35;
then reconsider a1 = a as Element of (FAdj (F,T)) by E4;
E is FAdj (F,T) -extending by FIELD_4:7;
then E5: Ext_eval ((MinPoly (a,F)),a1) = Ext_eval ((MinPoly (a,F)),a) by FIELD_6:11
.= 0. E by FIELD_6:52
.= 0. (FAdj (F,T)) by EC_PF_1:def 1 ;
rng (FinSeq_MinPolys T) = MinPolys T by FUNCT_2:def 3;
then MinPoly (a,F) in rng (FinSeq_MinPolys T) by E4;
then consider i being object such that
E6: ( i in dom (FinSeq_MinPolys T) & MinPoly (a,F) = (FinSeq_MinPolys T) . i ) by FUNCT_1:def 3;
reconsider i = i as Element of dom (FinSeq_MinPolys T) by E6;
Ext_eval ((ProductMinPolys T),a1) = 0. (FAdj (F,T)) by E5, E6, FIELD_13:4;
then E7: a1 is_a_root_of ProductMinPolys T, FAdj (F,T) by FIELD_4:def 2;
Roots ((FAdj (F,T)),(ProductMinPolys T)) = { a where a is Element of (FAdj (F,T)) : a is_a_root_of ProductMinPolys T, FAdj (F,T) } by FIELD_4:def 4;
hence o in Roots ((FAdj (F,T)),(ProductMinPolys T)) by E7; :: thesis: verum
end;
then T c= the carrier of K by E2;
hence K == FAdj (F,T) by E1, E3, FIELD_6:37; :: thesis: verum
end;
then FAdj (F,T) is SplittingField of ProductMinPolys T by E, FIELD_8:def 1;
then E is SplittingField of ProductMinPolys T by A, FIELD_13:16;
hence ex p being non constant separable Element of (Polynom-Ring F) st E is SplittingField of p ; :: thesis: verum
end;
end;