let F be Field; :: thesis: for p, q being non constant Element of the carrier of (Polynom-Ring F) st p is separable & q is separable holds
( p * q is separable iff p,q have_nowhere_common_roots )

let p, q be non constant Element of the carrier of (Polynom-Ring F); :: thesis: ( p is separable & q is separable implies ( p * q is separable iff p,q have_nowhere_common_roots ) )
assume AS: ( p is separable & q is separable ) ; :: thesis: ( p * q is separable iff p,q have_nowhere_common_roots )
reconsider r = p * q as non constant Element of the carrier of (Polynom-Ring F) ;
deg p > 0 by RING_4:def 4;
then reconsider p1 = p as non constant Polynomial of F by RATFUNC1:def 2;
deg q > 0 by RING_4:def 4;
then reconsider q1 = q as non constant Polynomial of F by RATFUNC1:def 2;
H: p * q = p1 *' q1 by POLYNOM3:def 10;
Z: now :: thesis: ( p,q have_nowhere_common_roots implies p * q is separable )
assume AS1: p,q have_nowhere_common_roots ; :: thesis: p * q is separable
now :: thesis: for E being FieldExtension of F st r splits_in E holds
for a being Element of E st a is_a_root_of p * q,E holds
multiplicity (r,a) = 1
let E be FieldExtension of F; :: thesis: ( r splits_in E implies for a being Element of E st a is_a_root_of p * q,E holds
multiplicity (r,b3) = 1 )

assume r splits_in E ; :: thesis: for a being Element of E st a is_a_root_of p * q,E holds
multiplicity (r,b3) = 1

then A: ( p *' q splits_in E & F is Subring of E ) by POLYNOM3:def 10, FIELD_4:def 1;
let a be Element of E; :: thesis: ( a is_a_root_of p * q,E implies multiplicity (r,b2) = 1 )
assume a is_a_root_of p * q,E ; :: thesis: multiplicity (r,b2) = 1
then B: 0. E = Ext_eval ((p1 *' q1),a) by H, FIELD_4:def 2
.= (Ext_eval (p1,a)) * (Ext_eval (q1,a)) by A, ALGNUM_1:20 ;
C: ( p1 splits_in E & q1 splits_in E ) by A, FIELD_13:7;
D: multiplicity ((p1 *' q1),a) = (multiplicity (p1,a)) + (multiplicity (q1,a)) by FIELD_15:62;
per cases ( Ext_eval (p1,a) = 0. E or Ext_eval (q1,a) = 0. E ) by B, VECTSP_2:def 1;
suppose S: Ext_eval (p1,a) = 0. E ; :: thesis: multiplicity (r,b2) = 1
then E: a is_a_root_of p,E by FIELD_4:def 2;
F: multiplicity (p,a) = 1 by S, AS, C, FIELD_15:75, FIELD_4:def 2;
G: ( Roots (E,p) = { a where a is Element of E : a is_a_root_of p,E } & Roots (E,q) = { a where a is Element of E : a is_a_root_of q,E } ) by FIELD_4:def 4;
hence multiplicity (r,a) = 1 + 0 by D, H, F
.= 1 ;
:: thesis: verum
end;
suppose S: Ext_eval (q1,a) = 0. E ; :: thesis: multiplicity (r,b2) = 1
then E: a is_a_root_of q,E by FIELD_4:def 2;
F: multiplicity (q,a) = 1 by S, AS, C, FIELD_15:75, FIELD_4:def 2;
G: ( Roots (E,p) = { a where a is Element of E : a is_a_root_of p,E } & Roots (E,q) = { a where a is Element of E : a is_a_root_of q,E } ) by FIELD_4:def 4;
hence multiplicity (r,a) = 0 + 1 by D, H, F
.= 1 ;
:: thesis: verum
end;
end;
end;
hence p * q is separable by FIELD_15:75; :: thesis: verum
end;
now :: thesis: ( p * q is separable implies p,q have_nowhere_common_roots )
assume A: p * q is separable ; :: thesis: p,q have_nowhere_common_roots
now :: thesis: not p,q have_common_roots_in_some_extension
assume p,q have_common_roots_in_some_extension ; :: thesis: contradiction
then consider E being FieldExtension of F such that
B: (Roots (E,p)) /\ (Roots (E,q)) <> {} ;
G: ( Roots (E,p) = { a where a is Element of E : a is_a_root_of p,E } & Roots (E,q) = { a where a is Element of E : a is_a_root_of q,E } ) by FIELD_4:def 4;
set o = the Element of (Roots (E,p)) /\ (Roots (E,q));
the Element of (Roots (E,p)) /\ (Roots (E,q)) in Roots (E,p) by B, XBOOLE_0:def 4;
then consider a1 being Element of E such that
C: ( the Element of (Roots (E,p)) /\ (Roots (E,q)) = a1 & a1 is_a_root_of p,E ) by G;
the Element of (Roots (E,p)) /\ (Roots (E,q)) in Roots (E,q) by B, XBOOLE_0:def 4;
then consider a2 being Element of E such that
D: ( the Element of (Roots (E,p)) /\ (Roots (E,q)) = a2 & a2 is_a_root_of q,E ) by G;
E: ( multiplicity (p,a1) >= 1 & multiplicity (q,a1) >= 1 ) by D, C, FIELD_15:57;
multiplicity ((p1 *' q1),a1) = (multiplicity (p,a1)) + (multiplicity (q,a1)) by FIELD_15:62;
then multiplicity ((p1 *' q1),a1) >= 1 + 1 by E, XREAL_1:7;
then (multiplicity ((p1 *' q1),a1)) - 0 > (1 + 1) - 1 by XREAL_1:15;
hence contradiction by H, A, FIELD_15:77; :: thesis: verum
end;
hence p,q have_nowhere_common_roots ; :: thesis: verum
end;
hence ( p * q is separable iff p,q have_nowhere_common_roots ) by Z; :: thesis: verum