let F be Field; :: thesis: for G being Subgroup of Aut F holds G is Subgroup of Aut (F,(Fix (F,G)))
let G be Subgroup of Aut F; :: thesis: G is Subgroup of Aut (F,(Fix (F,G)))
now :: thesis: for o being object st o in the carrier of G holds
o in the carrier of (Aut (F,(Fix (F,G))))
let o be object ; :: thesis: ( o in the carrier of G implies o in the carrier of (Aut (F,(Fix (F,G)))) )
assume B: o in the carrier of G ; :: thesis: o in the carrier of (Aut (F,(Fix (F,G))))
the carrier of G c= the carrier of (Aut F) by GROUP_2:def 5;
then o in { f where f is Automorphism of F : verum } by B;
then consider f being Automorphism of F such that
E: o = f ;
reconsider E = F as FieldExtension of Fix (F,G) by FIELD_4:7;
reconsider f = f as Automorphism of E ;
now :: thesis: for a being Element of (Fix (F,G)) holds f . a = a
let a be Element of (Fix (F,G)); :: thesis: f . a = a
the carrier of (Fix (F,G)) = Fixed_El (F,G) by df;
then a in Fixed_El (F,G) ;
then consider a1 being Element of F such that
G: ( a1 = a & ( for f being Function of F,F st f in G holds
f . a1 = a1 ) ) ;
f in G by B, E;
hence f . a = a by G; :: thesis: verum
end;
then f is Fix (F,G) -fixing ;
hence o in the carrier of (Aut (F,(Fix (F,G)))) by E; :: thesis: verum
end;
then B: the carrier of G c= the carrier of (Aut (F,(Fix (F,G)))) ;
then J: [: the carrier of G, the carrier of G:] c= [: the carrier of (Aut (F,(Fix (F,G)))), the carrier of (Aut (F,(Fix (F,G)))):] by ZFMISC_1:96;
the multF of G = the multF of (Aut F) || the carrier of G by GROUP_2:def 5;
then the multF of (Aut (F,(Fix (F,G)))) || the carrier of G = the multF of G by J, FUNCT_1:51;
hence G is Subgroup of Aut (F,(Fix (F,G))) by B, GROUP_2:def 5; :: thesis: verum