set f = *' ;
set L = F_Complex ;
now :: thesis: for a being Element of F_Real holds *' . a = a
let a be Element of F_Real; :: thesis: *' . a = a
F_Real is Subfield of F_Complex by FIELD_4:7;
then the carrier of F_Real c= the carrier of F_Complex by EC_PF_1:def 1;
then reconsider c = a as Element of F_Complex ;
thus *' . a = c *' by di
.= a ; :: thesis: verum
end;
hence *' is F_Real -fixing ; :: thesis: *' is isomorphism
now :: thesis: for o being object st o in the carrier of F_Complex holds
o in rng *'
let o be object ; :: thesis: ( o in the carrier of F_Complex implies o in rng *' )
assume o in the carrier of F_Complex ; :: thesis: o in rng *'
then reconsider a = o as Element of F_Complex ;
(Re a) - ((Im a) * <i>) in COMPLEX by XCMPLX_0:def 2;
then reconsider c = (Re a) + ((- (Im a)) * <i>) as Element of F_Complex by COMPLFLD:def 1;
H: dom *' = the carrier of F_Complex by FUNCT_2:def 1;
I: ( Re c = Re a & Im c = - (Im a) ) by COMPLEX1:12;
*' . c = c *' by di
.= (Re c) - ((Im c) * <i>) by COMPLEX1:def 11
.= (Re a) + ((Im a) * <i>) by I
.= a by COMPLEX1:13 ;
hence o in rng *' by H, FUNCT_1:def 3; :: thesis: verum
end;
then ( rng *' c= the carrier of F_Complex & the carrier of F_Complex c= rng *' ) by RELAT_1:def 19;
then B: *' is onto by XBOOLE_0:def 10;
now :: thesis: for x, y being Element of F_Complex holds *' . (x + y) = (*' . x) + (*' . y)
let x, y be Element of F_Complex; :: thesis: *' . (x + y) = (*' . x) + (*' . y)
thus *' . (x + y) = (x + y) *' by di
.= (Re (x + y)) - ((Im (x + y)) * <i>) by COMPLEX1:def 11
.= ((Re x) + (Re y)) - ((Im (x + y)) * <i>) by COMPLEX1:8
.= ((Re x) + (Re y)) - (((Im x) + (Im y)) * <i>) by COMPLEX1:8
.= ((Re x) - ((Im x) * <i>)) + ((Re y) - ((Im y) * <i>))
.= (x *') + ((Re y) - ((Im y) * <i>)) by COMPLEX1:def 11
.= (x *') + (y *') by COMPLEX1:def 11
.= (*' . x) + (y *') by di
.= (*' . x) + (*' . y) by di ; :: thesis: verum
end;
then C: *' is additive by VECTSP_1:def 20;
now :: thesis: for x, y being Element of F_Complex holds *' . (x * y) = (*' . x) * (*' . y)
let x, y be Element of F_Complex; :: thesis: *' . (x * y) = (*' . x) * (*' . y)
thus *' . (x * y) = (x * y) *' by di
.= (Re (x * y)) - ((Im (x * y)) * <i>) by COMPLEX1:def 11
.= (((Re x) * (Re y)) - ((Im x) * (Im y))) - ((Im (x * y)) * <i>) by COMPLEX1:9
.= (((Re x) * (Re y)) - ((Im x) * (Im y))) - ((((Re x) * (Im y)) + ((Re y) * (Im x))) * <i>) by COMPLEX1:9
.= ((Re x) - ((Im x) * <i>)) * ((Re y) - ((Im y) * <i>))
.= (x *') * ((Re y) - ((Im y) * <i>)) by COMPLEX1:def 11
.= (x *') * (y *') by COMPLEX1:def 11
.= (*' . x) * (y *') by di
.= (*' . x) * (*' . y) by di ; :: thesis: verum
end;
then D: *' is multiplicative by GROUP_6:def 6;
*' is unity-preserving by di, COMPLFLD:49;
hence *' is isomorphism by B, C, D; :: thesis: verum