let F be Field; :: thesis: for E being FieldExtension of F
for G being Subgroup of Aut (E,F) holds Fix (E,G) is IntermediateField of E,F

let E be FieldExtension of F; :: thesis: for G being Subgroup of Aut (E,F) holds Fix (E,G) is IntermediateField of E,F
let G be Subgroup of Aut (E,F); :: thesis: Fix (E,G) is IntermediateField of E,F
reconsider C = G as Subgroup of Aut E ;
H: ( Aut (E,F) = multMagma(# (Auts (E,F)),(AutComp (E,F)) #) & Auts (E,F) = { f where f is F -fixing Automorphism of E : verum } & the carrier of G c= the carrier of (Aut (E,F)) & F is Subfield of E ) by FIELD_4:7, GROUP_2:def 5;
now :: thesis: for o being object st o in the carrier of F holds
o in the carrier of (Fix (E,G))
let o be object ; :: thesis: ( o in the carrier of F implies o in the carrier of (Fix (E,G)) )
assume A: o in the carrier of F ; :: thesis: o in the carrier of (Fix (E,G))
the carrier of F c= the carrier of E by H, EC_PF_1:def 1;
then reconsider a = o as Element of E by A;
for f being Function of E,E st f in C holds
f . a = a by A, FIELD_8:def 2;
then o in Fixed_Elements (E,C) ;
hence o in the carrier of (Fix (E,G)) by df; :: thesis: verum
end;
then B: the carrier of F c= the carrier of (Fix (E,G)) ;
then I: [: the carrier of F, the carrier of F:] c= [: the carrier of (Fix (E,G)), the carrier of (Fix (E,G)):] by ZFMISC_1:96;
C: the addF of (Fix (E,G)) || the carrier of F = ( the addF of E || the carrier of (Fix (E,G))) || the carrier of F by EC_PF_1:def 1
.= the addF of E || the carrier of F by I, FUNCT_1:51
.= the addF of F by H, EC_PF_1:def 1 ;
D: the multF of (Fix (E,G)) || the carrier of F = ( the multF of E || the carrier of (Fix (E,G))) || the carrier of F by EC_PF_1:def 1
.= the multF of E || the carrier of F by I, FUNCT_1:51
.= the multF of F by H, EC_PF_1:def 1 ;
E: 1. F = 1. E by H, EC_PF_1:def 1
.= 1. (Fix (E,G)) by df ;
0. F = 0. E by H, EC_PF_1:def 1
.= 0. (Fix (E,G)) by df ;
then F is Subfield of Fix (E,G) by B, C, D, E, EC_PF_1:def 1;
then Fix (E,G) in IntermediateFields (E,F) by FIELD_14:4;
hence Fix (E,G) is IntermediateField of E,F by GALOIS_0:def 5; :: thesis: verum