let F be Field; :: thesis: for f being FinSequence of (Polynom-Ring F)
for p, q being Element of the carrier of (Polynom-Ring F) st p = Product f & ex i being Nat st
( 1 <= i & i <= len f & f . i = q ) holds
q divides p

let f be FinSequence of (Polynom-Ring F); :: thesis: for p, q being Element of the carrier of (Polynom-Ring F) st p = Product f & ex i being Nat st
( 1 <= i & i <= len f & f . i = q ) holds
q divides p

let p, q be Element of the carrier of (Polynom-Ring F); :: thesis: ( p = Product f & ex i being Nat st
( 1 <= i & i <= len f & f . i = q ) implies q divides p )

assume A: ( p = Product f & ex i being Nat st
( 1 <= i & i <= len f & f . i = q ) ) ; :: thesis: q divides p
then consider i being Nat such that
B: ( 1 <= i & i <= len f & f . i = q ) ;
reconsider i1 = i - 1 as Element of NAT by B, INT_1:3;
reconsider r1 = Product (f | i1), r2 = Product (f /^ i) as Element of the carrier of (Polynom-Ring F) ;
i in Seg (len f) by B;
then C: ( i1 + 1 = i & i in dom f ) by FINSEQ_1:def 3;
then D: f /. i = f . i by PARTFUN1:def 6;
E: r1 * r2 = r1 *' r2 by POLYNOM3:def 10;
f = (f | i1) ^ (f /^ i1) by RFINSEQ:8
.= (f | i1) ^ (<*(f /. i)*> ^ (f /^ i)) by C, FINSEQ_5:31 ;
then p = (Product (f | i1)) * (Product (<*(f /. i)*> ^ (f /^ i))) by A, GROUP_4:5
.= r1 * (q * r2) by B, D, GROUP_4:7
.= q * (r1 * r2) by GROUP_1:def 3
.= q *' (r1 *' r2) by E, POLYNOM3:def 10 ;
hence q divides p by RING_4:1; :: thesis: verum