let F be Field; :: thesis: for E being FieldExtension of F
for G being Subgroup of Aut E st Fix (E,G) == F holds
for p being Polynomial of E st ( for g being Element of the carrier of G holds (PolyHom g) . p = p ) holds
p is Polynomial of F

let E be FieldExtension of F; :: thesis: for G being Subgroup of Aut E st Fix (E,G) == F holds
for p being Polynomial of E st ( for g being Element of the carrier of G holds (PolyHom g) . p = p ) holds
p is Polynomial of F

let G be Subgroup of Aut E; :: thesis: ( Fix (E,G) == F implies for p being Polynomial of E st ( for g being Element of the carrier of G holds (PolyHom g) . p = p ) holds
p is Polynomial of F )

assume AS1: Fix (E,G) == F ; :: thesis: for p being Polynomial of E st ( for g being Element of the carrier of G holds (PolyHom g) . p = p ) holds
p is Polynomial of F

let p be Polynomial of E; :: thesis: ( ( for g being Element of the carrier of G holds (PolyHom g) . p = p ) implies p is Polynomial of F )
assume AS2: for f being Element of the carrier of G holds (PolyHom f) . p = p ; :: thesis: p is Polynomial of F
now :: thesis: for o being object st o in Coeff p holds
o in the carrier of F
let o be object ; :: thesis: ( o in Coeff p implies o in the carrier of F )
assume A: o in Coeff p ; :: thesis: o in the carrier of F
Coeff p = { (p . i) where i is Element of NAT : p . i <> 0. E } by FIELD_7:def 3;
then consider i being Element of NAT such that
B: ( o = p . i & p . i <> 0. E ) by A;
now :: thesis: for g being Function of E,E st g in G holds
p . i = g . (p . i)
let g be Function of E,E; :: thesis: ( g in G implies p . i = g . (p . i) )
assume C: g in G ; :: thesis: p . i = g . (p . i)
then reconsider g1 = g as additive Function of E,E ;
reconsider p1 = p as Element of the carrier of (Polynom-Ring E) by POLYNOM3:def 10;
thus p . i = ((PolyHom g1) . p1) . i by C, AS2
.= g . (p . i) by GALOIS_0:def 27 ; :: thesis: verum
end;
then p . i in Fixed_El (E,G) ;
hence o in the carrier of F by B, AS1, GALOIS_1:def 17; :: thesis: verum
end;
then Coeff p c= the carrier of F ;
hence p is Polynomial of F by FIELD_7:11; :: thesis: verum