let F be Field; :: thesis: for f being FinSequence of (Polynom-Ring F)
for p, q1, q2 being Element of the carrier of (Polynom-Ring F) st p = Product f & ex i, j being Nat st
( j <> i & 1 <= i & i <= len f & f . i = q1 & 1 <= j & j <= len f & f . j = q2 ) holds
q1 *' q2 divides p

let f be FinSequence of (Polynom-Ring F); :: thesis: for p, q1, q2 being Element of the carrier of (Polynom-Ring F) st p = Product f & ex i, j being Nat st
( j <> i & 1 <= i & i <= len f & f . i = q1 & 1 <= j & j <= len f & f . j = q2 ) holds
q1 *' q2 divides p

let p, q1, q2 be Element of the carrier of (Polynom-Ring F); :: thesis: ( p = Product f & ex i, j being Nat st
( j <> i & 1 <= i & i <= len f & f . i = q1 & 1 <= j & j <= len f & f . j = q2 ) implies q1 *' q2 divides p )

assume A: ( p = Product f & ex i, j being Nat st
( j <> i & 1 <= i & i <= len f & f . i = q1 & 1 <= j & j <= len f & f . j = q2 ) ) ; :: thesis: q1 *' q2 divides p
then consider i, j being Nat such that
B: ( j <> i & 1 <= i & i <= len f & f . i = q1 & 1 <= j & j <= len f & f . j = q2 ) ;
reconsider i1 = i - 1 as Element of NAT by B, INT_1:3;
i in Seg (len f) by B;
then C: ( i1 + 1 = i & i in dom f ) by FINSEQ_1:def 3;
then D: f /. i = f . i by PARTFUN1:def 6;
set g = (f | i1) ^ (f /^ i);
reconsider r = Product ((f | i1) ^ (f /^ i)), r1 = Product (f | i1), r2 = Product (f /^ i) as Element of the carrier of (Polynom-Ring F) ;
H1: f = (f | i1) ^ (f /^ i1) by RFINSEQ:8
.= (f | i1) ^ (<*(f /. i)*> ^ (f /^ i)) by C, FINSEQ_5:31 ;
then E: p = (Product (f | i1)) * (Product (<*(f /. i)*> ^ (f /^ i))) by A, GROUP_4:5
.= r1 * (q1 * r2) by B, D, GROUP_4:7
.= q1 * (r1 * r2) by GROUP_1:def 3
.= q1 * r by GROUP_4:5
.= q1 *' r by POLYNOM3:def 10 ;
F: len f = (len (f | i1)) + (len (<*(f /. i)*> ^ (f /^ i))) by H1, FINSEQ_1:22
.= (len (f | i1)) + ((len <*(f /. i)*>) + (len (f /^ i))) by FINSEQ_1:22
.= (len (f | i1)) + (1 + (len (f /^ i))) by FINSEQ_1:40
.= 1 + ((len (f | i1)) + (len (f /^ i)))
.= 1 + (len ((f | i1) ^ (f /^ i))) by FINSEQ_1:22 ;
ex k being Nat st
( 1 <= k & k <= len ((f | i1) ^ (f /^ i)) & ((f | i1) ^ (f /^ i)) . k = q2 )
proof
i1 + 1 = i ;
then KK: i1 <= i by NAT_1:11;
then K0: i1 <= len f by B, XXREAL_0:2;
K1: len (f | i1) = i1 by KK, B, XXREAL_0:2, FINSEQ_1:59;
per cases ( j < i or j > i ) by B, XXREAL_0:1;
suppose H3: j < i ; :: thesis: ex k being Nat st
( 1 <= k & k <= len ((f | i1) ^ (f /^ i)) & ((f | i1) ^ (f /^ i)) . k = q2 )

then j < len f by B, XXREAL_0:1;
then H4: (j - 1) + 1 <= len ((f | i1) ^ (f /^ i)) by F, INT_1:7;
j + 1 <= i by H3, INT_1:7;
then (j + 1) - 1 <= i - 1 by XREAL_1:9;
then K2: j in Seg (len (f | i1)) by B, K1;
then H5: j in dom (f | i1) by FINSEQ_1:def 3;
now :: thesis: not 1 > i1
assume 1 > i1 ; :: thesis: contradiction
then 1 >= i1 + 1 by INT_1:7;
hence contradiction by H3, B, XXREAL_0:1; :: thesis: verum
end;
then i1 in Seg (len f) by K0;
then i1 in dom f by FINSEQ_1:def 3;
then q2 = (f | i1) . j by K1, K2, B, RFINSEQ:6
.= ((f | i1) ^ (f /^ i)) . j by H5, FINSEQ_1:def 7 ;
hence ex k being Nat st
( 1 <= k & k <= len ((f | i1) ^ (f /^ i)) & ((f | i1) ^ (f /^ i)) . k = q2 ) by B, H4; :: thesis: verum
end;
suppose HH: j > i ; :: thesis: ex k being Nat st
( 1 <= k & k <= len ((f | i1) ^ (f /^ i)) & ((f | i1) ^ (f /^ i)) . k = q2 )

then j - i > i - i by XREAL_1:9;
then reconsider k1 = j - i as Element of NAT by INT_1:3;
set k = i1 + k1;
k1 > i - i by HH, XREAL_1:9;
then H0: 0 + 1 <= k1 by INT_1:7;
then H1: (f /^ i) . k1 = f . (k1 + i) by B, FINSEQ_6:114;
k1 <= i1 + k1 by NAT_1:11;
then H2: 1 <= i1 + k1 by H0, XXREAL_0:2;
(i1 + k1) + 0 < (j - 1) + 1 by XREAL_1:6;
then i1 + k1 < len f by B, XXREAL_0:2;
then H3: i1 + k1 <= len ((f | i1) ^ (f /^ i)) by F, INT_1:7;
H4: len (f /^ i) = (len f) - i by B, RFINSEQ:def 1;
k1 <= (len f) - i by B, XREAL_1:9;
then k1 in Seg (len (f /^ i)) by H4, H0;
then k1 in dom (f /^ i) by FINSEQ_1:def 3;
then ((f | i1) ^ (f /^ i)) . (i1 + k1) = q2 by B, H1, K1, FINSEQ_1:def 7;
hence ex k being Nat st
( 1 <= k & k <= len ((f | i1) ^ (f /^ i)) & ((f | i1) ^ (f /^ i)) . k = q2 ) by H2, H3; :: thesis: verum
end;
end;
end;
then consider s being Polynomial of F such that
F: q2 *' s = r by RING_4:1, sepprodB;
(q1 *' q2) *' s = q1 *' r by F, POLYNOM3:33;
hence q1 *' q2 divides p by E, RING_4:1; :: thesis: verum